let a, b, c, d be real number ; :: thesis: for p1, p2 being Point of (TOP-REAL 2) st a < b & c < d & p1 in LSeg |[a,c]|,|[b,c]| & p2 in LSeg |[a,c]|,|[b,c]| holds
( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) iff ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) ) )
let p1, p2 be Point of (TOP-REAL 2); :: thesis: ( a < b & c < d & p1 in LSeg |[a,c]|,|[b,c]| & p2 in LSeg |[a,c]|,|[b,c]| implies ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) iff ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) ) ) )
set K = rectangle a,b,c,d;
assume A1: ( a < b & c < d & p1 in LSeg |[a,c]|,|[b,c]| & p2 in LSeg |[a,c]|,|[b,c]| ) ; :: thesis: ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) iff ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) ) )
then A2: rectangle a,b,c,d is being_simple_closed_curve by Th60;
A3: ( p1 `2 = c & a <= p1 `1 & p1 `1 <= b ) by A1, Th11;
A4: ( p2 `2 = c & a <= p2 `1 & p2 `1 <= b ) by A1, Th11;
A5: W-min (rectangle a,b,c,d) = |[a,c]| by A1, Th56;
A6: E-max (rectangle a,b,c,d) = |[b,d]| by A1, Th56;
A7: Lower_Arc (rectangle a,b,c,d) = (LSeg |[b,d]|,|[b,c]|) \/ (LSeg |[b,c]|,|[a,c]|) by A1, Th62;
then A8: LSeg |[b,c]|,|[a,c]| c= Lower_Arc (rectangle a,b,c,d) by XBOOLE_1:7;
then A9: p1 in Lower_Arc (rectangle a,b,c,d) by A1;
A10: Lower_Arc (rectangle a,b,c,d) c= rectangle a,b,c,d by A2, JORDAN6:76;
A11: (Upper_Arc (rectangle a,b,c,d)) /\ (Lower_Arc (rectangle a,b,c,d)) = {(W-min (rectangle a,b,c,d)),(E-max (rectangle a,b,c,d))} by A2, JORDAN6:def 9;
A12: now
assume p1 in Upper_Arc (rectangle a,b,c,d) ; :: thesis: p1 = W-min (rectangle a,b,c,d)
then p1 in (Upper_Arc (rectangle a,b,c,d)) /\ (Lower_Arc (rectangle a,b,c,d)) by A1, A8, XBOOLE_0:def 4;
then ( p1 = W-min (rectangle a,b,c,d) or p1 = E-max (rectangle a,b,c,d) ) by A11, TARSKI:def 2;
hence p1 = W-min (rectangle a,b,c,d) by A1, A3, A6, EUCLID:56; :: thesis: verum
end;
thus ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) implies ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) ) ) :: thesis: ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) implies ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) ) )
proof
assume A13: ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) ) ; :: thesis: ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) )
then A14: ( ( p1 in Upper_Arc (rectangle a,b,c,d) & p2 in Lower_Arc (rectangle a,b,c,d) & not p2 = W-min (rectangle a,b,c,d) ) or ( p1 in Upper_Arc (rectangle a,b,c,d) & p2 in Upper_Arc (rectangle a,b,c,d) & LE p1,p2, Upper_Arc (rectangle a,b,c,d), W-min (rectangle a,b,c,d), E-max (rectangle a,b,c,d) ) or ( p1 in Lower_Arc (rectangle a,b,c,d) & p2 in Lower_Arc (rectangle a,b,c,d) & not p2 = W-min (rectangle a,b,c,d) & LE p1,p2, Lower_Arc (rectangle a,b,c,d), E-max (rectangle a,b,c,d), W-min (rectangle a,b,c,d) ) ) by JORDAN6:def 10;
consider f being Function of I[01] ,((TOP-REAL 2) | (Lower_Arc (rectangle a,b,c,d))) such that
A15: ( f is being_homeomorphism & f . 0 = E-max (rectangle a,b,c,d) & f . 1 = W-min (rectangle a,b,c,d) & rng f = Lower_Arc (rectangle a,b,c,d) & ( for r being Real st r in [.0 ,(1 / 2).] holds
f . r = ((1 - (2 * r)) * |[b,d]|) + ((2 * r) * |[b,c]|) ) & ( for r being Real st r in [.(1 / 2),1.] holds
f . r = ((1 - ((2 * r) - 1)) * |[b,c]|) + (((2 * r) - 1) * |[a,c]|) ) & ( for p being Point of (TOP-REAL 2) st p in LSeg |[b,d]|,|[b,c]| holds
( 0 <= (((p `2 ) - d) / (c - d)) / 2 & (((p `2 ) - d) / (c - d)) / 2 <= 1 & f . ((((p `2 ) - d) / (c - d)) / 2) = p ) ) & ( for p being Point of (TOP-REAL 2) st p in LSeg |[b,c]|,|[a,c]| holds
( 0 <= ((((p `1 ) - b) / (a - b)) / 2) + (1 / 2) & ((((p `1 ) - b) / (a - b)) / 2) + (1 / 2) <= 1 & f . (((((p `1 ) - b) / (a - b)) / 2) + (1 / 2)) = p ) ) ) by A1, Th64;
reconsider s1 = ((((p1 `1 ) - b) / (a - b)) / 2) + (1 / 2), s2 = ((((p2 `1 ) - b) / (a - b)) / 2) + (1 / 2) as Real ;
A16: f . s1 = p1 by A1, A15;
A17: f . s2 = p2 by A1, A15;
b - a > 0 by A1, XREAL_1:52;
then A18: - (b - a) < - 0 by XREAL_1:26;
A19: ( 0 <= s1 & s1 <= 1 ) by A1, A15;
( 0 <= s2 & s2 <= 1 ) by A1, A15;
then s1 <= s2 by A12, A13, A14, A15, A16, A17, A19, JORDAN5C:def 3;
then (((p1 `1 ) - b) / (a - b)) / 2 <= (((p2 `1 ) - b) / (a - b)) / 2 by XREAL_1:8;
then ((((p1 `1 ) - b) / (a - b)) / 2) * 2 <= ((((p2 `1 ) - b) / (a - b)) / 2) * 2 by XREAL_1:66;
then (((p1 `1 ) - b) / (a - b)) * (a - b) >= (((p2 `1 ) - b) / (a - b)) * (a - b) by A18, XREAL_1:67;
then (p1 `1 ) - b >= (((p2 `1 ) - b) / (a - b)) * (a - b) by A18, XCMPLX_1:88;
then (p1 `1 ) - b >= (p2 `1 ) - b by A18, XCMPLX_1:88;
then ((p1 `1 ) - b) + b >= ((p2 `1 ) - b) + b by XREAL_1:9;
hence p1 `1 >= p2 `1 ; :: thesis: p2 <> W-min (rectangle a,b,c,d)
now
assume A20: p2 = W-min (rectangle a,b,c,d) ; :: thesis: contradiction
then LE p2,p1, rectangle a,b,c,d by A2, A9, A10, JORDAN7:3;
hence contradiction by A1, A13, A20, Th60, JORDAN6:72; :: thesis: verum
end;
hence p2 <> W-min (rectangle a,b,c,d) ; :: thesis: verum
end;
thus ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) implies ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) ) ) :: thesis: verum
proof
assume A21: ( p1 `1 >= p2 `1 & p2 <> W-min (rectangle a,b,c,d) ) ; :: thesis: ( LE p1,p2, rectangle a,b,c,d & p1 <> W-min (rectangle a,b,c,d) )
A22: for g being Function of I[01] ,((TOP-REAL 2) | (Lower_Arc (rectangle a,b,c,d)))
for s1, s2 being Real st g is being_homeomorphism & g . 0 = E-max (rectangle a,b,c,d) & g . 1 = W-min (rectangle a,b,c,d) & g . s1 = p1 & 0 <= s1 & s1 <= 1 & g . s2 = p2 & 0 <= s2 & s2 <= 1 holds
s1 <= s2
proof
let g be Function of I[01] ,((TOP-REAL 2) | (Lower_Arc (rectangle a,b,c,d))); :: thesis: for s1, s2 being Real st g is being_homeomorphism & g . 0 = E-max (rectangle a,b,c,d) & g . 1 = W-min (rectangle a,b,c,d) & g . s1 = p1 & 0 <= s1 & s1 <= 1 & g . s2 = p2 & 0 <= s2 & s2 <= 1 holds
s1 <= s2
let s1, s2 be Real; :: thesis: ( g is being_homeomorphism & g . 0 = E-max (rectangle a,b,c,d) & g . 1 = W-min (rectangle a,b,c,d) & g . s1 = p1 & 0 <= s1 & s1 <= 1 & g . s2 = p2 & 0 <= s2 & s2 <= 1 implies s1 <= s2 )
assume A23: ( g is being_homeomorphism & g . 0 = E-max (rectangle a,b,c,d) & g . 1 = W-min (rectangle a,b,c,d) & g . s1 = p1 & 0 <= s1 & s1 <= 1 & g . s2 = p2 & 0 <= s2 & s2 <= 1 ) ; :: thesis: s1 <= s2
A24: dom g = the carrier of I[01] by FUNCT_2:def 1;
A25: g is one-to-one by A23, TOPS_2:def 5;
A26: the carrier of ((TOP-REAL 2) | (Lower_Arc (rectangle a,b,c,d))) = Lower_Arc (rectangle a,b,c,d) by PRE_TOPC:29;
then reconsider g1 = g as Function of I[01] ,(TOP-REAL 2) by FUNCT_2:9;
g is continuous by A23, TOPS_2:def 5;
then A27: g1 is continuous by PRE_TOPC:56;
reconsider h1 = proj1 as Function of (TOP-REAL 2),R^1 by TOPMETR:24;
reconsider h2 = proj2 as Function of (TOP-REAL 2),R^1 by TOPMETR:24;
reconsider hh1 = h1 as Function of TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #),R^1 ;
reconsider hh2 = h2 as Function of TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #),R^1 ;
A28: TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #) = TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #) | ([#] TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #)) by TSEP_1:3
.= TopStruct(# the carrier of ((TOP-REAL 2) | ([#] (TOP-REAL 2))),the topology of ((TOP-REAL 2) | ([#] (TOP-REAL 2))) #) by PRE_TOPC:66
.= (TOP-REAL 2) | ([#] (TOP-REAL 2)) ;
then B24: ( ( for p being Point of ((TOP-REAL 2) | ([#] (TOP-REAL 2))) holds hh1 . p = proj1 . p ) implies hh1 is continuous ) by JGRAPH_2:39;
A29: ( ( for p being Point of ((TOP-REAL 2) | ([#] (TOP-REAL 2))) holds hh1 . p = proj1 . p ) implies h1 is continuous ) by B24, PRE_TOPC:62;
BB: ( ( for p being Point of ((TOP-REAL 2) | ([#] (TOP-REAL 2))) holds hh2 . p = proj2 . p ) implies hh2 is continuous ) by A28, JGRAPH_2:40;
( ( for p being Point of ((TOP-REAL 2) | ([#] (TOP-REAL 2))) holds hh2 . p = proj2 . p ) implies h2 is continuous ) by BB, PRE_TOPC:62;
then consider h being Function of (TOP-REAL 2),R^1 such that
A30: ( ( for p being Point of (TOP-REAL 2)
for r1, r2 being real number st h1 . p = r1 & h2 . p = r2 holds
h . p = r1 + r2 ) & h is continuous ) by A29, JGRAPH_2:29;
reconsider k = h * g1 as Function of I[01] ,R^1 ;
A31: k is continuous Function of I[01] ,R^1 by A27, A30;
A32: E-max (rectangle a,b,c,d) = |[b,d]| by A1, Th56;
now
assume A33: s1 > s2 ; :: thesis: contradiction
A34: dom g = [.0 ,1.] by BORSUK_1:83, FUNCT_2:def 1;
0 in [.0 ,1.] by XXREAL_1:1;
then A35: k . 0 = h . (E-max (rectangle a,b,c,d)) by A23, A34, FUNCT_1:23
.= (h1 . (E-max (rectangle a,b,c,d))) + (h2 . (E-max (rectangle a,b,c,d))) by A30
.= ((E-max (rectangle a,b,c,d)) `1 ) + (proj2 . (E-max (rectangle a,b,c,d))) by PSCOMP_1:def 28
.= ((E-max (rectangle a,b,c,d)) `1 ) + ((E-max (rectangle a,b,c,d)) `2 ) by PSCOMP_1:def 29
.= ((E-max (rectangle a,b,c,d)) `1 ) + d by A32, EUCLID:56
.= b + d by A32, EUCLID:56 ;
s1 in [.0 ,1.] by A23, XXREAL_1:1;
then A36: k . s1 = h . p1 by A23, A34, FUNCT_1:23
.= (proj1 . p1) + (proj2 . p1) by A30
.= (p1 `1 ) + (proj2 . p1) by PSCOMP_1:def 28
.= (p1 `1 ) + c by A3, PSCOMP_1:def 29 ;
A37: s2 in [.0 ,1.] by A23, XXREAL_1:1;
then k . s2 = h . p2 by A23, A34, FUNCT_1:23
.= (h1 . p2) + (h2 . p2) by A30
.= (p2 `1 ) + (proj2 . p2) by PSCOMP_1:def 28
.= (p2 `1 ) + c by A4, PSCOMP_1:def 29 ;
then A38: ( k . 0 >= k . s1 & k . s1 >= k . s2 ) by A1, A3, A21, A35, A36, XREAL_1:9;
A39: 0 in [.0 ,1.] by XXREAL_1:1;
then A40: [.0 ,s2.] c= [.0 ,1.] by A37, XXREAL_2:def 12;
reconsider B = [.0 ,s2.] as Subset of I[01] by A37, A39, BORSUK_1:83, XXREAL_2:def 12;
A41: B is connected by A23, A37, A39, BORSUK_1:83, BORSUK_4:49;
A42: 0 in B by A23, XXREAL_1:1;
A43: s2 in B by A23, XXREAL_1:1;
A44: k . 0 is Real by XREAL_0:def 1;
A45: k . s2 is Real by XREAL_0:def 1;
k . s1 is Real by XREAL_0:def 1;
then consider xc being Point of I[01] such that
A46: ( xc in B & k . xc = k . s1 ) by A31, A38, A41, A42, A43, A44, A45, TOPREAL5:11;
xc in [.0 ,1.] by BORSUK_1:83;
then reconsider rxc = xc as Real ;
A47: k is one-to-one
proof
for x1, x2 being set st x1 in dom k & x2 in dom k & k . x1 = k . x2 holds
x1 = x2
proof
let x1, x2 be set ; :: thesis: ( x1 in dom k & x2 in dom k & k . x1 = k . x2 implies x1 = x2 )
assume A48: ( x1 in dom k & x2 in dom k & k . x1 = k . x2 ) ; :: thesis: x1 = x2
then reconsider r1 = x1 as Point of I[01] ;
reconsider r2 = x2 as Point of I[01] by A48;
A49: k . x1 = h . (g1 . x1) by A48, FUNCT_1:22
.= (h1 . (g1 . r1)) + (h2 . (g1 . r1)) by A30
.= ((g1 . r1) `1 ) + (proj2 . (g1 . r1)) by PSCOMP_1:def 28
.= ((g1 . r1) `1 ) + ((g1 . r1) `2 ) by PSCOMP_1:def 29 ;
A50: k . x2 = h . (g1 . x2) by A48, FUNCT_1:22
.= (h1 . (g1 . r2)) + (h2 . (g1 . r2)) by A30
.= ((g1 . r2) `1 ) + (proj2 . (g1 . r2)) by PSCOMP_1:def 28
.= ((g1 . r2) `1 ) + ((g1 . r2) `2 ) by PSCOMP_1:def 29 ;
A51: g . r1 in Lower_Arc (rectangle a,b,c,d) by A26;
A52: g . r2 in Lower_Arc (rectangle a,b,c,d) by A26;
reconsider gr1 = g . r1 as Point of (TOP-REAL 2) by A51;
reconsider gr2 = g . r2 as Point of (TOP-REAL 2) by A52;
now
per cases ( ( g . r1 in LSeg |[b,d]|,|[b,c]| & g . r2 in LSeg |[b,d]|,|[b,c]| ) or ( g . r1 in LSeg |[b,d]|,|[b,c]| & g . r2 in LSeg |[b,c]|,|[a,c]| ) or ( g . r1 in LSeg |[b,c]|,|[a,c]| & g . r2 in LSeg |[b,d]|,|[b,c]| ) or ( g . r1 in LSeg |[b,c]|,|[a,c]| & g . r2 in LSeg |[b,c]|,|[a,c]| ) ) by A7, A26, XBOOLE_0:def 3;
case A53: ( g . r1 in LSeg |[b,d]|,|[b,c]| & g . r2 in LSeg |[b,d]|,|[b,c]| ) ; :: thesis: x1 = x2
then A54: ( gr1 `1 = b & c <= gr1 `2 & gr1 `2 <= d ) by A1, Th9;
( gr2 `1 = b & c <= gr2 `2 & gr2 `2 <= d ) by A1, A53, Th9;
then |[(gr1 `1 ),(gr1 `2 )]| = g . r2 by A48, A49, A50, A54, EUCLID:57;
then g . r1 = g . r2 by EUCLID:57;
hence x1 = x2 by A24, A25, FUNCT_1:def 8; :: thesis: verum
end;
case A55: ( g . r1 in LSeg |[b,d]|,|[b,c]| & g . r2 in LSeg |[b,c]|,|[a,c]| ) ; :: thesis: x1 = x2
then A56: ( gr1 `1 = b & c <= gr1 `2 & gr1 `2 <= d ) by A1, Th9;
A57: ( gr2 `2 = c & a <= gr2 `1 & gr2 `1 <= b ) by A1, A55, Th11;
A58: b + (gr1 `2 ) = (gr2 `1 ) + c by A1, A48, A49, A50, A55, A56, Th11;
A59: now
assume b <> gr2 `1 ; :: thesis: contradiction
then b > gr2 `1 by A57, XXREAL_0:1;
hence contradiction by A56, A58, XREAL_1:10; :: thesis: verum
end;
then |[(gr1 `1 ),(gr1 `2 )]| = g . r2 by A56, A57, A59, EUCLID:57;
then g . r1 = g . r2 by EUCLID:57;
hence x1 = x2 by A24, A25, FUNCT_1:def 8; :: thesis: verum
end;
case A60: ( g . r1 in LSeg |[b,c]|,|[a,c]| & g . r2 in LSeg |[b,d]|,|[b,c]| ) ; :: thesis: x1 = x2
then A61: ( gr2 `1 = b & c <= gr2 `2 & gr2 `2 <= d ) by A1, Th9;
A62: ( gr1 `2 = c & a <= gr1 `1 & gr1 `1 <= b ) by A1, A60, Th11;
A63: b + (gr2 `2 ) = (gr1 `1 ) + c by A1, A48, A49, A50, A60, A61, Th11;
A64: now
assume b <> gr1 `1 ; :: thesis: contradiction
then b > gr1 `1 by A62, XXREAL_0:1;
hence contradiction by A61, A63, XREAL_1:10; :: thesis: verum
end;
then |[(gr2 `1 ),(gr2 `2 )]| = g . r1 by A61, A62, A64, EUCLID:57;
then g . r1 = g . r2 by EUCLID:57;
hence x1 = x2 by A24, A25, FUNCT_1:def 8; :: thesis: verum
end;
case A65: ( g . r1 in LSeg |[b,c]|,|[a,c]| & g . r2 in LSeg |[b,c]|,|[a,c]| ) ; :: thesis: x1 = x2
then A66: ( gr1 `2 = c & a <= gr1 `1 & gr1 `1 <= b ) by A1, Th11;
( gr2 `2 = c & a <= gr2 `1 & gr2 `1 <= b ) by A1, A65, Th11;
then |[(gr1 `1 ),(gr1 `2 )]| = g . r2 by A48, A49, A50, A66, EUCLID:57;
then g . r1 = g . r2 by EUCLID:57;
hence x1 = x2 by A24, A25, FUNCT_1:def 8; :: thesis: verum
end;
end;
end;
hence x1 = x2 ; :: thesis: verum
end;
hence k is one-to-one by FUNCT_1:def 8; :: thesis: verum
end;
A67: dom k = [.0 ,1.] by BORSUK_1:83, FUNCT_2:def 1;
then s1 in dom k by A23, XXREAL_1:1;
then rxc = s1 by A40, A46, A47, A67, FUNCT_1:def 8;
hence contradiction by A33, A46, XXREAL_1:1; :: thesis: verum
end;
hence s1 <= s2 ; :: thesis: verum
end;
A68: now
assume A69: p1 = W-min (rectangle a,b,c,d) ; :: thesis: contradiction
then ( p1 `1 = a & p1 `2 = c ) by A5, EUCLID:56;
then p1 `1 = p2 `1 by A4, A21, XXREAL_0:1;
then |[(p1 `1 ),(p1 `2 )]| = p2 by A3, A4, EUCLID:57;
hence contradiction by A21, A69, EUCLID:57; :: thesis: verum
end;
( p1 in Lower_Arc (rectangle a,b,c,d) & p2 in Lower_Arc (rectangle a,b,c,d) & not p2 = W-min (rectangle a,b,c,d) & LE p1,p2, Lower_Arc (rectangle a,b,c,d), E-max (rectangle a,b,c,d), W-min (rectangle a,b,c,d) ) by A1, A8, A21, A22, JORDAN5C:def 3;
hence LE p1,p2, rectangle a,b,c,d by JORDAN6:def 10; :: thesis: p1 <> W-min (rectangle a,b,c,d)
thus p1 <> W-min (rectangle a,b,c,d) by A68; :: thesis: verum
end;