let a, b be Real; :: thesis: for Z being open Subset of REAL
for f being PartFunc of REAL ,REAL st Z c= dom (arcsin * f) & ( for x being Real st x in Z holds
( f . x = (a * x) + b & f . x > - 1 & f . x < 1 ) ) holds
( arcsin * f is_differentiable_on Z & ( for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) ) )
let Z be open Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL st Z c= dom (arcsin * f) & ( for x being Real st x in Z holds
( f . x = (a * x) + b & f . x > - 1 & f . x < 1 ) ) holds
( arcsin * f is_differentiable_on Z & ( for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) ) )
let f be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (arcsin * f) & ( for x being Real st x in Z holds
( f . x = (a * x) + b & f . x > - 1 & f . x < 1 ) ) implies ( arcsin * f is_differentiable_on Z & ( for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) ) ) )
assume that
A1: Z c= dom (arcsin * f) and
A2: for x being Real st x in Z holds
( f . x = (a * x) + b & f . x > - 1 & f . x < 1 ) ; :: thesis: ( arcsin * f is_differentiable_on Z & ( for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) ) )
A3: for x being Real st x in Z holds
f . x = (a * x) + b by A2;
for y being set st y in Z holds
y in dom f by A1, FUNCT_1:21;
then A4: Z c= dom f by TARSKI:def 3;
then A5: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = a ) ) by A3, FDIFF_1:31;
A6: for x being Real st x in Z holds
arcsin * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies arcsin * f is_differentiable_in x )
assume A7: x in Z ; :: thesis: arcsin * f is_differentiable_in x
then A8: f is_differentiable_in x by A5, FDIFF_1:16;
( f . x > - 1 & f . x < 1 ) by A2, A7;
hence arcsin * f is_differentiable_in x by A8, Th6; :: thesis: verum

end;

then A9: arcsin * f is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 )))

proof

let x be Real; :: thesis: ( x in Z implies ((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) )
assume A10: x in Z ; :: thesis: ((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 )))
then A11: f is_differentiable_in x by A5, FDIFF_1:16;
( f . x > - 1 & f . x < 1 ) by A2, A10;
then diff (arcsin * f),x = (diff f,x) / (sqrt (1 - ((f . x) ^2 ))) by A11, Th6
.= ((f `| Z) . x) / (sqrt (1 - ((f . x) ^2 ))) by A5, A10, FDIFF_1:def 8
.= a / (sqrt (1 - ((f . x) ^2 ))) by A3, A4, A10, FDIFF_1:31
.= a / (sqrt (1 - (((a * x) + b) ^2 ))) by A2, A10 ;
hence ((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) by A9, A10, FDIFF_1:def 8; :: thesis: verum

end;

hence ( arcsin * f is_differentiable_on Z & ( for x being Real st x in Z holds
((arcsin * f) `| Z) . x = a / (sqrt (1 - (((a * x) + b) ^2 ))) ) ) by A1, A6, FDIFF_1:16; :: thesis: verum