let f be PartFunc of REAL , REAL ; :: thesis: ( f is convergent_in-infty & lim_in-infty f = 0 & ( for r being Real ex g being Real st
( g < r & g in dom f & f . g <> 0 ) ) & ex r being Real st
for g being Real st g in (dom f) /\ (left_open_halfline r) holds
f . g <= 0 implies f ^ is divergent_in-infty_to-infty )
assume A1: ( f is convergent_in-infty & lim_in-infty f = 0 & ( for r being Real ex g being Real st
( g < r & g in dom f & f . g <> 0 ) ) ) ; :: thesis: ( for r being Real ex g being Real st
( g in (dom f) /\ (left_open_halfline r) & not f . g <= 0 ) or f ^ is divergent_in-infty_to-infty )
given r being Real such that A2: for g being Real st g in (dom f) /\ (left_open_halfline r) holds
f . g <= 0 ; :: thesis: f ^ is divergent_in-infty_to-infty
thus for r1 being Real ex g1 being Real st
( g1 < r1 & g1 in dom (f ^ ) ) :: according to LIMFUNC1:def 11 :: thesis: for seq being Real_Sequence st seq is divergent_to-infty & rng seq c= dom (f ^ ) holds
(f ^ ) /* seq is divergent_to-infty

proof

let r1 be Real; :: thesis: ex g1 being Real st
( g1 < r1 & g1 in dom (f ^ ) )
consider g1 being Real such that
A3: ( g1 < r1 & g1 in dom f & f . g1 <> 0 ) by A1;
take g1 ; :: thesis: ( g1 < r1 & g1 in dom (f ^ ) )
thus g1 < r1 by A3; :: thesis: g1 in dom (f ^ )
not f . g1 in {0 } by A3, TARSKI:def 1;
then not g1 in f " {0 } by FUNCT_1:def 13;
then g1 in (dom f) \ (f " {0 }) by A3, XBOOLE_0:def 5;
hence g1 in dom (f ^ ) by RFUNCT_1:def 8; :: thesis: verum

end;

let s be Real_Sequence; :: thesis: ( s is divergent_to-infty & rng s c= dom (f ^ ) implies (f ^ ) /* s is divergent_to-infty )
assume A4: ( s is divergent_to-infty & rng s c= dom (f ^ ) ) ; :: thesis: (f ^ ) /* s is divergent_to-infty
then consider k being Element of NAT such that
A5: for n being Element of NAT st k <= n holds
s . n < r by Def5;
A6: s ^\ k is divergent_to-infty by A4, Th54;
dom (f ^ ) = (dom f) \ (f " {0 }) by RFUNCT_1:def 8;
then A7: dom (f ^ ) c= dom f by XBOOLE_1:36;
then A8: rng s c= dom f by A4, XBOOLE_1:1;
A9: rng (s ^\ k) c= rng s by VALUED_0:21;
then A10: ( rng (s ^\ k) c= dom (f ^ ) & rng (s ^\ k) c= dom f ) by A4, A8, XBOOLE_1:1;
then A11: ( f /* (s ^\ k) is convergent & lim (f /* (s ^\ k)) = 0 ) by A1, A6, Def13;
A12: f /* (s ^\ k) is non-zero by A4, A9, RFUNCT_2:26, XBOOLE_1:1;

A13: now

let n be Element of NAT ; :: thesis: (f /* (s ^\ k)) . n < 0
A14: (s ^\ k) . n in rng (s ^\ k) by VALUED_0:28;
s . (n + k) < r by A5, NAT_1:12;
then (s ^\ k) . n < r by NAT_1:def 3;
then (s ^\ k) . n in { g2 where g2 is Real : g2 < r } ;
then (s ^\ k) . n in left_open_halfline r by XXREAL_1:229;
then (s ^\ k) . n in (dom f) /\ (left_open_halfline r) by A10, A14, XBOOLE_0:def 4;
then A15: f . ((s ^\ k) . n) <= 0 by A2;
(f /* (s ^\ k)) . n <> 0 by A12, SEQ_1:7;
hence (f /* (s ^\ k)) . n < 0 by A8, A9, A15, FUNCT_2:185, XBOOLE_1:1; :: thesis: verum

end;

then for n being Element of NAT holds 0 <> (f /* (s ^\ k)) . n ;
then A16: f /* (s ^\ k) is non-zero by SEQ_1:7;
for n being Element of NAT st 0 <= n holds
(f /* (s ^\ k)) . n < 0 by A13;
then A17: (f /* (s ^\ k)) " is divergent_to-infty by A11, A16, Th63;
(f /* (s ^\ k)) " = ((f /* s) ^\ k) " by A4, A7, VALUED_0:27, XBOOLE_1:1
.= ((f /* s) " ) ^\ k by SEQM_3:41
.= ((f ^ ) /* s) ^\ k by A4, RFUNCT_2:27 ;
hence (f ^ ) /* s is divergent_to-infty by A17, Th34; :: thesis: verum