let Z be open Subset of REAL ; :: thesis: ( Z c= dom (sin * arccot ) & Z c= ].(- 1),1.[ implies ( sin * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 ))) ) ) )
assume that
A1: Z c= dom (sin * arccot ) and
A2: Z c= ].(- 1),1.[ ; :: thesis: ( sin * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 ))) ) )
AA: for x being Real st x in Z holds
sin * arccot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies sin * arccot is_differentiable_in x )
assume A3: x in Z ; :: thesis: sin * arccot is_differentiable_in x
arccot is_differentiable_on Z by A2, SIN_COS9:82;
then A4: arccot is_differentiable_in x by A3, FDIFF_1:16;
sin is_differentiable_in arccot . x by SIN_COS:69;
hence sin * arccot is_differentiable_in x by A4, FDIFF_2:13; :: thesis: verum

end;

then A5: sin * arccot is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 )))

proof

let x be Real; :: thesis: ( x in Z implies ((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 ))) )
assume A6: x in Z ; :: thesis: ((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 )))
A7: arccot is_differentiable_on Z by A2, SIN_COS9:82;
then A8: arccot is_differentiable_in x by A6, FDIFF_1:16;
A9: sin is_differentiable_in arccot . x by SIN_COS:69;
((sin * arccot ) `| Z) . x = diff (sin * arccot ),x by A5, A6, FDIFF_1:def 8
.= (diff sin ,(arccot . x)) * (diff arccot ,x) by A8, A9, FDIFF_2:13
.= (cos . (arccot . x)) * (diff arccot ,x) by SIN_COS:69
.= (cos . (arccot . x)) * ((arccot `| Z) . x) by A6, A7, FDIFF_1:def 8
.= (cos . (arccot . x)) * (- (1 / (1 + (x ^2 )))) by A2, A6, SIN_COS9:82
.= - ((cos . (arccot . x)) / (1 + (x ^2 ))) ;
hence ((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 ))) ; :: thesis: verum

end;

hence ( sin * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((sin * arccot ) `| Z) . x = - ((cos . (arccot . x)) / (1 + (x ^2 ))) ) ) by A1, AA, FDIFF_1:16; :: thesis: verum