let K be Field; :: thesis: for a being Element of K
for p being FinSequence of K st p is first-col-of-circulant holds
CCirc (a * p) = a * (CCirc p)
let a be Element of K; :: thesis: for p being FinSequence of K st p is first-col-of-circulant holds
CCirc (a * p) = a * (CCirc p)
let p be FinSequence of K; :: thesis: ( p is first-col-of-circulant implies CCirc (a * p) = a * (CCirc p) )
set n = len p;
assume A1: p is first-col-of-circulant ; :: thesis: CCirc (a * p) = a * (CCirc p)
then A4: a * p is first-col-of-circulant by Th46;
A6: len (a * p) = len p by MATRIXR1:16;
A10: CCirc p is_col_circulant_about p by A1, Def8;
A12: CCirc (a * p) is_col_circulant_about a * p by A4, Def8;
A13: ( len (CCirc (a * p)) = len p & len (CCirc p) = len p & width (CCirc (a * p)) = len p & width (CCirc p) = len p ) by A6, MATRIX_1:25;
A15: ( Indices (CCirc p) = Indices (CCirc (a * p)) & Indices (CCirc p) = [:(Seg (len p)),(Seg (len p)):] ) by A6, MATRIX_1:25, MATRIX_1:27;
for i, j being Nat st [i,j] in Indices (CCirc p) holds
(CCirc (a * p)) * i,j = a * ((CCirc p) * i,j)

proof

let i, j be Nat; :: thesis: ( [i,j] in Indices (CCirc p) implies (CCirc (a * p)) * i,j = a * ((CCirc p) * i,j) )
assume B1: [i,j] in Indices (CCirc p) ; :: thesis: (CCirc (a * p)) * i,j = a * ((CCirc p) * i,j)
then B2: [i,j] in Indices (CCirc (a * p)) by A6, MATRIX_1:27;
B3: ((i - j) mod (len p)) + 1 in Seg (len p) by B1, A15, Lm2;
B4: ( dom (a * p) = Seg (len (a * p)) & dom p = Seg (len p) ) by FINSEQ_1:def 3;
(CCirc (a * p)) * i,j = (a * p) . (((i - j) mod (len (a * p))) + 1) by B2, A12, Def4
.= (a * p) /. (((i - j) mod (len p)) + 1) by A6, B3, B4, PARTFUN1:def 8
.= a * (p /. (((i - j) mod (len p)) + 1)) by B3, B4, POLYNOM1:def 2
.= (a multfield ) . (p /. (((i - j) mod (len p)) + 1)) by FVSUM_1:61
.= (a multfield ) . (p . (((i - j) mod (len p)) + 1)) by B3, B4, PARTFUN1:def 8
.= (a multfield ) . ((CCirc p) * i,j) by B1, A10, Def4
.= a * ((CCirc p) * i,j) by FVSUM_1:61 ;
hence (CCirc (a * p)) * i,j = a * ((CCirc p) * i,j) ; :: thesis: verum

end;

hence CCirc (a * p) = a * (CCirc p) by A13, MATRIX_3:def 5; :: thesis: verum