let X be non empty set ; :: thesis: for S being SigmaField of X
for F being Functional_Sequence of X,ExtREAL
for n being Nat st ( for m being Nat holds F . m is_simple_func_in S ) holds
( F is additive & (Partial_Sums F) . n is_simple_func_in S )
let S be SigmaField of X; :: thesis: for F being Functional_Sequence of X,ExtREAL
for n being Nat st ( for m being Nat holds F . m is_simple_func_in S ) holds
( F is additive & (Partial_Sums F) . n is_simple_func_in S )
let F be Functional_Sequence of X,ExtREAL ; :: thesis: for n being Nat st ( for m being Nat holds F . m is_simple_func_in S ) holds
( F is additive & (Partial_Sums F) . n is_simple_func_in S )
let n be Nat; :: thesis: ( ( for m being Nat holds F . m is_simple_func_in S ) implies ( F is additive & (Partial_Sums F) . n is_simple_func_in S ) )
assume A1: for m being Nat holds F . m is_simple_func_in S ; :: thesis: ( F is additive & (Partial_Sums F) . n is_simple_func_in S )

hereby :: according to MESFUNC9:def 5 :: thesis: (Partial_Sums F) . n is_simple_func_in S

let n, m be Nat; :: thesis: ( n <> m implies for x being set holds
( not x in (dom (F . n)) /\ (dom (F . m)) or (F . n) . x <> +infty or (F . m) . x <> -infty ) )
assume n <> m ; :: thesis: for x being set holds
( not x in (dom (F . n)) /\ (dom (F . m)) or (F . n) . x <> +infty or (F . m) . x <> -infty )
( F . n is_simple_func_in S & F . m is_simple_func_in S ) by A1;
then ( F . n is without+infty & F . m is without+infty ) by MESFUNC5:20;
hence for x being set holds
( not x in (dom (F . n)) /\ (dom (F . m)) or (F . n) . x <> +infty or (F . m) . x <> -infty ) by MESFUNC5:def 6; :: thesis: verum

end;

defpred S₁[ Nat] means (Partial_Sums F) . $1 is_simple_func_in S;
(Partial_Sums F) . 0 = F . 0 by Def0;
then A2: S₁[ 0 ] by A1;
A3: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A4: S₁[k] ; :: thesis: S₁[k + 1]
F . (k + 1) is_simple_func_in S by A1;
then ((Partial_Sums F) . k) + (F . (k + 1)) is_simple_func_in S by A4, MESFUNC5:44;
hence S₁[k + 1] by Def0; :: thesis: verum

end;

for k being Nat holds S₁[k] from NAT_1:sch 2(A2, A3);
hence (Partial_Sums F) . n is_simple_func_in S ; :: thesis: verum