let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G)
let G be Subset of (PARTITIONS Y); :: thesis: for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G)
let u, a be Element of Funcs Y,BOOLEAN ; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G)
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G) )
assume u is_independent_of PA,G ; :: thesis: Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G)
then A1: u is_dependent_of CompF PA,G by Def8;
A2: Ex (u 'or' a),PA,G '<' u 'or' (Ex a,PA,G)

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (Ex (u 'or' a),PA,G) . z = TRUE or (u 'or' (Ex a,PA,G)) . z = TRUE )
assume (Ex (u 'or' a),PA,G) . z = TRUE ; :: thesis: (u 'or' (Ex a,PA,G)) . z = TRUE
then consider x1 being Element of Y such that
A3: ( x1 in EqClass z,(CompF PA,G) & (u 'or' a) . x1 = TRUE ) by BVFUNC_1:def 20;
A4: (u . x1) 'or' (a . x1) = TRUE by A3, BVFUNC_1:def 7;
A5: ( u . x1 = TRUE or u . x1 = FALSE ) by XBOOLEAN:def 3;
A6: ( z in EqClass z,(CompF PA,G) & EqClass z,(CompF PA,G) in CompF PA,G ) by EQREL_1:def 8;
A7: (u 'or' (Ex a,PA,G)) . z = (u . z) 'or' ((Ex a,PA,G) . z) by BVFUNC_1:def 7;

now

per cases ( u . x1 = TRUE or a . x1 = TRUE ) by A4, A5, BINARITH:7;

case A8: u . x1 = TRUE ; :: thesis: (u 'or' (Ex a,PA,G)) . z = TRUE

u . z = u . x1 by A1, A3, A6, BVFUNC_1:def 18;
hence (u 'or' (Ex a,PA,G)) . z = TRUE by A7, A8, BINARITH:19; :: thesis: verum

end;

case a . x1 = TRUE ; :: thesis: (u 'or' (Ex a,PA,G)) . z = TRUE

then (u 'or' (Ex a,PA,G)) . z = (u . z) 'or' TRUE by A3, A7, BVFUNC_1:def 20
.= TRUE by BINARITH:19 ;
hence (u 'or' (Ex a,PA,G)) . z = TRUE ; :: thesis: verum

end;

end;

end;

hence (u 'or' (Ex a,PA,G)) . z = TRUE ; :: thesis: verum

end;

u 'or' (Ex a,PA,G) '<' Ex (u 'or' a),PA,G

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (u 'or' (Ex a,PA,G)) . z = TRUE or (Ex (u 'or' a),PA,G) . z = TRUE )
assume (u 'or' (Ex a,PA,G)) . z = TRUE ; :: thesis: (Ex (u 'or' a),PA,G) . z = TRUE
then A9: (u . z) 'or' ((Ex a,PA,G) . z) = TRUE by BVFUNC_1:def 7;
A10: ( (Ex a,PA,G) . z = TRUE or (Ex a,PA,G) . z = FALSE ) by XBOOLEAN:def 3;
A11: ( z in EqClass z,(CompF PA,G) & EqClass z,(CompF PA,G) in CompF PA,G ) by EQREL_1:def 8;

now

per cases ( u . z = TRUE or (Ex a,PA,G) . z = TRUE ) by A9, A10, BINARITH:7;

case u . z = TRUE ; :: thesis: (Ex (u 'or' a),PA,G) . z = TRUE

then (u 'or' a) . z = TRUE 'or' (a . z) by BVFUNC_1:def 7
.= TRUE by BINARITH:19 ;
hence (Ex (u 'or' a),PA,G) . z = TRUE by A11, BVFUNC_1:def 20; :: thesis: verum

end;

case (Ex a,PA,G) . z = TRUE ; :: thesis: (Ex (u 'or' a),PA,G) . z = TRUE

then consider x1 being Element of Y such that
A12: ( x1 in EqClass z,(CompF PA,G) & a . x1 = TRUE ) by BVFUNC_1:def 20;
(u 'or' a) . x1 = (u . x1) 'or' (a . x1) by BVFUNC_1:def 7
.= TRUE by A12, BINARITH:19 ;
hence (Ex (u 'or' a),PA,G) . z = TRUE by A12, BVFUNC_1:def 20; :: thesis: verum

end;

end;

end;

hence (Ex (u 'or' a),PA,G) . z = TRUE ; :: thesis: verum

end;

hence Ex (u 'or' a),PA,G = u 'or' (Ex a,PA,G) by A2, BVFUNC_1:18; :: thesis: verum