let T be TopSpace; :: thesis: (PSO T) /\ (D(c,ps) T) = the topology of T
thus (PSO T) /\ (D(c,ps) T) c= the topology of T :: according to XBOOLE_0:def 10 :: thesis: the topology of T c= (PSO T) /\ (D(c,ps) T)

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in (PSO T) /\ (D(c,ps) T) or x in the topology of T )
assume x in (PSO T) /\ (D(c,ps) T) ; :: thesis: x in the topology of T
then A1: ( x in PSO T & x in D(c,ps) T ) by XBOOLE_0:def 4;
then consider A being Subset of T such that
A2: x = A and
A3: A is pre-semi-open ;
A4: A = psInt A by A3, Th5;
consider Z being Subset of T such that
A5: x = Z and
A6: Int Z = psInt Z by A1;
Z is open by A2, A4, A5, A6, TOPS_1:51;
hence x in the topology of T by A5, PRE_TOPC:def 5; :: thesis: verum

end;

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in the topology of T or x in (PSO T) /\ (D(c,ps) T) )
assume A7: x in the topology of T ; :: thesis: x in (PSO T) /\ (D(c,ps) T)
then reconsider K = x as Subset of T ;
K is open by A7, PRE_TOPC:def 5;
then A8: K = Int K by TOPS_1:55;
then A9: K c= Int (Cl K) by PRE_TOPC:48, TOPS_1:48;
Int (Cl K) c= Cl (Int (Cl K)) by PRE_TOPC:48;
then K c= Cl (Int (Cl K)) by A9, XBOOLE_1:1;
then A10: K is pre-semi-open by Def4;
then A11: K in PSO T ;
Int K = psInt K by A8, A10, Th5;
then K in { B where B is Subset of T : Int B = psInt B } ;
hence x in (PSO T) /\ (D(c,ps) T) by A11, XBOOLE_0:def 4; :: thesis: verum