let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u
let G be Subset of (PARTITIONS Y); :: thesis: for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u
let u, a be Element of Funcs Y,BOOLEAN ; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u )
assume u is_independent_of PA,G ; :: thesis: All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u
then A1: u is_dependent_of CompF PA,G by Def8;
A2: All (a 'imp' u),PA,G '<' (Ex a,PA,G) 'imp' u

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (All (a 'imp' u),PA,G) . z = TRUE or ((Ex a,PA,G) 'imp' u) . z = TRUE )
assume A3: (All (a 'imp' u),PA,G) . z = TRUE ; :: thesis: ((Ex a,PA,G) 'imp' u) . z = TRUE
A4: z in EqClass z,(CompF PA,G) by EQREL_1:def 8;
A5: ((Ex a,PA,G) 'imp' u) . z = ('not' ((Ex a,PA,G) . z)) 'or' (u . z) by BVFUNC_1:def 11;

per cases ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
u . x = TRUE or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & a . x = TRUE ) ) or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) & ( for x being Element of Y holds
( not x in EqClass z,(CompF PA,G) or not a . x = TRUE ) ) ) ) ;

suppose for x being Element of Y st x in EqClass z,(CompF PA,G) holds
u . x = TRUE ; :: thesis: ((Ex a,PA,G) 'imp' u) . z = TRUE

then ((Ex a,PA,G) 'imp' u) . z = ('not' ((Ex a,PA,G) . z)) 'or' TRUE by A4, A5
.= TRUE by BINARITH:19 ;
hence ((Ex a,PA,G) 'imp' u) . z = TRUE ; :: thesis: verum

end;

suppose A6: ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & a . x = TRUE ) ) ; :: thesis: ((Ex a,PA,G) 'imp' u) . z = TRUE

then consider x1 being Element of Y such that
A7: ( x1 in EqClass z,(CompF PA,G) & u . x1 <> TRUE ) ;
consider x2 being Element of Y such that
A8: ( x2 in EqClass z,(CompF PA,G) & a . x2 = TRUE ) by A6;
A9: u . x1 = u . x2 by A1, A7, A8, BVFUNC_1:def 18;
(a 'imp' u) . x2 = ('not' (a . x2)) 'or' (u . x2) by BVFUNC_1:def 11
.= ('not' TRUE ) 'or' FALSE by A7, A8, A9, XBOOLEAN:def 3
.= FALSE 'or' FALSE by MARGREL1:41
.= FALSE ;
hence ((Ex a,PA,G) 'imp' u) . z = TRUE by A3, A8, BVFUNC_1:def 19; :: thesis: verum

end;

suppose ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) & ( for x being Element of Y holds
( not x in EqClass z,(CompF PA,G) or not a . x = TRUE ) ) ) ; :: thesis: ((Ex a,PA,G) 'imp' u) . z = TRUE

then ((Ex a,PA,G) 'imp' u) . z = ('not' FALSE ) 'or' (u . z) by A5, BVFUNC_1:def 20
.= TRUE 'or' (u . z) by MARGREL1:41
.= TRUE by BINARITH:19 ;
hence ((Ex a,PA,G) 'imp' u) . z = TRUE ; :: thesis: verum

end;

end;

end;

(Ex a,PA,G) 'imp' u '<' All (a 'imp' u),PA,G

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not ((Ex a,PA,G) 'imp' u) . z = TRUE or (All (a 'imp' u),PA,G) . z = TRUE )
assume ((Ex a,PA,G) 'imp' u) . z = TRUE ; :: thesis: (All (a 'imp' u),PA,G) . z = TRUE
then A10: ('not' ((Ex a,PA,G) . z)) 'or' (u . z) = TRUE by BVFUNC_1:def 11;
A11: ( 'not' ((Ex a,PA,G) . z) = TRUE or 'not' ((Ex a,PA,G) . z) = FALSE ) by XBOOLEAN:def 3;
A12: ( z in EqClass z,(CompF PA,G) & EqClass z,(CompF PA,G) in CompF PA,G ) by EQREL_1:def 8;

now

per cases ( u . z = TRUE or ( 'not' ((Ex a,PA,G) . z) = TRUE & u . z = FALSE ) ) by A10, A11, BINARITH:7, XBOOLEAN:def 3;

case A13: u . z = TRUE ; :: thesis: (All (a 'imp' u),PA,G) . z = TRUE

for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(a 'imp' u) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (a 'imp' u) . x = TRUE )
assume A14: x in EqClass z,(CompF PA,G) ; :: thesis: (a 'imp' u) . x = TRUE
A15: (a 'imp' u) . x = ('not' (a . x)) 'or' (u . x) by BVFUNC_1:def 11;
u . x = u . z by A1, A12, A14, BVFUNC_1:def 18;
hence (a 'imp' u) . x = TRUE by A13, A15, BINARITH:19; :: thesis: verum

end;

hence (All (a 'imp' u),PA,G) . z = TRUE by BVFUNC_1:def 19; :: thesis: verum

end;

case ( 'not' ((Ex a,PA,G) . z) = TRUE & u . z = FALSE ) ; :: thesis: (All (a 'imp' u),PA,G) . z = TRUE

then A16: (Ex a,PA,G) . z = FALSE by MARGREL1:41;
for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(a 'imp' u) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (a 'imp' u) . x = TRUE )
assume A17: x in EqClass z,(CompF PA,G) ; :: thesis: (a 'imp' u) . x = TRUE
A18: (a 'imp' u) . x = ('not' (a . x)) 'or' (u . x) by BVFUNC_1:def 11;
a . x <> TRUE by A16, A17, BVFUNC_1:def 20;
then a . x = FALSE by XBOOLEAN:def 3;
then (a 'imp' u) . x = TRUE 'or' (u . x) by A18, MARGREL1:41
.= TRUE by BINARITH:19 ;
hence (a 'imp' u) . x = TRUE ; :: thesis: verum

end;

hence (All (a 'imp' u),PA,G) . z = TRUE by BVFUNC_1:def 19; :: thesis: verum

end;

end;

end;

hence (All (a 'imp' u),PA,G) . z = TRUE ; :: thesis: verum

end;

hence All (a 'imp' u),PA,G = (Ex a,PA,G) 'imp' u by A2, BVFUNC_1:18; :: thesis: verum