let a be Real; :: thesis: for Z being open Subset of REAL
for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
let Z be open Subset of REAL ; :: thesis: for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) implies ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) ) )
assume A1: ( Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) ) ; :: thesis: ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
then for y being set st y in Z holds
y in dom (f1 / f2) by FUNCT_1:21;
then Z c= dom (f1 / f2) by TARSKI:def 3;
then A2: Z c= (dom f1) /\ ((dom f2) \ (f2 " {0 })) by RFUNCT_1:def 4;
then A3: ( Z c= dom f1 & Z c= (dom f2) \ (f2 " {0 }) ) by XBOOLE_1:18;
A4: Z c= dom f2 by A2, XBOOLE_1:1;
A5: for x being Real st x in Z holds
f1 . x = (1 * x) + a by A1;
then A6: ( f1 is_differentiable_on Z & ( for x being Real st x in Z holds
(f1 `| Z) . x = 1 ) ) by A3, FDIFF_1:31;
A7: for x being Real st x in Z holds
f2 . x = ((- 1) * x) + a

proof

let x be Real; :: thesis: ( x in Z implies f2 . x = ((- 1) * x) + a )
assume x in Z ; :: thesis: f2 . x = ((- 1) * x) + a
then f2 . x = a - x by A1;
hence f2 . x = ((- 1) * x) + a ; :: thesis: verum

end;

then A8: ( f2 is_differentiable_on Z & ( for x being Real st x in Z holds
(f2 `| Z) . x = - 1 ) ) by A4, FDIFF_1:31;
for x being Real st x in Z holds
f2 . x <> 0 by A1;
then A9: f1 / f2 is_differentiable_on Z by A6, A8, FDIFF_2:21;
A10: for x being Real st x in Z holds
((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 )

proof

let x be Real; :: thesis: ( x in Z implies ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 ) )
assume A11: x in Z ; :: thesis: ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 )
then A12: f1 is_differentiable_in x by A6, FDIFF_1:16;
A13: f2 is_differentiable_in x by A8, A11, FDIFF_1:16;
A14: ( f2 . x <> 0 & f1 . x = a + x & f2 . x = a - x ) by A1, A11;
then diff (f1 / f2),x = (((diff f1,x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A12, A13, FDIFF_2:14
.= ((((f1 `| Z) . x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A6, A11, FDIFF_1:def 8
.= ((((f1 `| Z) . x) * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A8, A11, FDIFF_1:def 8
.= ((1 * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A3, A5, A11, FDIFF_1:31
.= ((1 * (f2 . x)) - ((- 1) * (f1 . x))) / ((f2 . x) ^2 ) by A4, A7, A11, FDIFF_1:31
.= (2 * a) / ((a - x) ^2 ) by A14 ;
hence ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 ) by A9, A11, FDIFF_1:def 8; :: thesis: verum

end;

A15: for x being Real st x in Z holds
(f1 / f2) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 / f2) . x > 0 )
assume A16: x in Z ; :: thesis: (f1 / f2) . x > 0
then A17: x in dom (f1 / f2) by A1, FUNCT_1:21;
A18: ( f1 . x > 0 & f2 . x > 0 ) by A1, A16;
(f1 / f2) . x = (f1 . x) * ((f2 . x) " ) by A17, RFUNCT_1:def 4
.= (f1 . x) / (f2 . x) by XCMPLX_0:def 9 ;
hence (f1 / f2) . x > 0 by A18, XREAL_1:141; :: thesis: verum

end;

A19: for x being Real st x in Z holds
ln * (f1 / f2) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * (f1 / f2) is_differentiable_in x )
assume A20: x in Z ; :: thesis: ln * (f1 / f2) is_differentiable_in x
then A21: f1 / f2 is_differentiable_in x by A9, FDIFF_1:16;
(f1 / f2) . x > 0 by A15, A20;
hence ln * (f1 / f2) is_differentiable_in x by A21, TAYLOR_1:20; :: thesis: verum

end;

then A22: ln * (f1 / f2) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) )
assume A23: x in Z ; :: thesis: ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 ))
then A24: f1 / f2 is_differentiable_in x by A9, FDIFF_1:16;
A25: ( f2 . x = a - x & f2 . x > 0 ) by A1, A23;
A26: x in dom (f1 / f2) by A1, A23, FUNCT_1:21;
A27: ( (f1 / f2) . x > 0 & f1 . x = a + x & f2 . x = a - x ) by A1, A15, A23;
then diff (ln * (f1 / f2)),x = (diff (f1 / f2),x) / ((f1 / f2) . x) by A24, TAYLOR_1:20
.= (((f1 / f2) `| Z) . x) / ((f1 / f2) . x) by A9, A23, FDIFF_1:def 8
.= ((2 * a) / ((a - x) ^2 )) / ((f1 / f2) . x) by A10, A23
.= ((2 * a) / ((a - x) ^2 )) / ((f1 . x) * ((f2 . x) " )) by A26, RFUNCT_1:def 4
.= ((2 * a) / ((a - x) * (a - x))) / ((a + x) / (a - x)) by A27, XCMPLX_0:def 9
.= (((2 * a) / (a - x)) / (a - x)) / ((a + x) / (a - x)) by XCMPLX_1:79
.= (((2 * a) / (a - x)) / ((a + x) / (a - x))) / (a - x) by XCMPLX_1:48
.= ((2 * a) / (a + x)) / (a - x) by A25, XCMPLX_1:55
.= (2 * a) / ((a + x) * (a - x)) by XCMPLX_1:79
.= (2 * a) / ((a ^2 ) - (x ^2 )) ;
hence ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) by A22, A23, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) ) by A1, A19, FDIFF_1:16; :: thesis: verum