let n be Element of NAT ; :: thesis: for Z being open Subset of REAL st Z c= dom ((- (1 / n)) (#) ((#Z n) * (sin ^ ))) & n > 0 & ( for x being Real st x in Z holds
sin . x <> 0 ) holds
( (- (1 / n)) (#) ((#Z n) * (sin ^ )) is_differentiable_on Z & ( for x being Real st x in Z holds
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) ) )
let Z be open Subset of REAL ; :: thesis: ( Z c= dom ((- (1 / n)) (#) ((#Z n) * (sin ^ ))) & n > 0 & ( for x being Real st x in Z holds
sin . x <> 0 ) implies ( (- (1 / n)) (#) ((#Z n) * (sin ^ )) is_differentiable_on Z & ( for x being Real st x in Z holds
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) ) ) )
assume that
A1: Z c= dom ((- (1 / n)) (#) ((#Z n) * (sin ^ ))) and
A2: n > 0 and
A3: for x being Real st x in Z holds
sin . x <> 0 ; :: thesis: ( (- (1 / n)) (#) ((#Z n) * (sin ^ )) is_differentiable_on Z & ( for x being Real st x in Z holds
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) ) )
A4: Z c= dom ((#Z n) * (sin ^ )) by A1, VALUED_1:def 5;
then for y being set st y in Z holds
y in dom (sin ^ ) by FUNCT_1:21;
then A5: Z c= dom (sin ^ ) by TARSKI:def 3;
A6: ( sin ^ is_differentiable_on Z & ( for x being Real st x in Z holds
((sin ^ ) `| Z) . x = - ((cos . x) / ((sin . x) ^2 )) ) ) by A3, FDIFF_4:40;

now

let x be Real; :: thesis: ( x in Z implies (#Z n) * (sin ^ ) is_differentiable_in x )
assume x in Z ; :: thesis: (#Z n) * (sin ^ ) is_differentiable_in x
then sin ^ is_differentiable_in x by A6, FDIFF_1:16;
hence (#Z n) * (sin ^ ) is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

then A7: (#Z n) * (sin ^ ) is_differentiable_on Z by A4, FDIFF_1:16;
for x being Real st x in Z holds
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1))

proof

let x be Real; :: thesis: ( x in Z implies (((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) )
assume A8: x in Z ; :: thesis: (((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1))
then A9: sin ^ is_differentiable_in x by A6, FDIFF_1:16;
A10: (sin ^ ) . x = (sin . x) " by A5, A8, RFUNCT_1:def 8
.= 1 / (sin . x) by XCMPLX_1:217 ;
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (- (1 / n)) * (diff ((#Z n) * (sin ^ )),x) by A1, A7, A8, FDIFF_1:28
.= (- (1 / n)) * ((n * (((sin ^ ) . x) #Z (n - 1))) * (diff (sin ^ ),x)) by A9, TAYLOR_1:3
.= (- (1 / n)) * ((n * (((sin ^ ) . x) #Z (n - 1))) * (((sin ^ ) `| Z) . x)) by A6, A8, FDIFF_1:def 8
.= (- (1 / n)) * ((n * (((sin ^ ) . x) #Z (n - 1))) * (- ((cos . x) / ((sin . x) ^2 )))) by A3, A8, FDIFF_4:40
.= - ((((1 / n) * n) * (((sin ^ ) . x) #Z (n - 1))) * (- ((cos . x) / ((sin . x) ^2 ))))
.= - ((1 * (((sin ^ ) . x) #Z (n - 1))) * (- ((cos . x) / ((sin . x) ^2 )))) by A2, XCMPLX_1:107
.= - (((1 / (sin . x)) #Z (n - 1)) * (- ((cos . x) / ((sin . x) #Z 2)))) by A10, Th1
.= - ((- ((cos . x) / ((sin . x) #Z 2))) * (1 / ((sin . x) #Z (n - 1)))) by PREPOWER:52
.= ((cos . x) / ((sin . x) #Z 2)) * (1 / ((sin . x) #Z (n - 1)))
.= ((cos . x) / ((sin . x) #Z 2)) / ((sin . x) #Z (n - 1)) by XCMPLX_1:100
.= (cos . x) / (((sin . x) #Z 2) * ((sin . x) #Z (n - 1))) by XCMPLX_1:79
.= (cos . x) / ((sin . x) #Z (2 + (n - 1))) by A3, A8, PREPOWER:54
.= (cos . x) / ((sin . x) #Z (n + 1)) ;
hence (((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) ; :: thesis: verum

end;

hence ( (- (1 / n)) (#) ((#Z n) * (sin ^ )) is_differentiable_on Z & ( for x being Real st x in Z holds
(((- (1 / n)) (#) ((#Z n) * (sin ^ ))) `| Z) . x = (cos . x) / ((sin . x) #Z (n + 1)) ) ) by A1, A7, FDIFF_1:28; :: thesis: verum