let A be non empty set ; :: thesis: for L being lower-bounded LATTICE
for O being Ordinal
for d being BiFunction of A,L
for q being QuadrSeq of d holds d c= ConsecutiveDelta q,O
let L be lower-bounded LATTICE; :: thesis: for O being Ordinal
for d being BiFunction of A,L
for q being QuadrSeq of d holds d c= ConsecutiveDelta q,O
let O be Ordinal; :: thesis: for d being BiFunction of A,L
for q being QuadrSeq of d holds d c= ConsecutiveDelta q,O
let d be BiFunction of A,L; :: thesis: for q being QuadrSeq of d holds d c= ConsecutiveDelta q,O
let q be QuadrSeq of d; :: thesis: d c= ConsecutiveDelta q,O
defpred S₁[ Ordinal] means d c= ConsecutiveDelta q,$1;
A1: S₁[ {} ] by Th29;
A2: for O1 being Ordinal st S₁[O1] holds
S₁[ succ O1]

proof

let O1 be Ordinal; :: thesis: ( S₁[O1] implies S₁[ succ O1] )
assume A3: d c= ConsecutiveDelta q,O1 ; :: thesis: S₁[ succ O1]
ConsecutiveDelta q,(succ O1) = new_bi_fun (BiFun (ConsecutiveDelta q,O1),(ConsecutiveSet A,O1),L),(Quadr q,O1) by Th30
.= new_bi_fun (ConsecutiveDelta q,O1),(Quadr q,O1) by Def16 ;
then ConsecutiveDelta q,O1 c= ConsecutiveDelta q,(succ O1) by Th22;
hence S₁[ succ O1] by A3, XBOOLE_1:1; :: thesis: verum

end;

A4: for O2 being Ordinal st O2 <> {} & O2 is limit_ordinal & ( for O1 being Ordinal st O1 in O2 holds
S₁[O1] ) holds
S₁[O2]

proof

let O2 be Ordinal; :: thesis: ( O2 <> {} & O2 is limit_ordinal & ( for O1 being Ordinal st O1 in O2 holds
S₁[O1] ) implies S₁[O2] )
assume A5: ( O2 <> {} & O2 is limit_ordinal & ( for O1 being Ordinal st O1 in O2 holds
d c= ConsecutiveDelta q,O1 ) ) ; :: thesis: S₁[O2]
deffunc H₁( Ordinal) -> BiFunction of (ConsecutiveSet A,$1),L = ConsecutiveDelta q,$1;
consider Ls being T-Sequence such that
A6: ( dom Ls = O2 & ( for O1 being Ordinal st O1 in O2 holds
Ls . O1 = H₁(O1) ) ) from ORDINAL2:sch 2();
A7: ConsecutiveDelta q,O2 = union (rng Ls) by A5, A6, Th31;
A8: {} in O2 by A5, ORDINAL3:10;
then Ls . {} = ConsecutiveDelta q,{} by A6
.= d by Th29 ;
then d in rng Ls by A6, A8, FUNCT_1:def 5;
hence S₁[O2] by A7, ZFMISC_1:92; :: thesis: verum

end;

for O being Ordinal holds S₁[O] from ORDINAL2:sch 1(A1, A2, A4);
hence d c= ConsecutiveDelta q,O ; :: thesis: verum