let Z be open Subset of REAL ; :: thesis: ( Z c= dom (arccot * cot ) & ( for x being Real st x in Z holds
( cot . x > - 1 & cot . x < 1 ) ) implies ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) ) )
assume that
A1: Z c= dom (arccot * cot ) and
A2: for x being Real st x in Z holds
( cot . x > - 1 & cot . x < 1 ) ; :: thesis: ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) )
dom (arccot * cot ) c= dom cot by RELAT_1:44;
then A3: Z c= dom cot by A1, XBOOLE_1:1;
AA: for x being Real st x in Z holds
arccot * cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies arccot * cot is_differentiable_in x )
assume A4: x in Z ; :: thesis: arccot * cot is_differentiable_in x
then sin . x <> 0 by A3, FDIFF_8:2;
then A5: cot is_differentiable_in x by FDIFF_7:47;
( cot . x > - 1 & cot . x < 1 ) by A2, A4;
hence arccot * cot is_differentiable_in x by A5, SIN_COS9:86; :: thesis: verum

end;

then A6: arccot * cot is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1

proof

let x be Real; :: thesis: ( x in Z implies ((arccot * cot ) `| Z) . x = 1 )
assume A7: x in Z ; :: thesis: ((arccot * cot ) `| Z) . x = 1
then A8: sin . x <> 0 by A3, FDIFF_8:2;
then A9: cot is_differentiable_in x by FDIFF_7:47;
A10: ( cot . x > - 1 & cot . x < 1 ) by A2, A7;
A13: cot . x = (cos . x) / (sin . x) by A3, A7, RFUNCT_1:def 4;
A14: (sin . x) ^2 <> 0 by A8, SQUARE_1:74;
((arccot * cot ) `| Z) . x = diff (arccot * cot ),x by A6, A7, FDIFF_1:def 8
.= - ((diff cot ,x) / (1 + ((cot . x) ^2 ))) by A9, A10, SIN_COS9:86
.= - ((- (1 / ((sin . x) ^2 ))) / (1 + ((cot . x) ^2 ))) by A8, FDIFF_7:47
.= (1 / ((sin . x) ^2 )) / (1 + ((cot . x) ^2 ))
.= 1 / (((sin . x) ^2 ) * (1 + (((cos . x) / (sin . x)) * ((cos . x) / (sin . x))))) by A13, XCMPLX_1:79
.= 1 / (((sin . x) ^2 ) * (1 + (((cos . x) ^2 ) / ((sin . x) ^2 )))) by XCMPLX_1:77
.= 1 / (((sin . x) ^2 ) + ((((sin . x) ^2 ) * ((cos . x) ^2 )) / ((sin . x) ^2 )))
.= 1 / (((sin . x) ^2 ) + ((cos . x) ^2 )) by A14, XCMPLX_1:90
.= 1 / 1 by SIN_COS:31
.= 1 ;
hence ((arccot * cot ) `| Z) . x = 1 ; :: thesis: verum

end;

hence ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) ) by A1, AA, FDIFF_1:16; :: thesis: verum