let X, Y be ComplexNormSpace; :: thesis: BoundedLinearOperators X,Y is linearly-closed
set W = BoundedLinearOperators X,Y;
A1: for v, u being VECTOR of (C_VectorSpace_of_LinearOperators X,Y) st v in BoundedLinearOperators X,Y & u in BoundedLinearOperators X,Y holds
v + u in BoundedLinearOperators X,Y

proof

let v, u be VECTOR of (C_VectorSpace_of_LinearOperators X,Y); :: thesis: ( v in BoundedLinearOperators X,Y & u in BoundedLinearOperators X,Y implies v + u in BoundedLinearOperators X,Y )
assume A2: ( v in BoundedLinearOperators X,Y & u in BoundedLinearOperators X,Y ) ; :: thesis: v + u in BoundedLinearOperators X,Y
reconsider f = v + u as LinearOperator of X,Y by Def5;
f is bounded

proof

reconsider u1 = u as bounded LinearOperator of X,Y by A2, Def8;
reconsider v1 = v as bounded LinearOperator of X,Y by A2, Def8;
consider K1 being Real such that
A3: ( 0 <= K1 & ( for x being VECTOR of X holds ||.(u1 . x).|| <= K1 * ||.x.|| ) ) by Def7;
consider K2 being Real such that
A4: ( 0 <= K2 & ( for x being VECTOR of X holds ||.(v1 . x).|| <= K2 * ||.x.|| ) ) by Def7;
take K3 = K1 + K2; :: according to CLOPBAN1:def 7 :: thesis: ( 0 <= K3 & ( for x being VECTOR of X holds ||.(f . x).|| <= K3 * ||.x.|| ) )
A5: 0 + 0 <= K1 + K2 by A3, A4;

now

let x be VECTOR of X; :: thesis: ||.(f . x).|| <= K3 * ||.x.||
A6: ||.(f . x).|| = ||.((u1 . x) + (v1 . x)).|| by Th18;
A7: ||.((u1 . x) + (v1 . x)).|| <= ||.(u1 . x).|| + ||.(v1 . x).|| by CLVECT_1:def 11;
A8: ||.(u1 . x).|| <= K1 * ||.x.|| by A3;
||.(v1 . x).|| <= K2 * ||.x.|| by A4;
then ||.(u1 . x).|| + ||.(v1 . x).|| <= (K1 * ||.x.||) + (K2 * ||.x.||) by A8, XREAL_1:9;
hence ||.(f . x).|| <= K3 * ||.x.|| by A6, A7, XXREAL_0:2; :: thesis: verum

end;

hence ( 0 <= K3 & ( for x being VECTOR of X holds ||.(f . x).|| <= K3 * ||.x.|| ) ) by A5; :: thesis: verum

end;

hence v + u in BoundedLinearOperators X,Y by Def8; :: thesis: verum

end;

for c being Complex
for v being VECTOR of (C_VectorSpace_of_LinearOperators X,Y) st v in BoundedLinearOperators X,Y holds
c * v in BoundedLinearOperators X,Y

proof

let c be Complex; :: thesis: for v being VECTOR of (C_VectorSpace_of_LinearOperators X,Y) st v in BoundedLinearOperators X,Y holds
c * v in BoundedLinearOperators X,Y
let v be VECTOR of (C_VectorSpace_of_LinearOperators X,Y); :: thesis: ( v in BoundedLinearOperators X,Y implies c * v in BoundedLinearOperators X,Y )
assume A9: v in BoundedLinearOperators X,Y ; :: thesis: c * v in BoundedLinearOperators X,Y
reconsider f = c * v as LinearOperator of X,Y by Def5;
f is bounded

proof

reconsider v1 = v as bounded LinearOperator of X,Y by A9, Def8;
consider K being Real such that
A10: ( 0 <= K & ( for x being VECTOR of X holds ||.(v1 . x).|| <= K * ||.x.|| ) ) by Def7;
take K1 = |.c.| * K; :: according to CLOPBAN1:def 7 :: thesis: ( 0 <= K1 & ( for x being VECTOR of X holds ||.(f . x).|| <= K1 * ||.x.|| ) )
A11: ( 0 <= K & 0 <= |.c.| ) by A10, COMPLEX1:132;

now

let x be VECTOR of X; :: thesis: ||.(f . x).|| <= (|.c.| * K) * ||.x.||
A12: ||.(c * (v1 . x)).|| = |.c.| * ||.(v1 . x).|| by CLVECT_1:def 11;
0 <= |.c.| by COMPLEX1:132;
then |.c.| * ||.(v1 . x).|| <= |.c.| * (K * ||.x.||) by A10, XREAL_1:66;
hence ||.(f . x).|| <= (|.c.| * K) * ||.x.|| by A12, Th19; :: thesis: verum

end;

hence ( 0 <= K1 & ( for x being VECTOR of X holds ||.(f . x).|| <= K1 * ||.x.|| ) ) by A11; :: thesis: verum

end;

hence c * v in BoundedLinearOperators X,Y by Def8; :: thesis: verum

end;

hence BoundedLinearOperators X,Y is linearly-closed by A1, CLVECT_1:def 4; :: thesis: verum