let x, y be Point of Complex_l1_Space ; :: thesis: for p being Complex holds
( ( ||.x.|| = 0 implies x = 0. Complex_l1_Space ) & ( x = 0. Complex_l1_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(p * x).|| = |.p.| * ||.x.|| )
let p be Complex; :: thesis: ( ( ||.x.|| = 0 implies x = 0. Complex_l1_Space ) & ( x = 0. Complex_l1_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(p * x).|| = |.p.| * ||.x.|| )

A1: now

assume A2: ||.x.|| = 0 ; :: thesis: x = 0. Complex_l1_Space
A3: ||.x.|| = Sum |.(seq_id x).| by Th8;
seq_id x is absolutely_summable by Th8;
then A4: for n being Element of NAT holds 0 = (seq_id x) . n by A2, A3, Th6;
x in the_set_of_ComplexSequences by Def1;
hence x = 0. Complex_l1_Space by A4, Th8, CSSPACE:def 6; :: thesis: verum

end;

A5: now

assume x = 0. Complex_l1_Space ; :: thesis: ||.x.|| = 0
then A6: for n being Element of NAT holds (seq_id x) . n = 0 by Th8, CSSPACE:def 6;
thus ||.x.|| = the norm of Complex_l1_Space . x by CLVECT_1:def 10
.= Sum |.(seq_id x).| by Def2
.= 0 by A6, Th5 ; :: thesis: verum

end;

A7: for n being Element of NAT holds 0 <= |.(seq_id x).| . n

proof

let n be Element of NAT ; :: thesis: 0 <= |.(seq_id x).| . n
0 <= |.((seq_id x) . n).| by COMPLEX1:132;
hence 0 <= |.(seq_id x).| . n by VALUED_1:18; :: thesis: verum

end;

seq_id x is absolutely_summable by Def1;
then A8: |.(seq_id x).| is summable by COMSEQ_3:def 11;
A9: ||.x.|| = Sum |.(seq_id x).| by Th8;
A10: ||.y.|| = Sum |.(seq_id y).| by Th8;
A11: Sum |.(seq_id (x + y)).| = ||.(x + y).|| by Th8;
A12: for n being Element of NAT holds |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).|

proof

let n be Element of NAT ; :: thesis: |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).|
|.(seq_id (x + y)).| . n = |.(seq_id ((seq_id x) + (seq_id y))).| . n by Th8
.= |.((seq_id x) + (seq_id y)).| . n by CSSPACE:3
.= |.(((seq_id x) + (seq_id y)) . n).| by VALUED_1:18
.= |.(((seq_id x) . n) + ((seq_id y) . n)).| by VALUED_1:1 ;
hence |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).| ; :: thesis: verum

end;

A13: for n being Element of NAT holds |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n)

proof

let n be Element of NAT ; :: thesis: |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n)
|.(((seq_id x) . n) + ((seq_id y) . n)).| <= |.((seq_id x) . n).| + |.((seq_id y) . n).| by COMPLEX1:142;
then |.(seq_id (x + y)).| . n <= |.((seq_id x) . n).| + |.((seq_id y) . n).| by A12;
then |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + |.((seq_id y) . n).| by VALUED_1:18;
hence |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n) by VALUED_1:18; :: thesis: verum

end;

A14: for n being Element of NAT holds |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n

proof

let n be Element of NAT ; :: thesis: |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n
(|.(seq_id x).| . n) + (|.(seq_id y).| . n) = (|.(seq_id x).| + |.(seq_id y).|) . n by SEQ_1:11;
hence |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n by A13; :: thesis: verum

end;

seq_id x is absolutely_summable by Def1;
then A15: |.(seq_id x).| is summable by COMSEQ_3:def 11;
seq_id y is absolutely_summable by Def1;
then A16: |.(seq_id y).| is summable by COMSEQ_3:def 11;
then A17: |.(seq_id x).| + |.(seq_id y).| is summable by A15, SERIES_1:10;

now

let n be Element of NAT ; :: thesis: 0 <= |.(seq_id (x + y)).| . n
|.(seq_id (x + y)).| . n = |.((seq_id (x + y)) . n).| by VALUED_1:18;
hence 0 <= |.(seq_id (x + y)).| . n by COMPLEX1:132; :: thesis: verum

end;

then A18: Sum |.(seq_id (x + y)).| <= Sum (|.(seq_id x).| + |.(seq_id y).|) by A14, A17, SERIES_1:24;
A19: for n being Element of NAT holds |.(p (#) (seq_id x)).| . n = |.p.| * (|.(seq_id x).| . n)

proof

let n be Element of NAT ; :: thesis: |.(p (#) (seq_id x)).| . n = |.p.| * (|.(seq_id x).| . n)
|.(p (#) (seq_id x)).| . n = |.((p (#) (seq_id x)) . n).| by VALUED_1:18
.= |.(p * ((seq_id x) . n)).| by VALUED_1:6
.= |.p.| * |.((seq_id x) . n).| by COMPLEX1:151
.= |.p.| * (|.(seq_id x).| . n) by VALUED_1:18 ;
hence |.(p (#) (seq_id x)).| . n = |.p.| * (|.(seq_id x).| . n) ; :: thesis: verum

end;

seq_id x is absolutely_summable by Def1;
then A20: |.(seq_id x).| is summable by COMSEQ_3:def 11;
||.(p * x).|| = Sum |.(seq_id (p * x)).| by Th8
.= Sum |.(seq_id (p (#) (seq_id x))).| by Th8
.= Sum |.(p (#) (seq_id x)).| by CSSPACE:3
.= Sum (|.p.| (#) |.(seq_id x).|) by A19, SEQ_1:13
.= |.p.| * (Sum |.(seq_id x).|) by A20, SERIES_1:13
.= |.p.| * ||.x.|| by Th8 ;
hence ( ( ||.x.|| = 0 implies x = 0. Complex_l1_Space ) & ( x = 0. Complex_l1_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(p * x).|| = |.p.| * ||.x.|| ) by A1, A5, A7, A8, A9, A10, A11, A16, A18, SERIES_1:10, SERIES_1:21; :: thesis: verum