let G be Group; :: thesis: for F being FinSequence of the carrier of G holds F |^ ((len F) |-> (@ 1)) = F
let F be FinSequence of the carrier of G; :: thesis: F |^ ((len F) |-> (@ 1)) = F
defpred S₁[ FinSequence of the carrier of G] means $1 |^ ((len $1) |-> (@ 1)) = $1;
A1: S₁[ <*> the carrier of G]

proof

set A = <*> the carrier of G;
thus (<*> the carrier of G) |^ ((len (<*> the carrier of G)) |-> (@ 1)) = (<*> the carrier of G) |^ (0 |-> (@ 1))
.= (<*> the carrier of G) |^ (<*> INT ) by FINSEQ_2:72
.= <*> the carrier of G by Th27 ; :: thesis: verum

end;

A2: for F being FinSequence of the carrier of G
for a being Element of G st S₁[F] holds
S₁[F ^ <*a*>]

proof

let F be FinSequence of the carrier of G; :: thesis: for a being Element of G st S₁[F] holds
S₁[F ^ <*a*>]
let a be Element of G; :: thesis: ( S₁[F] implies S₁[F ^ <*a*>] )
set A = F ^ <*a*>;
assume A3: S₁[F] ; :: thesis: S₁[F ^ <*a*>]
A4: len (F ^ <*a*>) = (len F) + (len <*a*>) by FINSEQ_1:35;
A5: len <*a*> = 1 by FINSEQ_1:57;
A6: len <*(@ 1)*> = 1 by FINSEQ_1:57;
A7: len ((len F) |-> (@ 1)) = len F by FINSEQ_1:def 18;
thus (F ^ <*a*>) |^ ((len (F ^ <*a*>)) |-> (@ 1)) = (F ^ <*a*>) |^ (((len F) |-> (@ 1)) ^ <*(@ 1)*>) by A4, A5, FINSEQ_2:74
.= (F |^ ((len F) |-> (@ 1))) ^ (<*a*> |^ <*(@ 1)*>) by A5, A6, A7, Th25
.= F ^ <*(a |^ 1)*> by A3, Th28
.= F ^ <*a*> by GROUP_1:44 ; :: thesis: verum

end;

for F being FinSequence of the carrier of G holds S₁[F] from FINSEQ_2:sch 2(A1, A2);
hence F |^ ((len F) |-> (@ 1)) = F ; :: thesis: verum