let C be Simple_closed_curve; :: thesis: for i, j, k, n being Element of NAT st n is_sufficiently_large_for C & 1 <= k & k <= len (Span C,n) & [i,j] in Indices (Gauge C,n) & (Span C,n) /. k = (Gauge C,n) * i,j holds
i < len (Gauge C,n)
let i, j, k, n be Element of NAT ; :: thesis: ( n is_sufficiently_large_for C & 1 <= k & k <= len (Span C,n) & [i,j] in Indices (Gauge C,n) & (Span C,n) /. k = (Gauge C,n) * i,j implies i < len (Gauge C,n) )
assume that
A1: n is_sufficiently_large_for C and
A2: ( 1 <= k & k <= len (Span C,n) ) and
A3: [i,j] in Indices (Gauge C,n) and
A4: (Span C,n) /. k = (Gauge C,n) * i,j ; :: thesis: i < len (Gauge C,n)
A5: ( 1 <= i & i <= len (Gauge C,n) & 1 <= j & j <= width (Gauge C,n) ) by A3, MATRIX_1:39;
len (Gauge C,n) = width (Gauge C,n) by JORDAN8:def 1;
then A6: ((Gauge C,n) * ((len (Gauge C,n)) -' 1),j) `1 = E-bound C by A5, JORDAN8:15;
SpanStart C,n in BDD C by A1, Th7;
then A7: E-bound C >= E-bound (BDD C) by JORDAN1C:19;
A8: BDD C is Bounded by JORDAN2C:114;
then A9: Cl (BDD C) is compact by TOPREAL6:71, TOPREAL6:88;
A10: BDD C c= Cl (BDD C) by PRE_TOPC:48;
L~ (Span C,n) c= BDD C by A1, Th22;
then A11: E-bound (L~ (Span C,n)) <= E-bound (Cl (BDD C)) by A9, A10, PSCOMP_1:130, XBOOLE_1:1;
SpanStart C,n in BDD C by A1, Th7;
then A12: E-bound (BDD C) = E-bound (Cl (BDD C)) by A8, TOPREAL6:95;
A13: len (Gauge C,n) >= 4 by JORDAN8:13;
then len (Gauge C,n) >= 0 + 1 by XXREAL_0:2;
then A14: (len (Gauge C,n)) - 1 >= 0 by XREAL_1:21;
len (Gauge C,n) >= 1 + 1 by A13, XXREAL_0:2;
then (len (Gauge C,n)) - 1 >= 1 by XREAL_1:21;
then A15: (len (Gauge C,n)) -' 1 >= 1 by A14, XREAL_0:def 2;
A16: len (Span C,n) > 4 by GOBOARD7:36;
k in dom (Span C,n) by A2, FINSEQ_3:27;
then (Span C,n) /. k in L~ (Span C,n) by A16, GOBOARD1:16, XXREAL_0:2;
then E-bound (L~ (Span C,n)) >= ((Gauge C,n) * i,j) `1 by A4, PSCOMP_1:71;
then E-bound (BDD C) >= ((Gauge C,n) * i,j) `1 by A11, A12, XXREAL_0:2;
then ((Gauge C,n) * ((len (Gauge C,n)) -' 1),j) `1 >= ((Gauge C,n) * i,j) `1 by A6, A7, XXREAL_0:2;
then i <= (len (Gauge C,n)) -' 1 by A5, A15, GOBOARD5:4;
then i < ((len (Gauge C,n)) -' 1) + 1 by NAT_1:13;
hence i < len (Gauge C,n) by A13, XREAL_1:237, XXREAL_0:2; :: thesis: verum