let X be non empty set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for f being PartFunc of X,COMPLEX
for E, A being Element of S st E = dom f & f is_integrable_on M & M . A = 0 holds
Integral M,(f | (E \ A)) = Integral M,f
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for f being PartFunc of X,COMPLEX
for E, A being Element of S st E = dom f & f is_integrable_on M & M . A = 0 holds
Integral M,(f | (E \ A)) = Integral M,f
let M be sigma_Measure of S; :: thesis: for f being PartFunc of X,COMPLEX
for E, A being Element of S st E = dom f & f is_integrable_on M & M . A = 0 holds
Integral M,(f | (E \ A)) = Integral M,f
let f be PartFunc of X,COMPLEX ; :: thesis: for E, A being Element of S st E = dom f & f is_integrable_on M & M . A = 0 holds
Integral M,(f | (E \ A)) = Integral M,f
let E, A be Element of S; :: thesis: ( E = dom f & f is_integrable_on M & M . A = 0 implies Integral M,(f | (E \ A)) = Integral M,f )
assume A1: ( E = dom f & f is_integrable_on M & M . A = 0 ) ; :: thesis: Integral M,(f | (E \ A)) = Integral M,f
then A2: ( Re f is_integrable_on M & Im f is_integrable_on M ) by Def4;
A3: ( dom f = dom (Re f) & dom f = dom (Im f) ) by Def1, Def2;
C0: ( R_EAL (Re f) is_integrable_on M & R_EAL (Im f) is_integrable_on M ) by A2, MESFUNC6:def 9;
then consider RE being Element of S such that
C1: ( RE = dom (R_EAL (Re f)) & R_EAL (Re f) is_measurable_on RE ) by MESFUNC5:def 17;
D1: ( RE = dom (Re f) & Re f is_measurable_on RE ) by C1, MESFUNC6:def 6;
consider IE being Element of S such that
C2: ( IE = dom (R_EAL (Im f)) & R_EAL (Im f) is_measurable_on IE ) by C0, MESFUNC5:def 17;
D2: ( IE = dom (Im f) & Im f is_measurable_on IE ) by C2, MESFUNC6:def 6;
set C = E \ A;
( (Re f) | (E \ A) is_integrable_on M & (Im f) | (E \ A) is_integrable_on M ) by A2, MESFUNC6:91;
then A4: ( Re (f | (E \ A)) is_integrable_on M & Im (f | (E \ A)) is_integrable_on M ) by COM91;
then ( -infty < Integral M,(Re (f | (E \ A))) & Integral M,(Re (f | (E \ A))) < +infty & -infty < Integral M,(Im (f | (E \ A))) & Integral M,(Im (f | (E \ A))) < +infty ) by MESFUNC6:90;
then reconsider R2 = Integral M,(Re (f | (E \ A))), I2 = Integral M,(Im (f | (E \ A))) as Real by XXREAL_0:14;
Integral M,((Re f) | (E \ A)) = Integral M,(Re (f | (E \ A))) by COM91;
then B1: Integral M,(Re (f | (E \ A))) = Integral M,(Re f) by A3, A1, D1, MESFUNC6:89;
Integral M,((Im f) | (E \ A)) = Integral M,(Im (f | (E \ A))) by COM91;
then B2: Integral M,(Im (f | (E \ A))) = Integral M,(Im f) by A3, A1, D2, MESFUNC6:89;
f | (E \ A) is_integrable_on M by A4, Def4;
hence Integral M,(f | (E \ A)) = R2 + (I2 * <i> ) by Def5
.= Integral M,f by A1, B1, B2, Def5 ;
:: thesis: verum