let Z be open Subset of REAL ; :: thesis: for f, f1 being PartFunc of REAL ,REAL st Z c= dom (ln * f) & f = exp_R + (exp_R * f1) & ( for x being Real st x in Z holds
f1 . x = - x ) holds
( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) )
let f, f1 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * f) & f = exp_R + (exp_R * f1) & ( for x being Real st x in Z holds
f1 . x = - x ) implies ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) ) )
assume that
A1: ( Z c= dom (ln * f) & f = exp_R + (exp_R * f1) ) and
A2: for x being Real st x in Z holds
f1 . x = - x ; :: thesis: ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) )
for y being set st y in Z holds
y in dom f by A1, FUNCT_1:21;
then A3: Z c= dom (exp_R + (exp_R * f1)) by A1, TARSKI:def 3;
then Z c= (dom exp_R ) /\ (dom (exp_R * f1)) by VALUED_1:def 1;
then A4: Z c= dom (exp_R * f1) by XBOOLE_1:18;
then A5: ( exp_R * f1 is_differentiable_on Z & ( for x being Real st x in Z holds
((exp_R * f1) `| Z) . x = - (exp_R (- x)) ) ) by A2, Th14;
A6: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
A7: for x being Real st x in Z holds
((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x))

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x)) )
assume A8: x in Z ; :: thesis: ((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x))
hence ((exp_R + (exp_R * f1)) `| Z) . x = (diff exp_R ,x) + (diff (exp_R * f1),x) by A3, A5, A6, FDIFF_1:26
.= (exp_R . x) + (diff (exp_R * f1),x) by SIN_COS:70
.= (exp_R . x) + (((exp_R * f1) `| Z) . x) by A5, A8, FDIFF_1:def 8
.= (exp_R . x) + (- (exp_R (- x))) by A2, A4, A8, Th14
.= (exp_R x) + (- (exp_R (- x))) by SIN_COS:def 27
.= (exp_R x) - (exp_R (- x)) ;
:: thesis: verum

end;

then A9: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = (exp_R x) - (exp_R (- x)) ) ) by A1, A3, A5, A6, FDIFF_1:26;
A10: for x being Real st x in Z holds
(exp_R + (exp_R * f1)) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (exp_R + (exp_R * f1)) . x > 0 )
assume A11: x in Z ; :: thesis: (exp_R + (exp_R * f1)) . x > 0
then A12: (exp_R + (exp_R * f1)) . x = (exp_R . x) + ((exp_R * f1) . x) by A3, VALUED_1:def 1
.= (exp_R . x) + (exp_R . (f1 . x)) by A4, A11, FUNCT_1:22
.= (exp_R . x) + (exp_R . (- x)) by A2, A11
.= (exp_R x) + (exp_R . (- x)) by SIN_COS:def 27
.= (exp_R x) + (exp_R (- x)) by SIN_COS:def 27 ;
( exp_R x > 0 & exp_R (- x) > 0 ) by SIN_COS:60;
hence (exp_R + (exp_R * f1)) . x > 0 by A12, XREAL_1:36; :: thesis: verum

end;

A13: for x being Real st x in Z holds
ln * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * f is_differentiable_in x )
assume A14: x in Z ; :: thesis: ln * f is_differentiable_in x
then A15: f is_differentiable_in x by A9, FDIFF_1:16;
f . x > 0 by A1, A10, A14;
hence ln * f is_differentiable_in x by A15, TAYLOR_1:20; :: thesis: verum

end;

then A16: ln * f is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x)))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) )
assume A17: x in Z ; :: thesis: ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x)))
then A18: f . x = (exp_R . x) + ((exp_R * f1) . x) by A1, A3, VALUED_1:def 1
.= (exp_R . x) + (exp_R . (f1 . x)) by A4, A17, FUNCT_1:22
.= (exp_R . x) + (exp_R . (- x)) by A2, A17
.= (exp_R x) + (exp_R . (- x)) by SIN_COS:def 27
.= (exp_R x) + (exp_R (- x)) by SIN_COS:def 27 ;
A19: f is_differentiable_in x by A9, A17, FDIFF_1:16;
f . x > 0 by A1, A10, A17;
then diff (ln * f),x = (diff f,x) / (f . x) by A19, TAYLOR_1:20
.= ((f `| Z) . x) / (f . x) by A9, A17, FDIFF_1:def 8
.= ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) by A1, A7, A17, A18 ;
hence ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) by A16, A17, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) ) by A1, A13, FDIFF_1:16; :: thesis: verum