let Z be open Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL st Z c= dom f & f | Z = id Z holds
( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 1 ) )
let f be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom f & f | Z = id Z implies ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 1 ) ) )
assume that
A1: Z c= dom f and
A2: f | Z = id Z ; :: thesis: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = 1 ) )
reconsider L = id REAL as PartFunc of REAL ,REAL ;
for p being Real holds L . p = 1 * p by FUNCT_1:35;
then reconsider L = L as LINEAR by Def4;
set R = cf;
A3: dom cf = REAL by FUNCOP_1:19;

now

let h be convergent_to_0 Real_Sequence; :: thesis: ( (h " ) (#) (cf /* h) is convergent & lim ((h " ) (#) (cf /* h)) = 0 )

A4: now

let n be Nat; :: thesis: ((h " ) (#) (cf /* h)) . n = 0
X: n in NAT by ORDINAL1:def 13;
A5: rng h c= dom cf by A3;
thus ((h " ) (#) (cf /* h)) . n = ((h " ) . n) * ((cf /* h) . n) by X, SEQ_1:12
.= ((h " ) . n) * (cf . (h . n)) by A5, X, FUNCT_2:185
.= ((h " ) . n) * 0 by FUNCOP_1:13
.= 0 ; :: thesis: verum

end;

then A6: (h " ) (#) (cf /* h) is V8() by VALUED_0:def 18;
hence (h " ) (#) (cf /* h) is convergent ; :: thesis: lim ((h " ) (#) (cf /* h)) = 0
((h " ) (#) (cf /* h)) . 0 = 0 by A4;
hence lim ((h " ) (#) (cf /* h)) = 0 by A6, SEQ_4:40; :: thesis: verum

end;

then reconsider R = cf as REST by Def3;

A7: now

let x be Real; :: thesis: ( x in Z implies f . x = x )
assume A8: x in Z ; :: thesis: f . x = x
then (f | Z) . x = x by A2, FUNCT_1:35;
hence f . x = x by A8, FUNCT_1:72; :: thesis: verum

end;

A9: now

let x0 be Real; :: thesis: ( x0 in Z implies f is_differentiable_in x0 )
assume A10: x0 in Z ; :: thesis: f is_differentiable_in x0
then consider N being Neighbourhood of x0 such that
A11: N c= Z by RCOMP_1:39;
A12: N c= dom f by A1, A11, XBOOLE_1:1;
for x being Real st x in N holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))

proof

let x be Real; :: thesis: ( x in N implies (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) )
assume x in N ; :: thesis: (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))
hence (f . x) - (f . x0) = x - (f . x0) by A7, A11
.= x - x0 by A7, A10
.= (L . (x - x0)) + 0 by FUNCT_1:35
.= (L . (x - x0)) + (R . (x - x0)) by FUNCOP_1:13 ;
:: thesis: verum

end;

hence f is_differentiable_in x0 by A12, Def5; :: thesis: verum

end;

hence A13: f is_differentiable_on Z by A1, Th16; :: thesis: for x being Real st x in Z holds
(f `| Z) . x = 1
let x0 be Real; :: thesis: ( x0 in Z implies (f `| Z) . x0 = 1 )
assume A14: x0 in Z ; :: thesis: (f `| Z) . x0 = 1
then A15: f is_differentiable_in x0 by A9;
then ex N being Neighbourhood of x0 st
( N c= dom f & ex L being LINEAR ex R being REST st
for x being Real st x in N holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) ) by Def5;
then consider N being Neighbourhood of x0 such that
A16: N c= dom f ;
consider N1 being Neighbourhood of x0 such that
A17: N1 c= Z by A14, RCOMP_1:39;
consider N2 being Neighbourhood of x0 such that
A18: ( N2 c= N1 & N2 c= N ) by RCOMP_1:38;
A19: N2 c= dom f by A16, A18, XBOOLE_1:1;
A20: for x being Real st x in N2 holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))

proof

let x be Real; :: thesis: ( x in N2 implies (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) )
assume x in N2 ; :: thesis: (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))
then x in N1 by A18;
hence (f . x) - (f . x0) = x - (f . x0) by A7, A17
.= x - x0 by A7, A14
.= (L . (x - x0)) + 0 by FUNCT_1:35
.= (L . (x - x0)) + (R . (x - x0)) by FUNCOP_1:13 ;
:: thesis: verum

end;

thus (f `| Z) . x0 = diff f,x0 by A13, A14, Def8
.= L . 1 by A15, A19, A20, Def6
.= 1 by FUNCT_1:35 ; :: thesis: verum