let X be non empty set ; :: thesis: for F being Functional_Sequence of X,ExtREAL
for n being Nat
for x being Element of X
for D being set st F is additive & F is with_the_same_dom & D c= dom (F . 0 ) & x in D holds
(Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n
let F be Functional_Sequence of X,ExtREAL ; :: thesis: for n being Nat
for x being Element of X
for D being set st F is additive & F is with_the_same_dom & D c= dom (F . 0 ) & x in D holds
(Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n
let n be Nat; :: thesis: for x being Element of X
for D being set st F is additive & F is with_the_same_dom & D c= dom (F . 0 ) & x in D holds
(Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n
let x be Element of X; :: thesis: for D being set st F is additive & F is with_the_same_dom & D c= dom (F . 0 ) & x in D holds
(Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n
let D be set ; :: thesis: ( F is additive & F is with_the_same_dom & D c= dom (F . 0 ) & x in D implies (Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n )
set PF = Partial_Sums F;
set PFx = Partial_Sums (F # x);
assume that
AS1: ( F is additive & F is with_the_same_dom & D c= dom (F . 0 ) ) and
AS2: x in D ; :: thesis: (Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n
defpred S₁[ Nat] means (Partial_Sums (F # x)) . $1 = ((Partial_Sums F) # x) . $1;
(Partial_Sums (F # x)) . 0 = (F # x) . 0 by Def1;
then (Partial_Sums (F # x)) . 0 = (F . 0 ) . x by MESFUNC5:def 13;
then (Partial_Sums (F # x)) . 0 = ((Partial_Sums F) . 0 ) . x by Def0;
then A1: S₁[ 0 ] by MESFUNC5:def 13;
A2: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A3: S₁[k] ; :: thesis: S₁[k + 1]
A4: (Partial_Sums F) . (k + 1) = ((Partial_Sums F) . k) + (F . (k + 1)) by Def0;
A5: D c= dom ((Partial_Sums F) . (k + 1)) by AS1, ADD0;
(Partial_Sums (F # x)) . (k + 1) = ((Partial_Sums (F # x)) . k) + ((F # x) . (k + 1)) by Def1;
then (Partial_Sums (F # x)) . (k + 1) = (((Partial_Sums F) # x) . k) + ((F . (k + 1)) . x) by A3, MESFUNC5:def 13;
then (Partial_Sums (F # x)) . (k + 1) = (((Partial_Sums F) . k) . x) + ((F . (k + 1)) . x) by MESFUNC5:def 13;
then (Partial_Sums (F # x)) . (k + 1) = ((Partial_Sums F) . (k + 1)) . x by AS2, A4, A5, MESFUNC1:def 3;
hence S₁[k + 1] by MESFUNC5:def 13; :: thesis: verum

end;

for k being Nat holds S₁[k] from NAT_1:sch 2(A1, A2);
hence (Partial_Sums (F # x)) . n = ((Partial_Sums F) # x) . n ; :: thesis: verum