let f be PartFunc of REAL ,REAL ; :: thesis: for x0 being real number
for N being Neighbourhood of x0 st f is_differentiable_in x0 & N c= dom f holds
for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= N holds
( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) )
let x0 be real number ; :: thesis: for N being Neighbourhood of x0 st f is_differentiable_in x0 & N c= dom f holds
for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= N holds
( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) )
let N be Neighbourhood of x0; :: thesis: ( f is_differentiable_in x0 & N c= dom f implies for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= N holds
( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) ) )
assume A1: ( f is_differentiable_in x0 & N c= dom f ) ; :: thesis: for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= N holds
( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) )
let h be convergent_to_0 Real_Sequence; :: thesis: for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= N holds
( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) )
let c be V8() Real_Sequence; :: thesis: ( rng c = {x0} & rng (h + c) c= N implies ( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) ) )
assume A2: ( rng c = {x0} & rng (h + c) c= N ) ; :: thesis: ( (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent & diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) )
consider N1 being Neighbourhood of x0 such that
A3: ( N1 c= dom f & ex L being LINEAR ex R being REST st
for x being Real st x in N1 holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) ) by A1, Def5;
consider L being LINEAR, R being REST such that
A4: for x being Real st x in N1 holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) by A3;
consider N2 being Neighbourhood of x0 such that
A5: ( N2 c= N & N2 c= N1 ) by RCOMP_1:38;
consider g being real number such that
A6: ( 0 < g & N2 = ].(x0 - g),(x0 + g).[ ) by RCOMP_1:def 7;
A7: x0 in N2

proof

A8: x0 + 0 < x0 + g by A6, XREAL_1:10;
x0 - g < x0 - 0 by A6, XREAL_1:17;
hence x0 in N2 by A6, A8; :: thesis: verum

end;

ex n being Element of NAT st
( rng (c ^\ n) c= N2 & rng ((h + c) ^\ n) c= N2 )

proof

x0 in rng c by A2, TARSKI:def 1;
then A10: lim c = x0 by SEQ_4:40;
A11: ( h is convergent & lim h = 0 ) by Def1;
then A12: lim (h + c) = 0 + x0 by A10, SEQ_2:20
.= x0 ;
h + c is convergent by A11, SEQ_2:19;
then consider n being Element of NAT such that
A13: for m being Element of NAT st n <= m holds
abs (((h + c) . m) - x0) < g by A6, A12, SEQ_2:def 7;
A14: rng (c ^\ n) = {x0} by A2, VALUED_0:26;
take n ; :: thesis: ( rng (c ^\ n) c= N2 & rng ((h + c) ^\ n) c= N2 )
thus rng (c ^\ n) c= N2 :: thesis: rng ((h + c) ^\ n) c= N2

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (c ^\ n) or y in N2 )
assume y in rng (c ^\ n) ; :: thesis: y in N2
hence y in N2 by A7, A14, TARSKI:def 1; :: thesis: verum

end;

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng ((h + c) ^\ n) or y in N2 )
assume y in rng ((h + c) ^\ n) ; :: thesis: y in N2
then consider m being Element of NAT such that
A15: y = ((h + c) ^\ n) . m by FUNCT_2:190;
n + 0 <= n + m by XREAL_1:9;
then abs (((h + c) . (n + m)) - x0) < g by A13;
then ( - g < ((h + c) . (m + n)) - x0 & ((h + c) . (m + n)) - x0 < g ) by SEQ_2:9;
then ( - g < (((h + c) ^\ n) . m) - x0 & (((h + c) ^\ n) . m) - x0 < g ) by NAT_1:def 3;
then ( x0 + (- g) < ((h + c) ^\ n) . m & ((h + c) ^\ n) . m < x0 + g ) by XREAL_1:21, XREAL_1:22;
hence y in N2 by A6, A15; :: thesis: verum

end;

then consider n being Element of NAT such that
A16: ( rng (c ^\ n) c= N2 & rng ((h + c) ^\ n) c= N2 ) ;
A17: rng (c ^\ n) c= dom f

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (c ^\ n) or y in dom f )
A18: rng (c ^\ n) = rng c by VALUED_0:26;
assume y in rng (c ^\ n) ; :: thesis: y in dom f
then y = x0 by A2, A18, TARSKI:def 1;
then y in N by A5, A7;
hence y in dom f by A1; :: thesis: verum

end;

