let X, Y be RealNormSpace; :: thesis: for f, g being Point of (R_NormSpace_of_BoundedLinearOperators X,Y)
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (R_NormSpace_of_BoundedLinearOperators X,Y); :: thesis: for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let a be Real; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A1: now
assume A2: ||.f.|| = 0 ; :: thesis: f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y)
reconsider g = f as bounded LinearOperator of X,Y by Def10;
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X,the carrier of Y ;
now
let t be VECTOR of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| * ||.t.|| by Th38;
then ||.(g . t).|| = 0 by A2, NORMSP_1:8;
hence g . t = 0. Y by NORMSP_1:def 2
.= z . t by FUNCOP_1:13 ;
:: thesis: verum
end;
then g = z by FUNCT_2:113;
hence f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) by Th37; :: thesis: verum
end;
A3: now
assume A4: f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X,the carrier of Y ;
reconsider g = f as bounded LinearOperator of X,Y by Def10;
A5: z = g by A4, Th37;
A6: now
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume A7: r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
consider t being VECTOR of X such that
A8: ( r = ||.(g . t).|| & ||.t.|| <= 1 ) by A7;
||.(g . t).|| = ||.(0. Y).|| by A5, FUNCOP_1:13
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum
end;
A9: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th32;
consider r0 being set such that
A10: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A10;
A11: 0 <= r0 by A6, A10;
( ( for s being real number st s in PreNorms g holds
s <= 0 ) implies sup (PreNorms g) <= 0 ) by SEQ_4:62;
then sup (PreNorms g) = 0 by A6, A9, A10, A11, SEQ_4:def 4;
then (BoundedLinearOperatorsNorm X,Y) . f = 0 by Th36;
hence ||.f.|| = 0 by NORMSP_1:def 1; :: thesis: verum
end;
end;
A12: ||.(a * f).|| = (abs a) * ||.f.||
proof
reconsider f1 = f, h1 = a * f as bounded LinearOperator of X,Y by Def10;
A13: now
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= (abs a) * ||.f.|| )
assume A14: ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= (abs a) * ||.f.||
A15: ||.(h1 . t).|| = ||.(a * (f1 . t)).|| by Th42;
A16: ||.(a * (f1 . t)).|| = (abs a) * ||.(f1 . t).|| by NORMSP_1:def 2;
A17: ||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th38;
0 <= ||.f.|| by Th39;
then ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A14, XREAL_1:66;
then A18: ||.(f1 . t).|| <= ||.f.|| by A17, XXREAL_0:2;
0 <= abs a by COMPLEX1:132;
hence ||.(h1 . t).|| <= (abs a) * ||.f.|| by A15, A16, A18, XREAL_1:66; :: thesis: verum
end;
A19: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= (abs a) * ||.f.|| )
assume A20: r in PreNorms h1 ; :: thesis: r <= (abs a) * ||.f.||
consider t being VECTOR of X such that
A21: ( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) by A20;
thus r <= (abs a) * ||.f.|| by A13, A21; :: thesis: verum
end;
A22: ( ( for s being real number st s in PreNorms h1 holds
s <= (abs a) * ||.f.|| ) implies sup (PreNorms h1) <= (abs a) * ||.f.|| ) by SEQ_4:62;
(BoundedLinearOperatorsNorm X,Y) . (a * f) = sup (PreNorms h1) by Th36;
then A23: ||.(a * f).|| <= (abs a) * ||.f.|| by A19, A22, NORMSP_1:def 1;
now
per cases ( a <> 0 or a = 0 ) ;
case A24: a <> 0 ; :: thesis: (abs a) * ||.f.|| <= ||.(a * f).||
A25: now
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).|| )
assume A26: ||.t.|| <= 1 ; :: thesis: ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).||
h1 . t = a * (f1 . t) by Th42;
then A27: (a " ) * (h1 . t) = ((a " ) * a) * (f1 . t) by RLVECT_1:def 9
.= 1 * (f1 . t) by A24, XCMPLX_0:def 7
.= f1 . t by RLVECT_1:def 9 ;
A28: ||.((a " ) * (h1 . t)).|| = (abs (a " )) * ||.(h1 . t).|| by NORMSP_1:def 2;
A29: ||.(h1 . t).|| <= ||.(a * f).|| * ||.t.|| by Th38;
0 <= ||.(a * f).|| by Th39;
then ||.(a * f).|| * ||.t.|| <= ||.(a * f).|| * 1 by A26, XREAL_1:66;
then A30: ||.(h1 . t).|| <= ||.(a * f).|| by A29, XXREAL_0:2;
A31: 0 <= abs (a " ) by COMPLEX1:132;
abs (a " ) = abs (1 * (a " ))
.= abs (1 / a) by XCMPLX_0:def 9
.= 1 / (abs a) by ABSVALUE:15
.= 1 * ((abs a) " ) by XCMPLX_0:def 9
.= (abs a) " ;
hence ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).|| by A27, A28, A30, A31, XREAL_1:66; :: thesis: verum
end;
A32: now
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= ((abs a) " ) * ||.(a * f).|| )
assume A33: r in PreNorms f1 ; :: thesis: r <= ((abs a) " ) * ||.(a * f).||
consider t being VECTOR of X such that
A34: ( r = ||.(f1 . t).|| & ||.t.|| <= 1 ) by A33;
thus r <= ((abs a) " ) * ||.(a * f).|| by A25, A34; :: thesis: verum
end;
A35: abs a <> 0 by A24, COMPLEX1:133;
A36: ( ( for s being real number st s in PreNorms f1 holds
s <= ((abs a) " ) * ||.(a * f).|| ) implies sup (PreNorms f1) <= ((abs a) " ) * ||.(a * f).|| ) by SEQ_4:62;
(BoundedLinearOperatorsNorm X,Y) . f = sup (PreNorms f1) by Th36;
then A37: ||.f.|| <= ((abs a) " ) * ||.(a * f).|| by A32, A36, NORMSP_1:def 1;
0 <= abs a by COMPLEX1:132;
then (abs a) * ||.f.|| <= (abs a) * (((abs a) " ) * ||.(a * f).||) by A37, XREAL_1:66;
then (abs a) * ||.f.|| <= ((abs a) * ((abs a) " )) * ||.(a * f).|| ;
then (abs a) * ||.f.|| <= 1 * ||.(a * f).|| by A35, XCMPLX_0:def 7;
hence (abs a) * ||.f.|| <= ||.(a * f).|| ; :: thesis: verum
end;
end;
end;
hence ||.(a * f).|| = (abs a) * ||.f.|| by A23, XXREAL_0:1; :: thesis: verum
end;
||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as bounded LinearOperator of X,Y by Def10;
A40: now
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= ||.f.|| + ||.g.|| )
assume A41: ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
A42: ||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| by Th41;
A43: ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| by NORMSP_1:def 2;
A44: ||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th38;
||.(g1 . t).|| <= ||.g.|| * ||.t.|| by Th38;
then A45: ||.(f1 . t).|| + ||.(g1 . t).|| <= (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) by A44, XREAL_1:9;
0 <= ||.f.|| by Th39;
then A46: ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A41, XREAL_1:66;
0 <= ||.g.|| by Th39;
then ||.g.|| * ||.t.|| <= ||.g.|| * 1 by A41, XREAL_1:66;
then (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) <= (||.f.|| * 1) + (||.g.|| * 1) by A46, XREAL_1:9;
then ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by A45, XXREAL_0:2;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A42, A43, XXREAL_0:2; :: thesis: verum
end;
A47: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume A48: r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
consider t being VECTOR of X such that
A49: ( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) by A48;
thus r <= ||.f.|| + ||.g.|| by A40, A49; :: thesis: verum
end;
A50: ( ( for s being real number st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies sup (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:62;
(BoundedLinearOperatorsNorm X,Y) . (f + g) = sup (PreNorms h1) by Th36;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A47, A50, NORMSP_1:def 1; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A3, A12; :: thesis: verum