let a be Real; :: thesis: for Z being open Subset of REAL
for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = x - a & f1 . x > 0 & f2 . x = x + a & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) ) )
let Z be open Subset of REAL ; :: thesis: for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = x - a & f1 . x > 0 & f2 . x = x + a & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) ) )
let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = x - a & f1 . x > 0 & f2 . x = x + a & f2 . x > 0 ) ) implies ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) ) ) )
assume A1: ( Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = x - a & f1 . x > 0 & f2 . x = x + a & f2 . x > 0 ) ) ) ; :: thesis: ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) ) )
then for y being set st y in Z holds
y in dom (f1 / f2) by FUNCT_1:21;
then Z c= dom (f1 / f2) by TARSKI:def 3;
then A2: Z c= (dom f1) /\ ((dom f2) \ (f2 " {0 })) by RFUNCT_1:def 4;
then A3: ( Z c= dom f1 & Z c= (dom f2) \ (f2 " {0 }) ) by XBOOLE_1:18;
A4: Z c= dom f2 by A2, XBOOLE_1:1;
A5: for x being Real st x in Z holds
f1 . x = (1 * x) + (- a)

proof

let x be Real; :: thesis: ( x in Z implies f1 . x = (1 * x) + (- a) )
assume A6: x in Z ; :: thesis: f1 . x = (1 * x) + (- a)
(1 * x) + (- a) = (1 * x) - a ;
hence f1 . x = (1 * x) + (- a) by A1, A6; :: thesis: verum

end;

then A7: ( f1 is_differentiable_on Z & ( for x being Real st x in Z holds
(f1 `| Z) . x = 1 ) ) by A3, FDIFF_1:31;
A8: for x being Real st x in Z holds
f2 . x = (1 * x) + a by A1;
then A9: ( f2 is_differentiable_on Z & ( for x being Real st x in Z holds
(f2 `| Z) . x = 1 ) ) by A4, FDIFF_1:31;
for x being Real st x in Z holds
f2 . x <> 0 by A1;
then A10: f1 / f2 is_differentiable_on Z by A7, A9, FDIFF_2:21;
A11: for x being Real st x in Z holds
((f1 / f2) `| Z) . x = (2 * a) / ((x + a) ^2 )

proof

let x be Real; :: thesis: ( x in Z implies ((f1 / f2) `| Z) . x = (2 * a) / ((x + a) ^2 ) )
assume A12: x in Z ; :: thesis: ((f1 / f2) `| Z) . x = (2 * a) / ((x + a) ^2 )
then A13: f1 is_differentiable_in x by A7, FDIFF_1:16;
A14: f2 is_differentiable_in x by A9, A12, FDIFF_1:16;
A15: ( f2 . x <> 0 & f1 . x = x - a & f2 . x = x + a ) by A1, A12;
then diff (f1 / f2),x = (((diff f1,x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A13, A14, FDIFF_2:14
.= ((((f1 `| Z) . x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A7, A12, FDIFF_1:def 8
.= ((((f1 `| Z) . x) * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A9, A12, FDIFF_1:def 8
.= ((1 * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A3, A5, A12, FDIFF_1:31
.= ((1 * (f2 . x)) - (1 * (f1 . x))) / ((f2 . x) ^2 ) by A4, A8, A12, FDIFF_1:31
.= (2 * a) / ((x + a) ^2 ) by A15 ;
hence ((f1 / f2) `| Z) . x = (2 * a) / ((x + a) ^2 ) by A10, A12, FDIFF_1:def 8; :: thesis: verum

end;

A16: for x being Real st x in Z holds
(f1 / f2) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 / f2) . x > 0 )
assume A17: x in Z ; :: thesis: (f1 / f2) . x > 0
then A18: x in dom (f1 / f2) by A1, FUNCT_1:21;
A19: ( f1 . x > 0 & f2 . x > 0 ) by A1, A17;
(f1 / f2) . x = (f1 . x) * ((f2 . x) " ) by A18, RFUNCT_1:def 4
.= (f1 . x) / (f2 . x) by XCMPLX_0:def 9 ;
hence (f1 / f2) . x > 0 by A19, XREAL_1:141; :: thesis: verum

end;

A20: for x being Real st x in Z holds
ln * (f1 / f2) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * (f1 / f2) is_differentiable_in x )
assume A21: x in Z ; :: thesis: ln * (f1 / f2) is_differentiable_in x
then A22: f1 / f2 is_differentiable_in x by A10, FDIFF_1:16;
(f1 / f2) . x > 0 by A16, A21;
hence ln * (f1 / f2) is_differentiable_in x by A22, TAYLOR_1:20; :: thesis: verum

end;

then A23: ln * (f1 / f2) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) )
assume A24: x in Z ; :: thesis: ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 ))
then A25: f1 / f2 is_differentiable_in x by A10, FDIFF_1:16;
A26: ( f2 . x = x + a & f2 . x > 0 ) by A1, A24;
A27: x in dom (f1 / f2) by A1, A24, FUNCT_1:21;
A28: ( (f1 / f2) . x > 0 & f1 . x = x - a & f2 . x = x + a ) by A1, A16, A24;
then diff (ln * (f1 / f2)),x = (diff (f1 / f2),x) / ((f1 / f2) . x) by A25, TAYLOR_1:20
.= (((f1 / f2) `| Z) . x) / ((f1 / f2) . x) by A10, A24, FDIFF_1:def 8
.= ((2 * a) / ((x + a) ^2 )) / ((f1 / f2) . x) by A11, A24
.= ((2 * a) / ((x + a) ^2 )) / ((f1 . x) * ((f2 . x) " )) by A27, RFUNCT_1:def 4
.= ((2 * a) / ((x + a) * (x + a))) / ((x - a) / (x + a)) by A28, XCMPLX_0:def 9
.= (((2 * a) / (x + a)) / (x + a)) / ((x - a) / (x + a)) by XCMPLX_1:79
.= (((2 * a) / (x + a)) / ((x - a) / (x + a))) / (x + a) by XCMPLX_1:48
.= ((2 * a) / (x - a)) / (x + a) by A26, XCMPLX_1:55
.= (2 * a) / ((x - a) * (x + a)) by XCMPLX_1:79
.= (2 * a) / ((x ^2 ) - (a ^2 )) ;
hence ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) by A23, A24, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((x ^2 ) - (a ^2 )) ) ) by A1, A20, FDIFF_1:16; :: thesis: verum