let V be non empty RLSStruct ; :: thesis: for M being Subset of V holds
( M is convex iff for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M )
let M be Subset of V; :: thesis: ( M is convex iff for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M )
A1: ( M is convex implies for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M )

proof

assume A2: M is convex ; :: thesis: for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M
let r be Real; :: thesis: ( 0 < r & r < 1 implies (r * M) + ((1 - r) * M) c= M )
assume A3: ( 0 < r & r < 1 ) ; :: thesis: (r * M) + ((1 - r) * M) c= M
for x being Element of V st x in (r * M) + ((1 - r) * M) holds
x in M

proof

let x be Element of V; :: thesis: ( x in (r * M) + ((1 - r) * M) implies x in M )
assume x in (r * M) + ((1 - r) * M) ; :: thesis: x in M
then x in { (u + v) where u, v is Element of V : ( u in r * M & v in (1 - r) * M ) } by RUSUB_4:def 10;
then consider u, v being Element of V such that
A4: ( x = u + v & u in r * M & v in (1 - r) * M ) ;
consider w1 being Element of V such that
A5: ( u = r * w1 & w1 in M ) by A4;
consider w2 being Element of V such that
A6: ( v = (1 - r) * w2 & w2 in M ) by A4;
thus x in M by A2, A3, A4, A5, A6, Def2; :: thesis: verum

end;

hence (r * M) + ((1 - r) * M) c= M by SUBSET_1:7; :: thesis: verum

end;

( ( for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M ) implies M is convex )

proof

assume A7: for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M ; :: thesis: M is convex
let u, v be VECTOR of V; :: according to CONVEX1:def 2 :: thesis: for r being Real st 0 < r & r < 1 & u in M & v in M holds
(r * u) + ((1 - r) * v) in M
let r be Real; :: thesis: ( 0 < r & r < 1 & u in M & v in M implies (r * u) + ((1 - r) * v) in M )
assume A8: ( 0 < r & r < 1 ) ; :: thesis: ( not u in M or not v in M or (r * u) + ((1 - r) * v) in M )
assume A9: ( u in M & v in M ) ; :: thesis: (r * u) + ((1 - r) * v) in M
then A10: r * u in r * M ;
(1 - r) * v in { ((1 - r) * w) where w is Element of V : w in M } by A9;
then (r * u) + ((1 - r) * v) in { (p + q) where p, q is Element of V : ( p in r * M & q in (1 - r) * M ) } by A10;
then A11: (r * u) + ((1 - r) * v) in (r * M) + ((1 - r) * M) by RUSUB_4:def 10;
(r * M) + ((1 - r) * M) c= M by A7, A8;
hence (r * u) + ((1 - r) * v) in M by A11; :: thesis: verum

end;

hence ( M is convex iff for r being Real st 0 < r & r < 1 holds
(r * M) + ((1 - r) * M) c= M ) by A1; :: thesis: verum