A19: rng ((h + c) ^\ n) c= dom f

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng ((h + c) ^\ n) or y in dom f )
assume y in rng ((h + c) ^\ n) ; :: thesis: y in dom f
then y in N2 by A16;
then y in N by A5;
hence y in dom f by A1; :: thesis: verum

end;

A20: rng c c= dom f

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng c or y in dom f )
assume y in rng c ; :: thesis: y in dom f
then y = x0 by A2, TARSKI:def 1;
then y in N by A5, A7;
hence y in dom f by A1; :: thesis: verum

end;

A21: rng (h + c) c= dom f

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (h + c) or y in dom f )
assume y in rng (h + c) ; :: thesis: y in dom f
then y in N by A2;
hence y in dom f by A1; :: thesis: verum

end;

A22: for x being Real st x in N2 holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) by A4, A5;
A23: for k being Element of NAT holds (f . (((h + c) ^\ n) . k)) - (f . ((c ^\ n) . k)) = (L . ((h ^\ n) . k)) + (R . ((h ^\ n) . k))

proof

let k be Element of NAT ; :: thesis: (f . (((h + c) ^\ n) . k)) - (f . ((c ^\ n) . k)) = (L . ((h ^\ n) . k)) + (R . ((h ^\ n) . k))
((h + c) ^\ n) . k in rng ((h + c) ^\ n) by VALUED_0:28;
then A24: ((h + c) ^\ n) . k in N2 by A16;
A25: (((h + c) ^\ n) . k) - ((c ^\ n) . k) = (((h ^\ n) + (c ^\ n)) . k) - ((c ^\ n) . k) by SEQM_3:37
.= (((h ^\ n) . k) + ((c ^\ n) . k)) - ((c ^\ n) . k) by SEQ_1:11
.= (h ^\ n) . k ;
A26: (c ^\ n) . k in rng (c ^\ n) by VALUED_0:28;
rng (c ^\ n) = rng c by VALUED_0:26;
then (c ^\ n) . k = x0 by A2, A26, TARSKI:def 1;
hence (f . (((h + c) ^\ n) . k)) - (f . ((c ^\ n) . k)) = (L . ((h ^\ n) . k)) + (R . ((h ^\ n) . k)) by A4, A5, A24, A25; :: thesis: verum

end;

