let Z be open Subset of REAL ; :: thesis: for g being PartFunc of REAL ,REAL st Z c= dom (g (#) ln ) & g = #Z 2 & ( for x being Real st x in Z holds
x > 0 ) holds
( g (#) ln is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) ) )
let g be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (g (#) ln ) & g = #Z 2 & ( for x being Real st x in Z holds
x > 0 ) implies ( g (#) ln is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) ) ) )
set f = ln ;
assume A1: ( Z c= dom (g (#) ln ) & g = #Z 2 & ( for x being Real st x in Z holds
x > 0 ) ) ; :: thesis: ( g (#) ln is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) ) )
then Z c= (dom g) /\ (dom ln ) by VALUED_1:def 4;
then A2: ( Z c= dom g & Z c= dom ln ) by XBOOLE_1:18;
for x being Real st x in Z holds
g is_differentiable_in x by A1, TAYLOR_1:2;
then A3: g is_differentiable_on Z by A2, FDIFF_1:16;
A4: for x being Real st x in Z holds
(g `| Z) . x = 2 * x

proof

let x be Real; :: thesis: ( x in Z implies (g `| Z) . x = 2 * x )
assume A5: x in Z ; :: thesis: (g `| Z) . x = 2 * x
diff g,x = 2 * (x #Z (2 - 1)) by A1, TAYLOR_1:2
.= 2 * x by PREPOWER:45 ;
hence (g `| Z) . x = 2 * x by A3, A5, FDIFF_1:def 8; :: thesis: verum

end;

A6: ( ln is_differentiable_on Z & ( for x being Real st x in Z holds
(ln `| Z) . x = 1 / x ) ) by A2, Th19;

now

let x be Real; :: thesis: ( x in Z implies ((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) )
assume A7: x in Z ; :: thesis: ((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x))
then A8: x <> 0 by A1;
((g (#) ln ) `| Z) . x = ((g . x) * (diff ln ,x)) + ((ln . x) * (diff g,x)) by A1, A3, A6, A7, FDIFF_1:29
.= ((g . x) * ((ln `| Z) . x)) + ((ln . x) * (diff g,x)) by A6, A7, FDIFF_1:def 8
.= ((g . x) * (1 / x)) + ((ln . x) * (diff g,x)) by A2, A7, Th19
.= ((x #Z 2) * (1 / x)) + ((ln . x) * (diff g,x)) by A1, TAYLOR_1:def 1
.= ((x #Z 2) * (1 / x)) + ((ln . x) * ((g `| Z) . x)) by A3, A7, FDIFF_1:def 8
.= ((x #Z (1 + 1)) * (1 / x)) + ((2 * x) * (ln . x)) by A4, A7
.= (((x #Z 1) * (x #Z 1)) * (1 / x)) + ((2 * x) * (ln . x)) by TAYLOR_1:1
.= (((x #Z 1) * x) * (1 / x)) + ((2 * x) * (ln . x)) by PREPOWER:45
.= ((x * x) * (1 / x)) + ((2 * x) * (ln . x)) by PREPOWER:45
.= (x * (x * (1 / x))) + ((2 * x) * (ln . x))
.= (x * 1) + ((2 * x) * (ln . x)) by A8, XCMPLX_1:107
.= x + ((2 * x) * (ln . x)) ;
hence ((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) ; :: thesis: verum

end;

hence ( g (#) ln is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) ln ) `| Z) . x = x + ((2 * x) * (ln . x)) ) ) by A1, A3, A6, FDIFF_1:29; :: thesis: verum