let y1, y2 be Point of X; :: thesis: ( ( for e being Real st e > 0 holds
ex Y0 being finite Subset of X st
( not Y0 is empty & Y0 c= Y & ( for Y1 being finite Subset of X st Y0 c= Y1 & Y1 c= Y holds
||.(y1 - (setsum Y1)).|| < e ) ) ) & ( for e being Real st e > 0 holds
ex Y0 being finite Subset of X st
( not Y0 is empty & Y0 c= Y & ( for Y1 being finite Subset of X st Y0 c= Y1 & Y1 c= Y holds
||.(y2 - (setsum Y1)).|| < e ) ) ) implies y1 = y2 )
assume that
A2: for e1 being Real st e1 > 0 holds
ex Y0 being finite Subset of X st
( not Y0 is empty & Y0 c= Y & ( for Y1 being finite Subset of X st Y0 c= Y1 & Y1 c= Y holds
||.(y1 - (setsum Y1)).|| < e1 ) ) and
A3: for e2 being Real st e2 > 0 holds
ex Y0 being finite Subset of X st
( not Y0 is empty & Y0 c= Y & ( for Y1 being finite Subset of X st Y0 c= Y1 & Y1 c= Y holds
||.(y2 - (setsum Y1)).|| < e2 ) ) ; :: thesis: y1 = y2

A4: now

let e3 be Real; :: thesis: ( e3 > 0 implies ||.(y1 - y2).|| < e3 )
assume A5: e3 > 0 ; :: thesis: ||.(y1 - y2).|| < e3
set e4 = e3 / 2;
A6: ( e3 / 2 is Real & e3 / 2 > 0 ) by A5, XREAL_1:141;
A7: (e3 / 2) + (e3 / 2) = e3 ;
consider Y01 being finite Subset of X such that
A8: ( not Y01 is empty & Y01 c= Y & ( for Y1 being finite Subset of X st Y01 c= Y1 & Y1 c= Y holds
||.(y1 - (setsum Y1)).|| < e3 / 2 ) ) by A2, A6;
consider Y02 being finite Subset of X such that
A9: ( not Y02 is empty & Y02 c= Y & ( for Y1 being finite Subset of X st Y02 c= Y1 & Y1 c= Y holds
||.(y2 - (setsum Y1)).|| < e3 / 2 ) ) by A3, A6;
set Y00 = Y01 \/ Y02;
A10: Y01 \/ Y02 c= Y by A8, A9, XBOOLE_1:8;
A11: ( Y01 \/ Y02 is finite Subset of X & Y01 c= Y01 \/ Y02 ) by XBOOLE_1:7;
||.(y2 - (setsum (Y01 \/ Y02))).|| < e3 / 2 by A9, A10, XBOOLE_1:7;
then ||.(- (y2 - (setsum (Y01 \/ Y02)))).|| < e3 / 2 by BHSP_1:37;
then ||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).|| < e3 by A7, A8, A10, A11, XREAL_1:10;
then ||.((y1 - (setsum (Y01 \/ Y02))) + (- (y2 - (setsum (Y01 \/ Y02))))).|| + (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||) < (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||) + e3 by BHSP_1:36, XREAL_1:10;
then A12: (||.((y1 - (setsum (Y01 \/ Y02))) + (- (y2 - (setsum (Y01 \/ Y02))))).|| + (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||)) + (- (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||)) < (e3 + (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||)) + (- (||.(y1 - (setsum (Y01 \/ Y02))).|| + ||.(- (y2 - (setsum (Y01 \/ Y02)))).||)) by XREAL_1:10;
||.(y1 - y2).|| = ||.((y1 - y2) + (0. X)).|| by RLVECT_1:def 7
.= ||.((y1 - y2) + ((setsum (Y01 \/ Y02)) - (setsum (Y01 \/ Y02)))).|| by RLVECT_1:16
.= ||.(((y1 - y2) + (setsum (Y01 \/ Y02))) - (setsum (Y01 \/ Y02))).|| by RLVECT_1:def 6
.= ||.((y1 - (y2 - (setsum (Y01 \/ Y02)))) - (setsum (Y01 \/ Y02))).|| by RLVECT_1:43
.= ||.(y1 - ((setsum (Y01 \/ Y02)) + (y2 - (setsum (Y01 \/ Y02))))).|| by RLVECT_1:41
.= ||.((y1 - (setsum (Y01 \/ Y02))) - (y2 - (setsum (Y01 \/ Y02)))).|| by RLVECT_1:41
.= ||.((y1 - (setsum (Y01 \/ Y02))) + (- (y2 - (setsum (Y01 \/ Y02))))).|| ;
hence ||.(y1 - y2).|| < e3 by A12; :: thesis: verum

end;

y1 = y2

proof

assume y1 <> y2 ; :: thesis: contradiction
then y1 - y2 <> 0. X by VECTSP_1:66;
then A13: ||.(y1 - y2).|| <> 0 by BHSP_1:32;
0 <= ||.(y1 - y2).|| by BHSP_1:34;
hence contradiction by A4, A13; :: thesis: verum

end;

hence y1 = y2 ; :: thesis: verum