let A be closed-interval Subset of REAL ; :: thesis: for Z being open Subset of REAL st A c= Z holds
integral ((- cos ) + ((id Z) (#) sin )),A = (((- (id Z)) (#) cos ) . (upper_bound A)) - (((- (id Z)) (#) cos ) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z implies integral ((- cos ) + ((id Z) (#) sin )),A = (((- (id Z)) (#) cos ) . (upper_bound A)) - (((- (id Z)) (#) cos ) . (lower_bound A)) )
assume A: A c= Z ; :: thesis: integral ((- cos ) + ((id Z) (#) sin )),A = (((- (id Z)) (#) cos ) . (upper_bound A)) - (((- (id Z)) (#) cos ) . (lower_bound A))
A1: dom ((- (id Z)) (#) cos ) = Z

proof

dom ((- (id Z)) (#) cos ) = (dom (- (id Z))) /\ REAL by SIN_COS:27, VALUED_1:def 4
.= dom (- (id Z)) by XBOOLE_1:28
.= dom (id Z) by VALUED_1:8 ;
hence dom ((- (id Z)) (#) cos ) = Z by RELAT_1:71; :: thesis: verum

end;

A2: Z = dom ((- cos ) + ((id Z) (#) sin ))

proof

dom ((- cos ) + ((id Z) (#) sin )) = (dom (- cos )) /\ (dom ((id Z) (#) sin )) by VALUED_1:def 1
.= REAL /\ (dom ((id Z) (#) sin )) by SIN_COS:27, VALUED_1:8
.= dom ((id Z) (#) sin ) by XBOOLE_1:28
.= (dom (id Z)) /\ REAL by SIN_COS:27, VALUED_1:def 4
.= dom (id Z) by XBOOLE_1:28 ;
hence Z = dom ((- cos ) + ((id Z) (#) sin )) by RELAT_1:71; :: thesis: verum

end;

Z = (dom (- cos )) /\ (dom ((id Z) (#) sin )) by A2, VALUED_1:def 1;
then D: ( Z c= dom (- cos ) & Z c= dom ((id Z) (#) sin ) ) by XBOOLE_1:18;
then ( Z c= dom (- cos ) & Z c= (dom (id Z)) /\ (dom sin ) ) by VALUED_1:def 4;
then AA: ( Z c= dom (- cos ) & Z c= dom (id Z) & Z c= dom sin ) by XBOOLE_1:18;
AB: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:35;
B: for x being Real st x in Z holds
((- cos ) + ((id Z) (#) sin )) . x = (- (cos . x)) + (x * (sin . x))

proof

let x be Real; :: thesis: ( x in Z implies ((- cos ) + ((id Z) (#) sin )) . x = (- (cos . x)) + (x * (sin . x)) )
assume C: x in Z ; :: thesis: ((- cos ) + ((id Z) (#) sin )) . x = (- (cos . x)) + (x * (sin . x))
then ((- cos ) + ((id Z) (#) sin )) . x = ((- cos ) . x) + (((id Z) (#) sin ) . x) by A2, VALUED_1:def 1
.= ((- cos ) . x) + (((id Z) . x) * (sin . x)) by VALUED_1:5
.= ((- cos ) . x) + (x * (sin . x)) by C, FUNCT_1:35
.= (- (cos . x)) + (x * (sin . x)) by VALUED_1:8 ;
hence ((- cos ) + ((id Z) (#) sin )) . x = (- (cos . x)) + (x * (sin . x)) ; :: thesis: verum

end;

C1: id Z is_differentiable_on Z by AA, AB, FDIFF_1:31;
sin is_differentiable_on Z by FDIFF_1:34, SIN_COS:73;
then C2: (id Z) (#) sin is_differentiable_on Z by D, C1, FDIFF_1:29;
- cos is_differentiable_on Z by FDIFF_1:34, INTEGRA8:26;
then ((- cos ) + ((id Z) (#) sin )) | Z is continuous by A2, C2, FDIFF_1:26, FDIFF_1:33;
then ((- cos ) + ((id Z) (#) sin )) | A is continuous by A, FCONT_1:17;
then A3: ( (- cos ) + ((id Z) (#) sin ) is_integrable_on A & ((- cos ) + ((id Z) (#) sin )) | A is bounded ) by A, A2, INTEGRA5:10, INTEGRA5:11;
A4: (- (id Z)) (#) cos is_differentiable_on Z by A1, FDIFF_4:44;
A5: for x being Real st x in dom (((- (id Z)) (#) cos ) `| Z) holds
(((- (id Z)) (#) cos ) `| Z) . x = ((- cos ) + ((id Z) (#) sin )) . x

proof

let x be Real; :: thesis: ( x in dom (((- (id Z)) (#) cos ) `| Z) implies (((- (id Z)) (#) cos ) `| Z) . x = ((- cos ) + ((id Z) (#) sin )) . x )
assume x in dom (((- (id Z)) (#) cos ) `| Z) ; :: thesis: (((- (id Z)) (#) cos ) `| Z) . x = ((- cos ) + ((id Z) (#) sin )) . x
then A6: x in Z by A4, FDIFF_1:def 8;
then (((- (id Z)) (#) cos ) `| Z) . x = (- (cos . x)) + (x * (sin . x)) by A1, FDIFF_4:44
.= ((- cos ) + ((id Z) (#) sin )) . x by B, A6 ;
hence (((- (id Z)) (#) cos ) `| Z) . x = ((- cos ) + ((id Z) (#) sin )) . x ; :: thesis: verum

end;

dom (((- (id Z)) (#) cos ) `| Z) = dom ((- cos ) + ((id Z) (#) sin )) by A2, A4, FDIFF_1:def 8;
then ((- (id Z)) (#) cos ) `| Z = (- cos ) + ((id Z) (#) sin ) by A5, PARTFUN1:34;
hence integral ((- cos ) + ((id Z) (#) sin )),A = (((- (id Z)) (#) cos ) . (upper_bound A)) - (((- (id Z)) (#) cos ) . (lower_bound A)) by A, A1, A3, FDIFF_4:44, INTEGRA5:13; :: thesis: verum