let a, b be Real; :: thesis: for Z being open Subset of REAL
for f being PartFunc of REAL ,REAL st Z c= dom (cos * f) & ( for x being Real st x in Z holds
f . x = (a * x) + b ) holds
( cos * f is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) ) )
let Z be open Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL st Z c= dom (cos * f) & ( for x being Real st x in Z holds
f . x = (a * x) + b ) holds
( cos * f is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) ) )
let f be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (cos * f) & ( for x being Real st x in Z holds
f . x = (a * x) + b ) implies ( cos * f is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) ) ) )
assume that
A1: Z c= dom (cos * f) and
A2: for x being Real st x in Z holds
f . x = (a * x) + b ; :: thesis: ( cos * f is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) ) )
for y being set st y in Z holds
y in dom f by A1, FUNCT_1:21;
then A3: Z c= dom f by TARSKI:def 3;
then A4: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = a ) ) by A2, FDIFF_1:31;
A5: for x being Real st x in Z holds
cos * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cos * f is_differentiable_in x )
assume x in Z ; :: thesis: cos * f is_differentiable_in x
then A6: f is_differentiable_in x by A4, FDIFF_1:16;
cos is_differentiable_in f . x by SIN_COS:68;
hence cos * f is_differentiable_in x by A6, FDIFF_2:13; :: thesis: verum

end;

then A7: cos * f is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b)))

proof

let x be Real; :: thesis: ( x in Z implies ((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) )
assume A8: x in Z ; :: thesis: ((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b)))
then A9: f is_differentiable_in x by A4, FDIFF_1:16;
A10: diff cos ,(f . x) = - (sin . (f . x)) by SIN_COS:68;
cos is_differentiable_in f . x by SIN_COS:68;
then diff (cos * f),x = (diff cos ,(f . x)) * (diff f,x) by A9, FDIFF_2:13
.= - ((sin . (f . x)) * (diff f,x)) by A10
.= - ((sin . ((a * x) + b)) * (diff f,x)) by A2, A8
.= - ((sin . ((a * x) + b)) * ((f `| Z) . x)) by A4, A8, FDIFF_1:def 8
.= - (a * (sin . ((a * x) + b))) by A2, A3, A8, FDIFF_1:31 ;
hence ((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) by A7, A8, FDIFF_1:def 8; :: thesis: verum

end;

hence ( cos * f is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * f) `| Z) . x = - (a * (sin . ((a * x) + b))) ) ) by A1, A5, FDIFF_1:16; :: thesis: verum