let Z be open Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL st Z c= dom ((#Z 2) * (f - exp_R )) & ( for x being Real st x in Z holds
f . x = 1 ) holds
( (#Z 2) * (f - exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ) )
let f be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom ((#Z 2) * (f - exp_R )) & ( for x being Real st x in Z holds
f . x = 1 ) implies ( (#Z 2) * (f - exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ) ) )
assume that
A1: Z c= dom ((#Z 2) * (f - exp_R )) and
A2: for x being Real st x in Z holds
f . x = 1 ; :: thesis: ( (#Z 2) * (f - exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ) )
for y being set st y in Z holds
y in dom (f - exp_R ) by A1, FUNCT_1:21;
then A3: Z c= dom (f - exp_R ) by TARSKI:def 3;
then Z c= (dom exp_R ) /\ (dom f) by VALUED_1:12;
then A4: Z c= dom f by XBOOLE_1:18;
A5: for x being Real st x in Z holds
f . x = (0 * x) + 1 by A2;
then A6: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 0 ) ) by A4, FDIFF_1:31;
A7: for x being Real st x in Z holds
(#Z 2) * (f - exp_R ) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies (#Z 2) * (f - exp_R ) is_differentiable_in x )
assume x in Z ; :: thesis: (#Z 2) * (f - exp_R ) is_differentiable_in x
then A8: f is_differentiable_in x by A6, FDIFF_1:16;
exp_R is_differentiable_in x by SIN_COS:70;
then f - exp_R is_differentiable_in x by A8, FDIFF_1:22;
hence (#Z 2) * (f - exp_R ) is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

then A9: (#Z 2) * (f - exp_R ) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
(((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x)))

proof

let x be Real; :: thesis: ( x in Z implies (((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) )
assume A10: x in Z ; :: thesis: (((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x)))
then A11: f is_differentiable_in x by A6, FDIFF_1:16;
A12: exp_R is_differentiable_in x by SIN_COS:70;
then A13: f - exp_R is_differentiable_in x by A11, FDIFF_1:22;
A14: diff (f - exp_R ),x = (diff f,x) - (diff exp_R ,x) by A11, A12, FDIFF_1:22
.= ((f `| Z) . x) - (diff exp_R ,x) by A6, A10, FDIFF_1:def 8
.= ((f `| Z) . x) - (exp_R . x) by SIN_COS:70
.= 0 - (exp_R . x) by A4, A5, A10, FDIFF_1:31
.= - (exp_R . x) ;
A15: (f - exp_R ) . x = (f . x) - (exp_R . x) by A3, A10, VALUED_1:13
.= 1 - (exp_R . x) by A2, A10 ;
(((#Z 2) * (f - exp_R )) `| Z) . x = diff ((#Z 2) * (f - exp_R )),x by A9, A10, FDIFF_1:def 8
.= (2 * (((f - exp_R ) . x) #Z (2 - 1))) * (diff (f - exp_R ),x) by A13, TAYLOR_1:3
.= (2 * (1 - (exp_R . x))) * (- (exp_R . x)) by A14, A15, PREPOWER:45
.= - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ;
hence (((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ; :: thesis: verum

end;

hence ( (#Z 2) * (f - exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (f - exp_R )) `| Z) . x = - ((2 * (exp_R . x)) * (1 - (exp_R . x))) ) ) by A1, A7, FDIFF_1:16; :: thesis: verum