A27: L is total by Def4;
A28: R is total by Def3;
A29: (f /* ((h + c) ^\ n)) - (f /* (c ^\ n)) = (L /* (h ^\ n)) + (R /* (h ^\ n))

proof

now

let k be Element of NAT ; :: thesis: ((f /* ((h + c) ^\ n)) - (f /* (c ^\ n))) . k = ((L /* (h ^\ n)) + (R /* (h ^\ n))) . k
thus ((f /* ((h + c) ^\ n)) - (f /* (c ^\ n))) . k = ((f /* ((h + c) ^\ n)) . k) - ((f /* (c ^\ n)) . k) by RFUNCT_2:6
.= (f . (((h + c) ^\ n) . k)) - ((f /* (c ^\ n)) . k) by A19, FUNCT_2:185
.= (f . (((h + c) ^\ n) . k)) - (f . ((c ^\ n) . k)) by A17, FUNCT_2:185
.= (L . ((h ^\ n) . k)) + (R . ((h ^\ n) . k)) by A23
.= ((L /* (h ^\ n)) . k) + (R . ((h ^\ n) . k)) by A27, FUNCT_2:192
.= ((L /* (h ^\ n)) . k) + ((R /* (h ^\ n)) . k) by A28, FUNCT_2:192
.= ((L /* (h ^\ n)) + (R /* (h ^\ n))) . k by SEQ_1:11 ; :: thesis: verum

end;

hence (f /* ((h + c) ^\ n)) - (f /* (c ^\ n)) = (L /* (h ^\ n)) + (R /* (h ^\ n)) by FUNCT_2:113; :: thesis: verum

end;

A30: ( ((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " ) is convergent & lim (((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " )) = L . 1 )

proof

deffunc H₁( Element of NAT ) -> Element of REAL = (L . 1) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . $1);
consider s1 being Real_Sequence such that
A31: for k being Element of NAT holds s1 . k = H₁(k) from SEQ_1:sch 1();
consider s being Real such that
A32: for p1 being Real holds L . p1 = s * p1 by Def4;
A33: L . 1 = s * 1 by A32
.= s ;

now

let m be Element of NAT ; :: thesis: (((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " )) . m = s1 . m
h ^\ n is non-zero by Def1;
then A34: (h ^\ n) . m <> 0 by SEQ_1:7;
thus (((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " )) . m = (((L /* (h ^\ n)) + (R /* (h ^\ n))) . m) * (((h ^\ n) " ) . m) by SEQ_1:12
.= (((L /* (h ^\ n)) . m) + ((R /* (h ^\ n)) . m)) * (((h ^\ n) " ) . m) by SEQ_1:11
.= (((L /* (h ^\ n)) . m) * (((h ^\ n) " ) . m)) + (((R /* (h ^\ n)) . m) * (((h ^\ n) " ) . m))
.= (((L /* (h ^\ n)) . m) * (((h ^\ n) " ) . m)) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m) by SEQ_1:12
.= (((L /* (h ^\ n)) . m) * (((h ^\ n) . m) " )) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m) by VALUED_1:10
.= ((L . ((h ^\ n) . m)) * (((h ^\ n) . m) " )) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m) by A27, FUNCT_2:192
.= ((s * ((h ^\ n) . m)) * (((h ^\ n) . m) " )) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m) by A32
.= (s * (((h ^\ n) . m) * (((h ^\ n) . m) " ))) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m)
.= (s * 1) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . m) by A34, XCMPLX_0:def 7
.= s1 . m by A31, A33 ; :: thesis: verum

end;

then A35: ((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " ) = s1 by FUNCT_2:113;

A36: now

let r be real number ; :: thesis: ( 0 < r implies ex n1 being Element of NAT st
for k being Element of NAT st n1 <= k holds
abs ((s1 . k) - (L . 1)) < r )
assume A37: 0 < r ; :: thesis: ex n1 being Element of NAT st
for k being Element of NAT st n1 <= k holds
abs ((s1 . k) - (L . 1)) < r
( ((h ^\ n) " ) (#) (R /* (h ^\ n)) is convergent & lim (((h ^\ n) " ) (#) (R /* (h ^\ n))) = 0 ) by Def3;
then consider m being Element of NAT such that
A38: for k being Element of NAT st m <= k holds
abs (((((h ^\ n) " ) (#) (R /* (h ^\ n))) . k) - 0 ) < r by A37, SEQ_2:def 7;
take n1 = m; :: thesis: for k being Element of NAT st n1 <= k holds
abs ((s1 . k) - (L . 1)) < r
let k be Element of NAT ; :: thesis: ( n1 <= k implies abs ((s1 . k) - (L . 1)) < r )
assume A39: n1 <= k ; :: thesis: abs ((s1 . k) - (L . 1)) < r
abs ((s1 . k) - (L . 1)) = abs (((L . 1) + (((R /* (h ^\ n)) (#) ((h ^\ n) " )) . k)) - (L . 1)) by A31
.= abs (((((h ^\ n) " ) (#) (R /* (h ^\ n))) . k) - 0 ) ;
hence abs ((s1 . k) - (L . 1)) < r by A38, A39; :: thesis: verum

end;

hence ((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " ) is convergent by A35, SEQ_2:def 6; :: thesis: lim (((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " )) = L . 1
hence lim (((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " )) = L . 1 by A35, A36, SEQ_2:def 7; :: thesis: verum

end;

A40: N2 c= dom f by A1, A5, XBOOLE_1:1;
A41: ((L /* (h ^\ n)) + (R /* (h ^\ n))) (#) ((h ^\ n) " ) = (((f /* (h + c)) ^\ n) - (f /* (c ^\ n))) (#) ((h ^\ n) " ) by A21, A29, VALUED_0:27
.= (((f /* (h + c)) ^\ n) - ((f /* c) ^\ n)) (#) ((h ^\ n) " ) by A20, VALUED_0:27
.= (((f /* (h + c)) - (f /* c)) ^\ n) (#) ((h ^\ n) " ) by SEQM_3:39
.= (((f /* (h + c)) - (f /* c)) ^\ n) (#) ((h " ) ^\ n) by SEQM_3:41
.= (((f /* (h + c)) - (f /* c)) (#) (h " )) ^\ n by SEQM_3:42 ;
then A42: L . 1 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) by A30, SEQ_4:36;
thus (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent by A30, A41, SEQ_4:35; :: thesis: diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c)))
thus diff f,x0 = lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) by A1, A22, A40, A42, Def6; :: thesis: verum