let X be RealUnitarySpace; :: thesis: for g being Point of X
for seq1, seq2 being sequence of X st seq1 is convergent & lim seq1 = g & seq1 is_compared_to seq2 holds
( seq2 is convergent & lim seq2 = g )
let g be Point of X; :: thesis: for seq1, seq2 being sequence of X st seq1 is convergent & lim seq1 = g & seq1 is_compared_to seq2 holds
( seq2 is convergent & lim seq2 = g )
let seq1, seq2 be sequence of X; :: thesis: ( seq1 is convergent & lim seq1 = g & seq1 is_compared_to seq2 implies ( seq2 is convergent & lim seq2 = g ) )
assume that
A1: seq1 is convergent and
A2: lim seq1 = g and
A3: seq1 is_compared_to seq2 ; :: thesis: ( seq2 is convergent & lim seq2 = g )

A4: now

let r be Real; :: thesis: ( r > 0 implies ex m being Element of NAT st
for n being Element of NAT st n >= m holds
dist (seq2 . n),g < r )
assume r > 0 ; :: thesis: ex m being Element of NAT st
for n being Element of NAT st n >= m holds
dist (seq2 . n),g < r
then A5: r / 2 > 0 by XREAL_1:217;
then consider m1 being Element of NAT such that
A6: for n being Element of NAT st n >= m1 holds
dist (seq1 . n),g < r / 2 by A1, A2, BHSP_2:def 2;
consider m2 being Element of NAT such that
A7: for n being Element of NAT st n >= m2 holds
dist (seq1 . n),(seq2 . n) < r / 2 by A3, A5, Def2;
take m = m1 + m2; :: thesis: for n being Element of NAT st n >= m holds
dist (seq2 . n),g < r
let n be Element of NAT ; :: thesis: ( n >= m implies dist (seq2 . n),g < r )
assume A8: n >= m ; :: thesis: dist (seq2 . n),g < r
m1 + m2 >= m1 by NAT_1:12;
then n >= m1 by A8, XXREAL_0:2;
then A9: dist (seq1 . n),g < r / 2 by A6;
m >= m2 by NAT_1:12;
then n >= m2 by A8, XXREAL_0:2;
then dist (seq1 . n),(seq2 . n) < r / 2 by A7;
then A10: (dist (seq2 . n),(seq1 . n)) + (dist (seq1 . n),g) < (r / 2) + (r / 2) by A9, XREAL_1:10;
dist (seq2 . n),g <= (dist (seq2 . n),(seq1 . n)) + (dist (seq1 . n),g) by BHSP_1:42;
hence dist (seq2 . n),g < r by A10, XXREAL_0:2; :: thesis: verum

end;

then seq2 is convergent by BHSP_2:def 1;
hence ( seq2 is convergent & lim seq2 = g ) by A4, BHSP_2:def 2; :: thesis: verum