let a be Real; :: thesis: for Z being open Subset of REAL
for f, f1 being PartFunc of REAL ,REAL st Z c= dom ((id Z) - (a (#) f)) & f = ln * f1 & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 ) ) holds
( (id Z) - (a (#) f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ) )
let Z be open Subset of REAL ; :: thesis: for f, f1 being PartFunc of REAL ,REAL st Z c= dom ((id Z) - (a (#) f)) & f = ln * f1 & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 ) ) holds
( (id Z) - (a (#) f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ) )
let f, f1 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom ((id Z) - (a (#) f)) & f = ln * f1 & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 ) ) implies ( (id Z) - (a (#) f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ) ) )
assume A1: ( Z c= dom ((id Z) - (a (#) f)) & f = ln * f1 & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 ) ) ) ; :: thesis: ( (id Z) - (a (#) f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ) )
then Z c= (dom (id Z)) /\ (dom (a (#) f)) by VALUED_1:12;
then A2: ( Z c= dom (id Z) & Z c= dom (a (#) f) ) by XBOOLE_1:18;
then A3: Z c= dom (ln * f1) by A1, VALUED_1:def 5;
A4: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:35;
then A5: ( id Z is_differentiable_on Z & ( for x being Real st x in Z holds
((id Z) `| Z) . x = 1 ) ) by A2, FDIFF_1:31;
A6: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 1 / (a + x) ) ) by A1, A3, Th1;
then A7: ( a (#) f is_differentiable_on Z & ( for x being Real st x in Z holds
((a (#) f) `| Z) . x = a * (diff f,x) ) ) by A2, FDIFF_1:28;
A8: for x being Real st x in Z holds
((a (#) f) `| Z) . x = a / (a + x)

proof

let x be Real; :: thesis: ( x in Z implies ((a (#) f) `| Z) . x = a / (a + x) )
assume A9: x in Z ; :: thesis: ((a (#) f) `| Z) . x = a / (a + x)
hence ((a (#) f) `| Z) . x = a * (diff f,x) by A2, A6, FDIFF_1:28
.= a * ((f `| Z) . x) by A6, A9, FDIFF_1:def 8
.= a * (1 / (a + x)) by A1, A3, A9, Th1
.= a / (a + x) by XCMPLX_1:100 ;
:: thesis: verum

end;

for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x)

proof

let x be Real; :: thesis: ( x in Z implies (((id Z) - (a (#) f)) `| Z) . x = x / (a + x) )
assume A10: x in Z ; :: thesis: (((id Z) - (a (#) f)) `| Z) . x = x / (a + x)
then A11: ( f1 . x = a + x & f1 . x > 0 ) by A1;
(((id Z) - (a (#) f)) `| Z) . x = (diff (id Z),x) - (diff (a (#) f),x) by A1, A5, A7, A10, FDIFF_1:27
.= (((id Z) `| Z) . x) - (diff (a (#) f),x) by A5, A10, FDIFF_1:def 8
.= (((id Z) `| Z) . x) - (((a (#) f) `| Z) . x) by A7, A10, FDIFF_1:def 8
.= 1 - (((a (#) f) `| Z) . x) by A2, A4, A10, FDIFF_1:31
.= 1 - (a / (a + x)) by A8, A10
.= ((1 * (a + x)) - a) / (a + x) by A11, XCMPLX_1:128
.= x / (a + x) ;
hence (((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ; :: thesis: verum

end;

hence ( (id Z) - (a (#) f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) - (a (#) f)) `| Z) . x = x / (a + x) ) ) by A1, A5, A7, FDIFF_1:27; :: thesis: verum