let X be non empty TopSpace; :: thesis: for f1 being Function of X,R^1
for a being real number st f1 is continuous holds
ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being real number st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
let f1 be Function of X,R^1 ; :: thesis: for a being real number st f1 is continuous holds
ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being real number st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
let a be real number ; :: thesis: ( f1 is continuous implies ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being real number st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous ) )
assume A1: f1 is continuous ; :: thesis: ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being real number st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous )
defpred S₁[ set , set ] means for r1 being Real st f1 . $1 = r1 holds
$2 = r1 + a;
A2: for x being Element of X ex y being Element of REAL st S₁[x,y]

proof

let x be Element of X; :: thesis: ex y being Element of REAL st S₁[x,y]
reconsider r1 = f1 . x as Real by TOPMETR:24;
reconsider r2 = a as Element of REAL by XREAL_0:def 1;
set r3 = r1 + r2;
for r1 being Real st f1 . x = r1 holds
r1 + r2 = r1 + r2 ;
hence ex y being Element of REAL st
for r1 being Real st f1 . x = r1 holds
y = r1 + a ; :: thesis: verum

end;

ex f being Function of the carrier of X,REAL st
for x being Element of X holds S₁[x,f . x] from FUNCT_2:sch 3(A2);
then consider f being Function of the carrier of X,REAL such that
A3: for x being Element of X
for r1 being Real st f1 . x = r1 holds
f . x = r1 + a ;
reconsider g0 = f as Function of X,R^1 by TOPMETR:24;
A4: for p being Point of X
for r1 being real number st f1 . p = r1 holds
g0 . p = r1 + a

proof

let p be Point of X; :: thesis: for r1 being real number st f1 . p = r1 holds
g0 . p = r1 + a
let r1 be real number ; :: thesis: ( f1 . p = r1 implies g0 . p = r1 + a )
assume A5: f1 . p = r1 ; :: thesis: g0 . p = r1 + a
reconsider r1 = r1 as Element of REAL by XREAL_0:def 1;
g0 . p = r1 + a by A3, A5;
hence g0 . p = r1 + a ; :: thesis: verum

end;

for p being Point of X
for V being Subset of R^1 st g0 . p in V & V is open holds
ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )

proof

let p be Point of X; :: thesis: for V being Subset of R^1 st g0 . p in V & V is open holds
ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )
let V be Subset of R^1 ; :: thesis: ( g0 . p in V & V is open implies ex W being Subset of X st
( p in W & W is open & g0 .: W c= V ) )
assume A6: ( g0 . p in V & V is open ) ; :: thesis: ex W being Subset of X st
( p in W & W is open & g0 .: W c= V )
reconsider r = g0 . p as Real by TOPMETR:24;
consider r0 being Real such that
A7: ( r0 > 0 & ].(r - r0),(r + r0).[ c= V ) by A6, FRECHET:8;
reconsider r1 = f1 . p as Real by TOPMETR:24;
set r4 = r0;
reconsider G1 = ].(r1 - r0),(r1 + r0).[ as Subset of R^1 by TOPMETR:24;
A8: r1 < r1 + r0 by A7, XREAL_1:31;
then r1 - r0 < r1 by XREAL_1:21;
then A9: f1 . p in G1 by A8, XXREAL_1:4;
G1 is open by JORDAN6:46;
then consider W1 being Subset of X such that
A10: ( p in W1 & W1 is open & f1 .: W1 c= G1 ) by A1, A9, Th20;
set W = W1;
g0 .: W1 c= ].(r - r0),(r + r0).[

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in g0 .: W1 or x in ].(r - r0),(r + r0).[ )
assume x in g0 .: W1 ; :: thesis: x in ].(r - r0),(r + r0).[
then consider z being set such that
A11: ( z in dom g0 & z in W1 & g0 . z = x ) by FUNCT_1:def 12;
reconsider pz = z as Point of X by A11;
pz in the carrier of X ;
then pz in dom f1 by FUNCT_2:def 1;
then A12: f1 . pz in f1 .: W1 by A11, FUNCT_1:def 12;
reconsider aa1 = f1 . pz as Real by TOPMETR:24;
A13: x = aa1 + a by A3, A11;
A14: ( r1 - r0 < aa1 & aa1 < r1 + r0 ) by A10, A12, XXREAL_1:4;
then A15: (r1 + r0) + a > aa1 + a by XREAL_1:10;
A16: (r1 - r0) + a < aa1 + a by A14, XREAL_1:10;
(r1 - r0) + a = (r1 + a) - r0
.= r - r0 by A3 ;
hence x in ].(r - r0),(r + r0).[ by A13, A15, A16, XXREAL_1:4; :: thesis: verum

end;

hence ex W being Subset of X st
( p in W & W is open & g0 .: W c= V ) by A7, A10, XBOOLE_1:1; :: thesis: verum

end;

then g0 is continuous by Th20;
hence ex g being Function of X,R^1 st
( ( for p being Point of X
for r1 being real number st f1 . p = r1 holds
g . p = r1 + a ) & g is continuous ) by A4; :: thesis: verum