let X, Y be RealLinearSpace; :: thesis: LinearOperators X,Y is linearly-closed
set W = LinearOperators X,Y;
A1: for v, u being VECTOR of (RealVectSpace the carrier of X,Y) st v in LinearOperators X,Y & u in LinearOperators X,Y holds
v + u in LinearOperators X,Y

proof

let v, u be VECTOR of (RealVectSpace the carrier of X,Y); :: thesis: ( v in LinearOperators X,Y & u in LinearOperators X,Y implies v + u in LinearOperators X,Y )
assume A2: ( v in LinearOperators X,Y & u in LinearOperators X,Y ) ; :: thesis: v + u in LinearOperators X,Y
v + u is LinearOperator of X,Y

proof

reconsider f = v + u as Function of X,Y by FUNCT_2:121;
f is LinearOperator of X,Y

proof

A3: f is additive

proof

let x, y be VECTOR of X; :: according to LOPBAN_1:def 5 :: thesis: f . (x + y) = (f . x) + (f . y)
reconsider v' = v, u' = u as Element of Funcs the carrier of X,the carrier of Y ;
A4: u' is LinearOperator of X,Y by A2, Def7;
A5: v' is LinearOperator of X,Y by A2, Def7;
thus f . (x + y) = (u' . (x + y)) + (v' . (x + y)) by Th3
.= ((u' . x) + (u' . y)) + (v' . (x + y)) by A4, Def5
.= ((u' . x) + (u' . y)) + ((v' . x) + (v' . y)) by A5, Def5
.= (((u' . x) + (u' . y)) + (v' . x)) + (v' . y) by RLVECT_1:def 6
.= (((u' . x) + (v' . x)) + (u' . y)) + (v' . y) by RLVECT_1:def 6
.= ((f . x) + (u' . y)) + (v' . y) by Th3
.= (f . x) + ((u' . y) + (v' . y)) by RLVECT_1:def 6
.= (f . x) + (f . y) by Th3 ; :: thesis: verum

end;

f is homogeneous

proof

let x be VECTOR of X; :: according to LOPBAN_1:def 6 :: thesis: for r being Real holds f . (r * x) = r * (f . x)
let s be Real; :: thesis: f . (s * x) = s * (f . x)
reconsider v' = v, u' = u as Element of Funcs the carrier of X,the carrier of Y ;
A6: u' is LinearOperator of X,Y by A2, Def7;
A7: v' is LinearOperator of X,Y by A2, Def7;
thus f . (s * x) = (u' . (s * x)) + (v' . (s * x)) by Th3
.= (s * (u' . x)) + (v' . (s * x)) by A6, Def6
.= (s * (u' . x)) + (s * (v' . x)) by A7, Def6
.= s * ((u' . x) + (v' . x)) by RLVECT_1:def 9
.= s * (f . x) by Th3 ; :: thesis: verum

end;

hence f is LinearOperator of X,Y by A3; :: thesis: verum

end;

hence v + u is LinearOperator of X,Y ; :: thesis: verum

end;

hence v + u in LinearOperators X,Y by Def7; :: thesis: verum

end;

for a being Real
for v being VECTOR of (RealVectSpace the carrier of X,Y) st v in LinearOperators X,Y holds
a * v in LinearOperators X,Y

proof

let a be Real; :: thesis: for v being VECTOR of (RealVectSpace the carrier of X,Y) st v in LinearOperators X,Y holds
a * v in LinearOperators X,Y
let v be VECTOR of (RealVectSpace the carrier of X,Y); :: thesis: ( v in LinearOperators X,Y implies a * v in LinearOperators X,Y )
assume A8: v in LinearOperators X,Y ; :: thesis: a * v in LinearOperators X,Y
a * v is LinearOperator of X,Y

proof

reconsider f = a * v as Function of X,Y by FUNCT_2:121;
f is LinearOperator of X,Y

proof

A9: f is additive

proof

let x, y be VECTOR of X; :: according to LOPBAN_1:def 5 :: thesis: f . (x + y) = (f . x) + (f . y)
reconsider v' = v as Element of Funcs the carrier of X,the carrier of Y ;
A10: v' is LinearOperator of X,Y by A8, Def7;
thus f . (x + y) = a * (v' . (x + y)) by Th5
.= a * ((v' . x) + (v' . y)) by A10, Def5
.= (a * (v' . x)) + (a * (v' . y)) by RLVECT_1:def 9
.= (f . x) + (a * (v' . y)) by Th5
.= (f . x) + (f . y) by Th5 ; :: thesis: verum

end;

f is homogeneous

proof

let x be VECTOR of X; :: according to LOPBAN_1:def 6 :: thesis: for r being Real holds f . (r * x) = r * (f . x)
let s be Real; :: thesis: f . (s * x) = s * (f . x)
reconsider v' = v as Element of Funcs the carrier of X,the carrier of Y ;
A11: v' is LinearOperator of X,Y by A8, Def7;
thus f . (s * x) = a * (v' . (s * x)) by Th5
.= a * (s * (v' . x)) by A11, Def6
.= (a * s) * (v' . x) by RLVECT_1:def 9
.= s * (a * (v' . x)) by RLVECT_1:def 9
.= s * (f . x) by Th5 ; :: thesis: verum

end;

hence f is LinearOperator of X,Y by A9; :: thesis: verum

end;

hence a * v is LinearOperator of X,Y ; :: thesis: verum

end;

hence a * v in LinearOperators X,Y by Def7; :: thesis: verum

end;

hence LinearOperators X,Y is linearly-closed by A1, RLSUB_1:def 1; :: thesis: verum