let Z be open Subset of REAL ; :: thesis: ( not 0 in Z & Z c= dom (ln * ((id Z) ^ )) implies ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) ) )
set f = id Z;
assume A1: ( not 0 in Z & Z c= dom (ln * ((id Z) ^ )) ) ; :: thesis: ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) )
A2: for x being Real st x in Z holds
(id Z) . x = x by FUNCT_1:35;
dom (ln * ((id Z) ^ )) c= dom ((id Z) ^ ) by RELAT_1:44;
then A3: Z c= dom ((id Z) ^ ) by A1, XBOOLE_1:1;
A5: for x being Real st x in Z holds
((id Z) ^ ) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies ((id Z) ^ ) . x > 0 )
assume A6: x in Z ; :: thesis: ((id Z) ^ ) . x > 0
then A7: ((id Z) ^ ) . x in right_open_halfline 0 by A1, FUNCT_1:21, TAYLOR_1:18;
A8: ((id Z) ^ ) . x = ((id Z) . x) " by A3, A6, RFUNCT_1:def 8
.= 1 / x by A2, A6 ;
then ex g being Real st
( 1 / x = g & 0 < g ) by A7, Lm1;
hence ((id Z) ^ ) . x > 0 by A8; :: thesis: verum

end;

A9: for x being Real st x in Z holds
(id Z) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (id Z) . x > 0 )
assume A10: x in Z ; :: thesis: (id Z) . x > 0
then ((id Z) ^ ) . x > 0 by A5;
then ((id Z) . x) " > 0 by A3, A10, RFUNCT_1:def 8;
hence (id Z) . x > 0 by XREAL_1:124; :: thesis: verum

end;

A12: ( (id Z) ^ is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) ^ ) `| Z) . x = - (1 / (x ^2 )) ) ) by A1, FDIFF_5:4;
A13: for x being Real st x in Z holds
( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) )

proof

let x be Real; :: thesis: ( x in Z implies ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) ) )
assume A14: x in Z ; :: thesis: ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) )
then A15: (id Z) ^ is_differentiable_in x by A12, FDIFF_1:16;
((id Z) ^ ) . x > 0 by A5, A14;
hence ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) ) by A15, TAYLOR_1:20; :: thesis: verum

end;

then A16: for x being Real st x in Z holds
ln * ((id Z) ^ ) is_differentiable_in x ;
then A17: ln * ((id Z) ^ ) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x)

proof

let x be Real; :: thesis: ( x in Z implies ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) )
assume A18: x in Z ; :: thesis: ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x)
then (id Z) . x <> 0 by A9;
then A19: x <> 0 by A2, A18;
diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) by A13, A18
.= ((((id Z) ^ ) `| Z) . x) / (((id Z) ^ ) . x) by A12, A18, FDIFF_1:def 8
.= ((((id Z) ^ ) `| Z) . x) / (((id Z) . x) " ) by A3, A18, RFUNCT_1:def 8
.= ((((id Z) ^ ) `| Z) . x) / (1 * (x " )) by A2, A18
.= (- (1 / (x ^2 ))) / (1 * (x " )) by A18, FDIFF_5:4, A1
.= - (x / (x ^2 ))
.= - ((x / x) / x) by XCMPLX_1:79
.= - (1 / x) by A19, XCMPLX_1:60 ;
hence ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) by A17, A18, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) ) by A1, A16, FDIFF_1:16; :: thesis: verum