let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: ( f1 is convergent_in-infty & f2 is_left_divergent_to-infty_in lim_in-infty f1 & ( for r being Real ex g being Real st
( g < r & g in dom (f2 * f1) ) ) & ex r being Real st
for g being Real st g in (dom f1) /\ (left_open_halfline r) holds
f1 . g < lim_in-infty f1 implies f2 * f1 is divergent_in-infty_to-infty )
assume A1: ( f1 is convergent_in-infty & f2 is_left_divergent_to-infty_in lim_in-infty f1 & ( for r being Real ex g being Real st
( g < r & g in dom (f2 * f1) ) ) ) ; :: thesis: ( for r being Real ex g being Real st
( g in (dom f1) /\ (left_open_halfline r) & not f1 . g < lim_in-infty f1 ) or f2 * f1 is divergent_in-infty_to-infty )
given r being Real such that A2: for g being Real st g in (dom f1) /\ (left_open_halfline r) holds
f1 . g < lim_in-infty f1 ; :: thesis: f2 * f1 is divergent_in-infty_to-infty

now

let s be Real_Sequence; :: thesis: ( s is divergent_to-infty & rng s c= dom (f2 * f1) implies (f2 * f1) /* s is divergent_to-infty )
assume A3: ( s is divergent_to-infty & rng s c= dom (f2 * f1) ) ; :: thesis: (f2 * f1) /* s is divergent_to-infty
then consider k being Element of NAT such that
A4: for n being Element of NAT st k <= n holds
s . n < r by LIMFUNC1:def 5;
set q = s ^\ k;
A5: s ^\ k is divergent_to-infty by A3, LIMFUNC1:54;
A6: ( rng s c= dom f1 & rng (f1 /* s) c= dom f2 ) by A3, Lm2;
A7: rng (s ^\ k) c= rng s by VALUED_0:21;
then rng (s ^\ k) c= dom f1 by A6, XBOOLE_1:1;
then A8: ( f1 /* (s ^\ k) is convergent & lim (f1 /* (s ^\ k)) = lim_in-infty f1 ) by A1, A5, LIMFUNC1:def 13;
rng (f1 /* (s ^\ k)) c= (dom f2) /\ (left_open_halfline (lim_in-infty f1))

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng (f1 /* (s ^\ k)) or x in (dom f2) /\ (left_open_halfline (lim_in-infty f1)) )
assume x in rng (f1 /* (s ^\ k)) ; :: thesis: x in (dom f2) /\ (left_open_halfline (lim_in-infty f1))
then consider n being Element of NAT such that
A9: (f1 /* (s ^\ k)) . n = x by FUNCT_2:190;
A10: x = f1 . ((s ^\ k) . n) by A6, A7, A9, FUNCT_2:185, XBOOLE_1:1
.= f1 . (s . (n + k)) by NAT_1:def 3 ;
(f1 /* s) . (n + k) in rng (f1 /* s) by VALUED_0:28;
then (f1 /* s) . (n + k) in dom f2 by A6;
then A11: x in dom f2 by A6, A10, FUNCT_2:185;
s . (n + k) < r by A4, NAT_1:12;
then s . (n + k) in { r2 where r2 is Real : r2 < r } ;
then A12: s . (n + k) in left_open_halfline r by XXREAL_1:229;
s . (n + k) in rng s by VALUED_0:28;
then s . (n + k) in (dom f1) /\ (left_open_halfline r) by A6, A12, XBOOLE_0:def 4;
then f1 . (s . (n + k)) < lim_in-infty f1 by A2;
then x in { g1 where g1 is Real : g1 < lim_in-infty f1 } by A10;
then x in left_open_halfline (lim_in-infty f1) by XXREAL_1:229;
hence x in (dom f2) /\ (left_open_halfline (lim_in-infty f1)) by A11, XBOOLE_0:def 4; :: thesis: verum

end;

then A13: f2 /* (f1 /* (s ^\ k)) is divergent_to-infty by A1, A8, LIMFUNC2:def 3;
f2 /* (f1 /* (s ^\ k)) = f2 /* ((f1 /* s) ^\ k) by A6, VALUED_0:27
.= (f2 /* (f1 /* s)) ^\ k by A6, VALUED_0:27
.= ((f2 * f1) /* s) ^\ k by A3, VALUED_0:31 ;
hence (f2 * f1) /* s is divergent_to-infty by A13, LIMFUNC1:34; :: thesis: verum

end;

hence f2 * f1 is divergent_in-infty_to-infty by A1, LIMFUNC1:def 11; :: thesis: verum