let X be Banach_Algebra; :: thesis: for z, w being Element of X st z,w are_commutative holds
(Sum (z rExpSeq )) * (Sum (w rExpSeq )) = Sum ((z + w) rExpSeq )
let z, w be Element of X; :: thesis: ( z,w are_commutative implies (Sum (z rExpSeq )) * (Sum (w rExpSeq )) = Sum ((z + w) rExpSeq ) )
assume A1: z,w are_commutative ; :: thesis: (Sum (z rExpSeq )) * (Sum (w rExpSeq )) = Sum ((z + w) rExpSeq )
deffunc H₁( Element of NAT ) -> Element of the carrier of X = (Partial_Sums (Conj $1,z,w)) . $1;
ex seq being sequence of X st
for k being Element of NAT holds seq . k = H₁(k) from FUNCT_2:sch 4();
then consider seq being sequence of X such that
A2: for k being Element of NAT holds seq . k = (Partial_Sums (Conj k,z,w)) . k ;

now

let k be Element of NAT ; :: thesis: seq . k = (((Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq ))) - (Partial_Sums ((z + w) rExpSeq ))) . k
thus seq . k = (Partial_Sums (Conj k,z,w)) . k by A2
.= (((Partial_Sums (z rExpSeq )) . k) * ((Partial_Sums (w rExpSeq )) . k)) - ((Partial_Sums ((z + w) rExpSeq )) . k) by A1, Th26
.= (((Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq ))) . k) - ((Partial_Sums ((z + w) rExpSeq )) . k) by LOPBAN_3:def 11
.= (((Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq ))) - (Partial_Sums ((z + w) rExpSeq ))) . k by NORMSP_1:def 6 ; :: thesis: verum

end;

then A3: seq = ((Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq ))) - (Partial_Sums ((z + w) rExpSeq )) by FUNCT_2:113;
A4: Partial_Sums (z rExpSeq ) is convergent by LOPBAN_3:def 2;
A5: Partial_Sums (w rExpSeq ) is convergent by LOPBAN_3:def 2;
A6: Partial_Sums ((z + w) rExpSeq ) is convergent by LOPBAN_3:def 2;
A7: ( (Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq )) is convergent & lim ((Partial_Sums (z rExpSeq )) * (Partial_Sums (w rExpSeq ))) = (lim (Partial_Sums (z rExpSeq ))) * (lim (Partial_Sums (w rExpSeq ))) ) by A4, A5, Th3, Th8;
( seq is convergent & lim seq = 0. X ) by A2, Th33;
hence Sum ((z + w) rExpSeq ) = (Sum (z rExpSeq )) * (Sum (w rExpSeq )) by A3, A6, A7, Th1; :: thesis: verum