let X, Y be ComplexNormSpace; :: thesis: for f, g, h being Point of (C_NormSpace_of_BoundedLinearOperators X,Y) holds
( h = f - g iff for x being VECTOR of X holds h . x = (f . x) - (g . x) )
let f, g, h be Point of (C_NormSpace_of_BoundedLinearOperators X,Y); :: thesis: ( h = f - g iff for x being VECTOR of X holds h . x = (f . x) - (g . x) )
reconsider f' = f, g' = g, h' = h as bounded LinearOperator of X,Y by Def8;

hereby :: thesis: ( ( for x being VECTOR of X holds h . x = (f . x) - (g . x) ) implies h = f - g )

assume h = f - g ; :: thesis: for x being VECTOR of X holds h . x = (f . x) - (g . x)
then h + g = f - (g - g) by RLVECT_1:43;
then h + g = f - (0. (C_NormSpace_of_BoundedLinearOperators X,Y)) by RLVECT_1:28;
then A1: h + g = f by RLVECT_1:26;

now

let x be VECTOR of X; :: thesis: (f' . x) - (g' . x) = h' . x
f' . x = (h' . x) + (g' . x) by A1, Th39;
then (f' . x) - (g' . x) = (h' . x) + ((g' . x) - (g' . x)) by RLVECT_1:def 6;
then (f' . x) - (g' . x) = (h' . x) + (0. Y) by RLVECT_1:28;
hence (f' . x) - (g' . x) = h' . x by RLVECT_1:10; :: thesis: verum

end;

hence for x being VECTOR of X holds h . x = (f . x) - (g . x) ; :: thesis: verum

end;

assume A2: for x being VECTOR of X holds h . x = (f . x) - (g . x) ; :: thesis: h = f - g

now

let x be VECTOR of X; :: thesis: (h' . x) + (g' . x) = f' . x
h' . x = (f' . x) - (g' . x) by A2;
then (h' . x) + (g' . x) = (f' . x) - ((g' . x) - (g' . x)) by RLVECT_1:43;
then (h' . x) + (g' . x) = (f' . x) - (0. Y) by RLVECT_1:28;
hence (h' . x) + (g' . x) = f' . x by RLVECT_1:26; :: thesis: verum

end;

then f = h + g by Th39;
then f - g = h + (g - g) by RLVECT_1:def 6;
then f - g = h + (0. (C_NormSpace_of_BoundedLinearOperators X,Y)) by RLVECT_1:28;
hence h = f - g by RLVECT_1:10; :: thesis: verum