let Z be open Subset of REAL ; :: thesis: ( Z c= dom (ln * cot ) implies ( ln * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x))) ) ) )
assume A1: Z c= dom (ln * cot ) ; :: thesis: ( ln * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x))) ) )
A2: for x being Real st x in Z holds
sin . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies sin . x <> 0 )
assume x in Z ; :: thesis: sin . x <> 0
then x in dom (cos / sin ) by A1, FUNCT_1:21;
hence sin . x <> 0 by Th2; :: thesis: verum

end;

A3: for x being Real st x in Z holds
cot . x > 0

proof

let x be Real; :: thesis: ( x in Z implies cot . x > 0 )
assume x in Z ; :: thesis: cot . x > 0
then cot . x in right_open_halfline 0 by A1, FUNCT_1:21, TAYLOR_1:18;
then ex g being Real st
( cot . x = g & 0 < g ) by Lm1;
hence cot . x > 0 ; :: thesis: verum

end;

dom (ln * cot ) c= dom cot by RELAT_1:44;
then A4: Z c= dom cot by A1, XBOOLE_1:1;
A5: for x being Real st x in Z holds
cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cot is_differentiable_in x )
assume x in Z ; :: thesis: cot is_differentiable_in x
then sin . x <> 0 by A2;
hence cot is_differentiable_in x by FDIFF_7:47; :: thesis: verum

end;

A6: for x being Real st x in Z holds
ln * cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * cot is_differentiable_in x )
assume A7: x in Z ; :: thesis: ln * cot is_differentiable_in x
then A8: cot is_differentiable_in x by A5;
( sin . x <> 0 & cot . x > 0 ) by A2, A3, A7;
hence ln * cot is_differentiable_in x by A8, TAYLOR_1:20; :: thesis: verum

end;

then A9: ln * cot is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x)))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x))) )
assume A10: x in Z ; :: thesis: ((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x)))
then A11: cot is_differentiable_in x by A5;
A12: ( sin . x <> 0 & cot . x > 0 ) by A2, A3, A10;
then diff (ln * cot ),x = (diff cot ,x) / (cot . x) by A11, TAYLOR_1:20
.= (- (1 / ((sin . x) ^2 ))) / (cot . x) by A12, FDIFF_7:47
.= - ((1 / ((sin . x) ^2 )) / (cot . x))
.= - (1 / (((sin . x) ^2 ) * (cot . x))) by XCMPLX_1:79
.= - (1 / (((sin . x) ^2 ) * ((cos . x) / (sin . x)))) by A4, A10, RFUNCT_1:def 4
.= - (1 / ((((sin . x) ^2 ) * (cos . x)) / (sin . x)))
.= - ((sin . x) / (((sin . x) ^2 ) * (cos . x))) by XCMPLX_1:57
.= - (((sin . x) / ((sin . x) ^2 )) / (cos . x)) by XCMPLX_1:79
.= - ((((sin . x) / (sin . x)) / (sin . x)) / (cos . x)) by XCMPLX_1:79
.= - ((1 / (sin . x)) / (cos . x)) by A12, XCMPLX_1:60
.= - (1 / ((sin . x) * (cos . x))) by XCMPLX_1:79 ;
hence ((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x))) by A9, A10, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cot ) `| Z) . x = - (1 / ((sin . x) * (cos . x))) ) ) by A1, A6, FDIFF_1:16; :: thesis: verum