let R be domRing; :: thesis: for V being LeftMod of R
for L being Linear_Combination of V
for a being Scalar of R holds Sum (a * L) = a * (Sum L)
let V be LeftMod of R; :: thesis: for L being Linear_Combination of V
for a being Scalar of R holds Sum (a * L) = a * (Sum L)
let L be Linear_Combination of V; :: thesis: for a being Scalar of R holds Sum (a * L) = a * (Sum L)
let a be Scalar of R; :: thesis: Sum (a * L) = a * (Sum L)

per cases ( a <> 0. R or a = 0. R ) ;

suppose A1: a <> 0. R ; :: thesis: Sum (a * L) = a * (Sum L)

consider F being FinSequence of the carrier of V such that
A2: F is one-to-one and
A3: rng F = Carrier (a * L) and
A4: Sum (a * L) = Sum ((a * L) (#) F) by VECTSP_6:def 9;
consider G being FinSequence of the carrier of V such that
A5: G is one-to-one and
A6: rng G = Carrier L and
A7: Sum L = Sum (L (#) G) by VECTSP_6:def 9;
set g = L (#) G;
set f = (a * L) (#) F;
set l = a * L;
deffunc H₁( Nat) -> set = F <- (G . $1);
consider P being FinSequence such that
A8: len P = len F and
A9: for k being Nat st k in dom P holds
P . k = H₁(k) from FINSEQ_1:sch 2();
A10: Seg (len F) = dom F by FINSEQ_1:def 3;
A11: dom P = dom F by A8, FINSEQ_3:31;
A12: Carrier (a * L) = Carrier L by A1, Th7;
A13: len G = len F by A1, A2, A3, A5, A6, Th7, FINSEQ_1:65;
A14: rng P c= dom F

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng P or x in dom F )
assume x in rng P ; :: thesis: x in dom F
then consider y being set such that
A15: y in dom P and
A16: P . y = x by FUNCT_1:def 5;
reconsider y = y as Element of NAT by A15;
A17: y in dom F by A8, A15, FINSEQ_3:31;
y in dom G by A8, A13, A15, FINSEQ_3:31;
then G . y in rng F by A3, A6, A12, FUNCT_1:def 5;
then ( P . y = F <- (G . y) & F just_once_values G . y ) by A2, A9, A17, A11, FINSEQ_4:10;
hence x in dom F by A16, FINSEQ_4:def 3; :: thesis: verum

end;

A18: now

let x be set ; :: thesis: ( ( x in dom G implies ( x in dom P & P . x in dom F ) ) & ( x in dom P & P . x in dom F implies x in dom G ) )
thus ( x in dom G implies ( x in dom P & P . x in dom F ) ) :: thesis: ( x in dom P & P . x in dom F implies x in dom G )

proof

assume x in dom G ; :: thesis: ( x in dom P & P . x in dom F )
hence x in dom P by A8, A13, FINSEQ_3:31; :: thesis: P . x in dom F
then ( rng P c= dom F & P . x in rng P ) by A14, FUNCT_1:def 5;
hence P . x in dom F ; :: thesis: verum

end;

assume ( x in dom P & P . x in dom F ) ; :: thesis: x in dom G
hence x in dom G by A8, A13, FINSEQ_3:31; :: thesis: verum

end;

now

let x be set ; :: thesis: ( x in dom G implies G . x = F . (P . x) )
assume A19: x in dom G ; :: thesis: G . x = F . (P . x)
then reconsider n = x as Element of NAT ;
G . n in rng F by A3, A6, A12, A19, FUNCT_1:def 5;
then A20: F just_once_values G . n by A2, FINSEQ_4:10;
n in Seg (len F) by A13, A19, FINSEQ_1:def 3;
then F . (P . n) = F . (F <- (G . n)) by A9, A11, A10
.= G . n by A20, FINSEQ_4:def 3 ;
hence G . x = F . (P . x) ; :: thesis: verum

end;

then A21: G = F * P by A18, FUNCT_1:20;
dom F c= rng P

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in dom F or x in rng P )
assume A22: x in dom F ; :: thesis: x in rng P
set f = (F " ) * G;
dom (F " ) = rng G by A2, A3, A6, A12, FUNCT_1:55;
then A23: rng ((F " ) * G) = rng (F " ) by RELAT_1:47
.= dom F by A2, FUNCT_1:55 ;
(F " ) * G = ((F " ) * F) * P by A21, RELAT_1:55
.= (id (dom F)) * P by A2, FUNCT_1:61
.= P by A14, RELAT_1:79 ;
hence x in rng P by A22, A23; :: thesis: verum

end;

then A24: dom F = rng P by A14, XBOOLE_0:def 10;
A25: dom P = dom F by A8, FINSEQ_3:31;
then A26: P is one-to-one by A24, FINSEQ_4:75;
( dom F = {} implies dom F = {} ) ;
then reconsider P = P as Function of (dom F),(dom F) by A14, A25, FUNCT_2:def 1, RELSET_1:11;
A27: len ((a * L) (#) F) = len F by VECTSP_6:def 8;
then A28: dom ((a * L) (#) F) = dom F by FINSEQ_3:31;
then reconsider P = P as Function of (dom ((a * L) (#) F)),(dom ((a * L) (#) F)) ;
reconsider Fp = ((a * L) (#) F) * P as FinSequence of the carrier of V by FINSEQ_2:51;
reconsider P = P as Permutation of (dom ((a * L) (#) F)) by A24, A26, A28, FUNCT_2:83;
A29: Fp = ((a * L) (#) F) * P ;
then A30: Sum Fp = Sum ((a * L) (#) F) by RLVECT_2:9;
A31: len Fp = len ((a * L) (#) F) by A29, FINSEQ_2:48;
then A32: len Fp = len (L (#) G) by A13, A27, VECTSP_6:def 8;

now

let k be Element of NAT ; :: thesis: for v being Vector of V st k in dom Fp & v = (L (#) G) . k holds
Fp . k = a * v
let v be Vector of V; :: thesis: ( k in dom Fp & v = (L (#) G) . k implies Fp . k = a * v )
assume that
A33: k in dom Fp and
A34: v = (L (#) G) . k ; :: thesis: Fp . k = a * v
A35: k in Seg (len (L (#) G)) by A32, A33, FINSEQ_1:def 3;
then A36: k in dom G by A13, A27, A31, A32, FINSEQ_1:def 3;
then G . k in rng G by FUNCT_1:def 5;
then F just_once_values G . k by A2, A3, A6, A12, FINSEQ_4:10;
then A37: F <- (G . k) in dom F by FINSEQ_4:def 3;
then reconsider i = F <- (G . k) as Element of NAT ;
A38: k in dom (L (#) G) by A35, FINSEQ_1:def 3;
A39: k in dom P by A8, A27, A31, A32, A35, FINSEQ_1:def 3;
A40: G /. k = G . k by A36, PARTFUN1:def 8
.= F . (P . k) by A21, A39, FUNCT_1:23
.= F . i by A9, A27, A31, A32, A35, A11, A10
.= F /. i by A37, PARTFUN1:def 8 ;
i in Seg (len ((a * L) (#) F)) by A27, A37, FINSEQ_1:def 3;
then A41: i in dom ((a * L) (#) F) by FINSEQ_1:def 3;
thus Fp . k = ((a * L) (#) F) . (P . k) by A39, FUNCT_1:23
.= ((a * L) (#) F) . (F <- (G . k)) by A9, A27, A31, A32, A35, A11, A10
.= ((a * L) . (F /. i)) * (F /. i) by A41, VECTSP_6:def 8
.= (a * (L . (F /. i))) * (F /. i) by VECTSP_6:def 12
.= a * ((L . (F /. i)) * (F /. i)) by VECTSP_1:def 26
.= a * v by A34, A38, A40, VECTSP_6:def 8 ; :: thesis: verum

end;

hence Sum (a * L) = a * (Sum L) by A4, A7, A30, A32, VECTSP_3:9; :: thesis: verum

end;

suppose A42: a = 0. R ; :: thesis: Sum (a * L) = a * (Sum L)

hence Sum (a * L) = Sum (ZeroLC V) by VECTSP_6:60
.= 0. V by VECTSP_6:41
.= a * (Sum L) by A42, VECTSP_1:59 ;
:: thesis: verum

end;

end;