let X be RealUnitarySpace; :: thesis: for a being Real
for seq being sequence of X st seq is Cauchy holds
a * seq is Cauchy
let a be Real; :: thesis: for seq being sequence of X st seq is Cauchy holds
a * seq is Cauchy
let seq be sequence of X; :: thesis: ( seq is Cauchy implies a * seq is Cauchy )
assume A1: seq is Cauchy ; :: thesis: a * seq is Cauchy

A2: now

assume A3: a = 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
then consider m1 being Element of NAT such that
A4: for n, m being Element of NAT st n >= m1 & m >= m1 holds
dist (seq . n),(seq . m) < r by A1, Def1;
take k = m1; :: thesis: for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
let n, m be Element of NAT ; :: thesis: ( n >= k & m >= k implies dist ((a * seq) . n),((a * seq) . m) < r )
assume ( n >= k & m >= k ) ; :: thesis: dist ((a * seq) . n),((a * seq) . m) < r
then A5: dist (seq . n),(seq . m) < r by A4;
dist (a * (seq . n)),(a * (seq . m)) = dist H₁(X),(0 * (seq . m)) by A3, RLVECT_1:23
.= dist H₁(X),H₁(X) by RLVECT_1:23
.= 0 by BHSP_1:41 ;
then dist (a * (seq . n)),(a * (seq . m)) < r by A5, BHSP_1:44;
then dist ((a * seq) . n),(a * (seq . m)) < r by NORMSP_1:def 8;
hence dist ((a * seq) . n),((a * seq) . m) < r by NORMSP_1:def 8; :: thesis: verum

end;

now

assume A6: a <> 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
then A7: abs a > 0 by COMPLEX1:133;
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r )
assume A8: r > 0 ; :: thesis: ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
A9: abs a <> 0 by A6, COMPLEX1:133;
0 / (abs a) = 0 ;
then r / (abs a) > 0 by A7, A8, XREAL_1:76;
then consider m1 being Element of NAT such that
A10: for n, m being Element of NAT st n >= m1 & m >= m1 holds
dist (seq . n),(seq . m) < r / (abs a) by A1, Def1;
take k = m1; :: thesis: for n, m being Element of NAT st n >= k & m >= k holds
dist ((a * seq) . n),((a * seq) . m) < r
let n, m be Element of NAT ; :: thesis: ( n >= k & m >= k implies dist ((a * seq) . n),((a * seq) . m) < r )
assume ( n >= k & m >= k ) ; :: thesis: dist ((a * seq) . n),((a * seq) . m) < r
then A11: dist (seq . n),(seq . m) < r / (abs a) by A10;
A12: dist (a * (seq . n)),(a * (seq . m)) = ||.((a * (seq . n)) - (a * (seq . m))).|| by BHSP_1:def 5
.= ||.(a * ((seq . n) - (seq . m))).|| by RLVECT_1:48
.= (abs a) * ||.((seq . n) - (seq . m)).|| by BHSP_1:33
.= (abs a) * (dist (seq . n),(seq . m)) by BHSP_1:def 5 ;
(abs a) * (r / (abs a)) = (abs a) * (((abs a) " ) * r) by XCMPLX_0:def 9
.= ((abs a) * ((abs a) " )) * r
.= 1 * r by A9, XCMPLX_0:def 7
.= r ;
then dist (a * (seq . n)),(a * (seq . m)) < r by A7, A11, A12, XREAL_1:70;
then dist ((a * seq) . n),(a * (seq . m)) < r by NORMSP_1:def 8;
hence dist ((a * seq) . n),((a * seq) . m) < r by NORMSP_1:def 8; :: thesis: verum

end;

hence a * seq is Cauchy by A2, Def1; :: thesis: verum