let Z be open Subset of REAL ; :: thesis: ( Z c= dom (((id Z) + cot ) - cosec ) & ( for x being Real st x in Z holds
( 1 + (cos . x) <> 0 & 1 - (cos . x) <> 0 ) ) implies ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) ) )
assume that
A1: Z c= dom (((id Z) + cot ) - cosec ) and
A2: for x being Real st x in Z holds
( 1 + (cos . x) <> 0 & 1 - (cos . x) <> 0 ) ; :: thesis: ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) )
C: Z c= (dom ((id Z) + cot )) /\ (dom cosec ) by A1, VALUED_1:12;
then B1: ( Z c= dom ((id Z) + cot ) & Z c= dom cosec ) by XBOOLE_1:18;
then Z c= (dom (id Z)) /\ (dom cot ) by VALUED_1:def 1;
then A3: ( Z c= dom cot & Z c= dom cosec & Z c= dom (id Z) ) by C, XBOOLE_1:18;
A5: cosec is_differentiable_on Z by B1, FDIFF_9:5;
for x being Real st x in Z holds
cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cot is_differentiable_in x )
assume x in Z ; :: thesis: cot is_differentiable_in x
then sin . x <> 0 by A3, FDIFF_8:2;
hence cot is_differentiable_in x by FDIFF_7:47; :: thesis: verum

end;

then A6: cot is_differentiable_on Z by A3, FDIFF_1:16;
B3: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:35;
then B4: ( id Z is_differentiable_on Z & ( for x being Real st x in Z holds
((id Z) `| Z) . x = 1 ) ) by A3, FDIFF_1:31;
AA: (id Z) + cot is_differentiable_on Z by B1, B4, A6, FDIFF_1:26;
B5: for x being Real st x in Z holds
(((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 )) )
assume A7: x in Z ; :: thesis: (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 ))
then A8: sin . x <> 0 by A3, FDIFF_8:2;
then A9: (sin . x) ^2 > 0 by SQUARE_1:74;
(((id Z) + cot ) `| Z) . x = (diff (id Z),x) + (diff cot ,x) by B1, A6, B4, A7, FDIFF_1:26
.= (((id Z) `| Z) . x) + (diff cot ,x) by B4, A7, FDIFF_1:def 8
.= 1 + (diff cot ,x) by A3, B3, A7, FDIFF_1:31
.= 1 + (- (1 / ((sin . x) ^2 ))) by A8, FDIFF_7:47
.= 1 - (1 / ((sin . x) ^2 ))
.= (((sin . x) ^2 ) / ((sin . x) ^2 )) - (1 / ((sin . x) ^2 )) by A9, XCMPLX_1:60
.= (((sin . x) ^2 ) - 1) / ((sin . x) ^2 ) by XCMPLX_1:121
.= (((sin . x) ^2 ) - (((sin . x) ^2 ) + ((cos . x) ^2 ))) / ((sin . x) ^2 ) by SIN_COS:31
.= (- ((cos . x) ^2 )) / ((sin . x) ^2 )
.= - (((cos . x) ^2 ) / ((sin . x) ^2 )) by XCMPLX_1:188 ;
hence (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 )) ; :: thesis: verum

end;

for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x))

proof

let x be Real; :: thesis: ( x in Z implies ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) )
assume A10: x in Z ; :: thesis: ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x))
then A11: ( sin . x <> 0 & 1 + (cos . x) <> 0 & 1 - (cos . x) <> 0 ) by A2, A3, FDIFF_8:2;
((((id Z) + cot ) - cosec ) `| Z) . x = (diff ((id Z) + cot ),x) - (diff cosec ,x) by A1, A5, AA, A10, FDIFF_1:27
.= ((((id Z) + cot ) `| Z) . x) - (diff cosec ,x) by AA, A10, FDIFF_1:def 8
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - (diff cosec ,x) by B5, A10
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - ((cosec `| Z) . x) by A5, A10, FDIFF_1:def 8
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - (- ((cos . x) / ((sin . x) ^2 ))) by B1, A10, FDIFF_9:5
.= ((cos . x) / ((sin . x) ^2 )) - (((cos . x) ^2 ) / ((sin . x) ^2 ))
.= ((cos . x) - ((cos . x) * (cos . x))) / ((sin . x) ^2 ) by XCMPLX_1:121
.= ((cos . x) * (1 - (cos . x))) / ((((sin . x) ^2 ) + ((cos . x) ^2 )) - ((cos . x) ^2 ))
.= ((cos . x) * (1 - (cos . x))) / (1 - ((cos . x) ^2 )) by SIN_COS:31
.= ((cos . x) * (1 - (cos . x))) / ((1 - (cos . x)) * (1 + (cos . x)))
.= (((cos . x) * (1 - (cos . x))) / (1 - (cos . x))) / (1 + (cos . x)) by XCMPLX_1:79
.= ((cos . x) * ((1 - (cos . x)) / (1 - (cos . x)))) / (1 + (cos . x)) by XCMPLX_1:75
.= ((cos . x) * 1) / (1 + (cos . x)) by A11, XCMPLX_1:60
.= (cos . x) / (1 + (cos . x)) ;
hence ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ; :: thesis: verum

end;

hence ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) ) by A1, AA, A5, FDIFF_1:27; :: thesis: verum