let x0 be Real; :: thesis: for f being PartFunc of REAL ,REAL st ( f is_left_divergent_to+infty_in x0 or f is_left_divergent_to-infty_in x0 ) holds
abs f is_left_divergent_to+infty_in x0
let f be PartFunc of REAL ,REAL ; :: thesis: ( ( f is_left_divergent_to+infty_in x0 or f is_left_divergent_to-infty_in x0 ) implies abs f is_left_divergent_to+infty_in x0 )
assume A1: ( f is_left_divergent_to+infty_in x0 or f is_left_divergent_to-infty_in x0 ) ; :: thesis: abs f is_left_divergent_to+infty_in x0

now

per cases ( f is_left_divergent_to+infty_in x0 or f is_left_divergent_to-infty_in x0 ) by A1;

suppose A2: f is_left_divergent_to+infty_in x0 ; :: thesis: abs f is_left_divergent_to+infty_in x0

A3: now

let r be Real; :: thesis: ( r < x0 implies ex g being Real st
( r < g & g < x0 & g in dom (abs f) ) )
assume r < x0 ; :: thesis: ex g being Real st
( r < g & g < x0 & g in dom (abs f) )
then consider g being Real such that
A4: ( r < g & g < x0 & g in dom f ) by A2, Def2;
take g = g; :: thesis: ( r < g & g < x0 & g in dom (abs f) )
thus ( r < g & g < x0 & g in dom (abs f) ) by A4, VALUED_1:def 11; :: thesis: verum

end;

now

let seq be Real_Sequence; :: thesis: ( seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) /\ (left_open_halfline x0) implies (abs f) /* seq is divergent_to+infty )
assume A5: ( seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) /\ (left_open_halfline x0) ) ; :: thesis: (abs f) /* seq is divergent_to+infty
then A6: rng seq c= (dom f) /\ (left_open_halfline x0) by VALUED_1:def 11;
then f /* seq is divergent_to+infty by A2, A5, Def2;
then A7: abs (f /* seq) is divergent_to+infty by LIMFUNC1:52;
(dom f) /\ (left_open_halfline x0) c= dom f by XBOOLE_1:17;
then rng seq c= dom f by A6, XBOOLE_1:1;
hence (abs f) /* seq is divergent_to+infty by A7, RFUNCT_2:25; :: thesis: verum

end;

hence abs f is_left_divergent_to+infty_in x0 by A3, Def2; :: thesis: verum

end;

suppose A8: f is_left_divergent_to-infty_in x0 ; :: thesis: abs f is_left_divergent_to+infty_in x0

A9: now

let r be Real; :: thesis: ( r < x0 implies ex g being Real st
( r < g & g < x0 & g in dom (abs f) ) )
assume r < x0 ; :: thesis: ex g being Real st
( r < g & g < x0 & g in dom (abs f) )
then consider g being Real such that
A10: ( r < g & g < x0 & g in dom f ) by A8, Def3;
take g = g; :: thesis: ( r < g & g < x0 & g in dom (abs f) )
thus ( r < g & g < x0 & g in dom (abs f) ) by A10, VALUED_1:def 11; :: thesis: verum

end;

now

let seq be Real_Sequence; :: thesis: ( seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) /\ (left_open_halfline x0) implies (abs f) /* seq is divergent_to+infty )
assume A11: ( seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) /\ (left_open_halfline x0) ) ; :: thesis: (abs f) /* seq is divergent_to+infty
then A12: rng seq c= (dom f) /\ (left_open_halfline x0) by VALUED_1:def 11;
then f /* seq is divergent_to-infty by A8, A11, Def3;
then A13: abs (f /* seq) is divergent_to+infty by LIMFUNC1:52;
(dom f) /\ (left_open_halfline x0) c= dom f by XBOOLE_1:17;
then rng seq c= dom f by A12, XBOOLE_1:1;
hence (abs f) /* seq is divergent_to+infty by A13, RFUNCT_2:25; :: thesis: verum

end;

hence abs f is_left_divergent_to+infty_in x0 by A9, Def2; :: thesis: verum

end;

end;

end;

hence abs f is_left_divergent_to+infty_in x0 ; :: thesis: verum