let Z be open Subset of REAL ; :: thesis: ( Z c= dom (tan * exp_R ) implies ( tan * exp_R is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 ) ) ) )
assume A1: Z c= dom (tan * exp_R ) ; :: thesis: ( tan * exp_R is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 ) ) )
A2: for x being Real st x in Z holds
cos . (exp_R . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (exp_R . x) <> 0 )
assume x in Z ; :: thesis: cos . (exp_R . x) <> 0
then exp_R . x in dom (sin / cos ) by A1, FUNCT_1:21;
hence cos . (exp_R . x) <> 0 by Th1; :: thesis: verum

end;

A3: for x being Real st x in Z holds
tan * exp_R is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan * exp_R is_differentiable_in x )
assume A4: x in Z ; :: thesis: tan * exp_R is_differentiable_in x
A5: exp_R is_differentiable_in x by SIN_COS:70;
cos . (exp_R . x) <> 0 by A2, A4;
then tan is_differentiable_in exp_R . x by FDIFF_7:46;
hence tan * exp_R is_differentiable_in x by A5, FDIFF_2:13; :: thesis: verum

end;

then A6: tan * exp_R is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 )

proof

let x be Real; :: thesis: ( x in Z implies ((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 ) )
assume A7: x in Z ; :: thesis: ((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 )
A8: exp_R is_differentiable_in x by SIN_COS:70;
A9: cos . (exp_R . x) <> 0 by A2, A7;
then tan is_differentiable_in exp_R . x by FDIFF_7:46;
then diff (tan * exp_R ),x = (diff tan ,(exp_R . x)) * (diff exp_R ,x) by A8, FDIFF_2:13
.= (1 / ((cos . (exp_R . x)) ^2 )) * (diff exp_R ,x) by A9, FDIFF_7:46
.= (exp_R . x) / ((cos . (exp_R . x)) ^2 ) by SIN_COS:70 ;
hence ((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 ) by A6, A7, FDIFF_1:def 8; :: thesis: verum

end;

hence ( tan * exp_R is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * exp_R ) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2 ) ) ) by A1, A3, FDIFF_1:16; :: thesis: verum