let Z be open Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL st Z c= dom (ln * ((exp_R - f) / exp_R )) & ( for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ) holds
( ln * ((exp_R - f) / exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) ) )
let f be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * ((exp_R - f) / exp_R )) & ( for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ) implies ( ln * ((exp_R - f) / exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) ) ) )
assume that
A1: Z c= dom (ln * ((exp_R - f) / exp_R )) and
A2: for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ; :: thesis: ( ln * ((exp_R - f) / exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) ) )
for y being set st y in Z holds
y in dom ((exp_R - f) / exp_R ) by A1, FUNCT_1:21;
then Z c= dom ((exp_R - f) / exp_R ) by TARSKI:def 3;
then Z c= (dom (exp_R - f)) /\ ((dom exp_R ) \ (exp_R " {0 })) by RFUNCT_1:def 4;
then A3: ( Z c= dom (exp_R - f) & Z c= (dom exp_R ) \ (exp_R " {0 }) ) by XBOOLE_1:18;
then Z c= (dom exp_R ) /\ (dom f) by VALUED_1:12;
then A4: Z c= dom f by XBOOLE_1:18;
A5: for x being Real st x in Z holds
f . x = (0 * x) + 1 by A2;
then A6: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 0 ) ) by A4, FDIFF_1:31;
A7: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
then A8: ( exp_R - f is_differentiable_on Z & ( for x being Real st x in Z holds
((exp_R - f) `| Z) . x = (diff exp_R ,x) - (diff f,x) ) ) by A3, A6, FDIFF_1:27;
A9: for x being Real st x in Z holds
((exp_R - f) `| Z) . x = exp_R . x

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R - f) `| Z) . x = exp_R . x )
assume A10: x in Z ; :: thesis: ((exp_R - f) `| Z) . x = exp_R . x
hence ((exp_R - f) `| Z) . x = (diff exp_R ,x) - (diff f,x) by A3, A6, A7, FDIFF_1:27
.= (exp_R . x) - (diff f,x) by SIN_COS:70
.= (exp_R . x) - ((f `| Z) . x) by A6, A10, FDIFF_1:def 8
.= (exp_R . x) - 0 by A4, A5, A10, FDIFF_1:31
.= exp_R . x ;
:: thesis: verum

end;

for x being Real st x in Z holds
exp_R . x <> 0 by SIN_COS:59;
then A11: (exp_R - f) / exp_R is_differentiable_on Z by A7, A8, FDIFF_2:21;
A12: for x being Real st x in Z holds
(((exp_R - f) / exp_R ) `| Z) . x = 1 / (exp_R . x)

proof

let x be Real; :: thesis: ( x in Z implies (((exp_R - f) / exp_R ) `| Z) . x = 1 / (exp_R . x) )
assume A13: x in Z ; :: thesis: (((exp_R - f) / exp_R ) `| Z) . x = 1 / (exp_R . x)
A14: exp_R is_differentiable_in x by SIN_COS:70;
A15: exp_R - f is_differentiable_in x by A8, A13, FDIFF_1:16;
A16: (exp_R - f) . x = (exp_R . x) - (f . x) by A3, A13, VALUED_1:13
.= (exp_R . x) - 1 by A2, A13 ;
then A17: ( exp_R . x <> 0 & (exp_R - f) . x = (exp_R . x) - 1 ) by SIN_COS:59;
then diff ((exp_R - f) / exp_R ),x = (((diff (exp_R - f),x) * (exp_R . x)) - ((diff exp_R ,x) * ((exp_R - f) . x))) / ((exp_R . x) ^2 ) by A14, A15, FDIFF_2:14
.= (((((exp_R - f) `| Z) . x) * (exp_R . x)) - ((diff exp_R ,x) * ((exp_R - f) . x))) / ((exp_R . x) ^2 ) by A8, A13, FDIFF_1:def 8
.= (((exp_R . x) * (exp_R . x)) - ((diff exp_R ,x) * ((exp_R - f) . x))) / ((exp_R . x) ^2 ) by A9, A13
.= (((exp_R . x) * (exp_R . x)) - ((exp_R . x) * ((exp_R . x) - 1))) / ((exp_R . x) ^2 ) by A16, SIN_COS:70
.= ((exp_R . x) / (exp_R . x)) / (exp_R . x) by XCMPLX_1:79
.= 1 / (exp_R . x) by A17, XCMPLX_1:60 ;
hence (((exp_R - f) / exp_R ) `| Z) . x = 1 / (exp_R . x) by A11, A13, FDIFF_1:def 8; :: thesis: verum

end;

A18: for x being Real st x in Z holds
((exp_R - f) / exp_R ) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R - f) / exp_R ) . x > 0 )
assume A19: x in Z ; :: thesis: ((exp_R - f) / exp_R ) . x > 0
then x in dom ((exp_R - f) / exp_R ) by A1, FUNCT_1:21;
then A20: ((exp_R - f) / exp_R ) . x = ((exp_R - f) . x) * ((exp_R . x) " ) by RFUNCT_1:def 4
.= ((exp_R - f) . x) * (1 / (exp_R . x)) by XCMPLX_1:217
.= ((exp_R - f) . x) / (exp_R . x) by XCMPLX_1:100 ;
A21: (exp_R - f) . x > 0 by A2, A19;
exp_R . x > 0 by SIN_COS:59;
hence ((exp_R - f) / exp_R ) . x > 0 by A20, A21, XREAL_1:141; :: thesis: verum

end;

A22: for x being Real st x in Z holds
ln * ((exp_R - f) / exp_R ) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * ((exp_R - f) / exp_R ) is_differentiable_in x )
assume A23: x in Z ; :: thesis: ln * ((exp_R - f) / exp_R ) is_differentiable_in x
then A24: (exp_R - f) / exp_R is_differentiable_in x by A11, FDIFF_1:16;
((exp_R - f) / exp_R ) . x > 0 by A18, A23;
hence ln * ((exp_R - f) / exp_R ) is_differentiable_in x by A24, TAYLOR_1:20; :: thesis: verum

end;

then A25: ln * ((exp_R - f) / exp_R ) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1)

proof

let x be Real; :: thesis: ( x in Z implies ((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) )
assume A26: x in Z ; :: thesis: ((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1)
then x in dom ((exp_R - f) / exp_R ) by A1, FUNCT_1:21;
then A27: ((exp_R - f) / exp_R ) . x = ((exp_R - f) . x) * ((exp_R . x) " ) by RFUNCT_1:def 4
.= ((exp_R - f) . x) * (1 / (exp_R . x)) by XCMPLX_1:217
.= ((exp_R - f) . x) / (exp_R . x) by XCMPLX_1:100
.= ((exp_R . x) - (f . x)) / (exp_R . x) by A3, A26, VALUED_1:13
.= ((exp_R . x) - 1) / (exp_R . x) by A2, A26 ;
A28: (exp_R - f) / exp_R is_differentiable_in x by A11, A26, FDIFF_1:16;
A29: ((exp_R - f) / exp_R ) . x > 0 by A18, A26;
A30: exp_R . x > 0 by SIN_COS:59;
diff (ln * ((exp_R - f) / exp_R )),x = (diff ((exp_R - f) / exp_R ),x) / (((exp_R - f) / exp_R ) . x) by A28, A29, TAYLOR_1:20
.= ((((exp_R - f) / exp_R ) `| Z) . x) / (((exp_R - f) / exp_R ) . x) by A11, A26, FDIFF_1:def 8
.= (1 / (exp_R . x)) / (((exp_R . x) - 1) / (exp_R . x)) by A12, A26, A27
.= 1 / ((exp_R . x) - 1) by A30, XCMPLX_1:55 ;
hence ((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) by A25, A26, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * ((exp_R - f) / exp_R ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R )) `| Z) . x = 1 / ((exp_R . x) - 1) ) ) by A1, A22, FDIFF_1:16; :: thesis: verum