let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'imp' a),PA,G = u 'imp' (All a,PA,G)
let G be Subset of (PARTITIONS Y); :: thesis: for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'imp' a),PA,G = u 'imp' (All a,PA,G)
let u, a be Element of Funcs Y,BOOLEAN ; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'imp' a),PA,G = u 'imp' (All a,PA,G)
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies All (u 'imp' a),PA,G = u 'imp' (All a,PA,G) )
assume u is_independent_of PA,G ; :: thesis: All (u 'imp' a),PA,G = u 'imp' (All a,PA,G)
then A1: u is_dependent_of CompF PA,G by Def8;
A2: All (u 'imp' a),PA,G '<' u 'imp' (All a,PA,G)

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (All (u 'imp' a),PA,G) . z = TRUE or (u 'imp' (All a,PA,G)) . z = TRUE )
assume A3: (All (u 'imp' a),PA,G) . z = TRUE ; :: thesis: (u 'imp' (All a,PA,G)) . z = TRUE
A4: z in EqClass z,(CompF PA,G) by EQREL_1:def 8;
A5: (u 'imp' (All a,PA,G)) . z = ('not' (u . z)) 'or' ((All a,PA,G) . z) by BVFUNC_1:def 11;

per cases ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
a . x = TRUE or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
'not' (u . x) = TRUE ) ) or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not 'not' (u . x) = TRUE ) ) ) ;

suppose for x being Element of Y st x in EqClass z,(CompF PA,G) holds
a . x = TRUE ; :: thesis: (u 'imp' (All a,PA,G)) . z = TRUE

then (All a,PA,G) . z = TRUE by BVFUNC_1:def 19;
hence (u 'imp' (All a,PA,G)) . z = TRUE by A5, BINARITH:19; :: thesis: verum

end;

suppose ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
'not' (u . x) = TRUE ) ) ; :: thesis: (u 'imp' (All a,PA,G)) . z = TRUE

then 'not' (u . z) = TRUE by A4;
hence (u 'imp' (All a,PA,G)) . z = TRUE by A5, BINARITH:19; :: thesis: verum

end;

suppose A6: ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not 'not' (u . x) = TRUE ) ) ; :: thesis: (u 'imp' (All a,PA,G)) . z = TRUE

then consider x1 being Element of Y such that
A7: ( x1 in EqClass z,(CompF PA,G) & 'not' (u . x1) <> TRUE ) ;
consider x2 being Element of Y such that
A8: ( x2 in EqClass z,(CompF PA,G) & a . x2 <> TRUE ) by A6;
u . x1 = u . x2 by A1, A7, A8, BVFUNC_1:def 18;
then 'not' (u . x2) = FALSE by A7, XBOOLEAN:def 3;
then A9: u . x2 = TRUE by MARGREL1:41;
a . x2 = FALSE by A8, XBOOLEAN:def 3;
then (u 'imp' a) . x2 = ('not' TRUE ) 'or' FALSE by A9, BVFUNC_1:def 11;
then (u 'imp' a) . x2 = FALSE 'or' FALSE by MARGREL1:41
.= FALSE ;
hence (u 'imp' (All a,PA,G)) . z = TRUE by A3, A8, BVFUNC_1:def 19; :: thesis: verum

end;

end;

end;

u 'imp' (All a,PA,G) '<' All (u 'imp' a),PA,G

proof

let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (u 'imp' (All a,PA,G)) . z = TRUE or (All (u 'imp' a),PA,G) . z = TRUE )
assume (u 'imp' (All a,PA,G)) . z = TRUE ; :: thesis: (All (u 'imp' a),PA,G) . z = TRUE
then A10: ('not' (u . z)) 'or' ((All a,PA,G) . z) = TRUE by BVFUNC_1:def 11;
A11: ( (All a,PA,G) . z = TRUE or (All a,PA,G) . z = FALSE ) by XBOOLEAN:def 3;

now

per cases ( (All a,PA,G) . z = TRUE or ( (All a,PA,G) . z <> TRUE & 'not' (u . z) = TRUE ) ) by A10, A11, BINARITH:7;

suppose A12: (All a,PA,G) . z = TRUE ; :: thesis: (All (u 'imp' a),PA,G) . z = TRUE

for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(u 'imp' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (u 'imp' a) . x = TRUE )
assume A13: x in EqClass z,(CompF PA,G) ; :: thesis: (u 'imp' a) . x = TRUE
(u 'imp' a) . x = ('not' (u . x)) 'or' (a . x) by BVFUNC_1:def 11
.= ('not' (u . x)) 'or' TRUE by A12, A13, BVFUNC_1:def 19
.= TRUE by BINARITH:19 ;
hence (u 'imp' a) . x = TRUE ; :: thesis: verum

end;

hence (All (u 'imp' a),PA,G) . z = TRUE by BVFUNC_1:def 19; :: thesis: verum

end;

suppose A14: ( (All a,PA,G) . z <> TRUE & 'not' (u . z) = TRUE ) ; :: thesis: (All (u 'imp' a),PA,G) . z = TRUE

A15: ( z in EqClass z,(CompF PA,G) & EqClass z,(CompF PA,G) in CompF PA,G ) by EQREL_1:def 8;
for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(u 'imp' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (u 'imp' a) . x = TRUE )
assume A16: x in EqClass z,(CompF PA,G) ; :: thesis: (u 'imp' a) . x = TRUE
A17: (u 'imp' a) . x = ('not' (u . x)) 'or' (a . x) by BVFUNC_1:def 11;
u . x = u . z by A1, A15, A16, BVFUNC_1:def 18;
hence (u 'imp' a) . x = TRUE by A14, A17, BINARITH:19; :: thesis: verum

end;

hence (All (u 'imp' a),PA,G) . z = TRUE by BVFUNC_1:def 19; :: thesis: verum

end;

end;

end;

hence (All (u 'imp' a),PA,G) . z = TRUE ; :: thesis: verum

end;

hence All (u 'imp' a),PA,G = u 'imp' (All a,PA,G) by A2, BVFUNC_1:18; :: thesis: verum