let sn be Real; :: thesis: for p2 being Point of (TOP-REAL 2) st - 1 < sn & sn < 1 holds
ex K being non empty compact Subset of (TOP-REAL 2) st
( K = (sn -FanMorphE ) .: K & ex V2 being Subset of (TOP-REAL 2) st
( p2 in V2 & V2 is open & V2 c= K & (sn -FanMorphE ) . p2 in V2 ) )
let p2 be Point of (TOP-REAL 2); :: thesis: ( - 1 < sn & sn < 1 implies ex K being non empty compact Subset of (TOP-REAL 2) st
( K = (sn -FanMorphE ) .: K & ex V2 being Subset of (TOP-REAL 2) st
( p2 in V2 & V2 is open & V2 c= K & (sn -FanMorphE ) . p2 in V2 ) ) )
assume A1: ( - 1 < sn & sn < 1 ) ; :: thesis: ex K being non empty compact Subset of (TOP-REAL 2) st
( K = (sn -FanMorphE ) .: K & ex V2 being Subset of (TOP-REAL 2) st
( p2 in V2 & V2 is open & V2 c= K & (sn -FanMorphE ) . p2 in V2 ) )
reconsider O = 0.REAL 2 as Point of (Euclid 2) ;
reconsider V0 = Ball O,(|.p2.| + 1) as Subset of (TOP-REAL 2) ;
A2: |.p2.| < |.p2.| + 1 by XREAL_1:31;
A3: O in V0 by GOBOARD6:4;
A4: V0 c= cl_Ball O,(|.p2.| + 1) by METRIC_1:15;
reconsider K0 = cl_Ball O,(|.p2.| + 1) as non empty compact Subset of (TOP-REAL 2) by A3, A4, Th22;
reconsider u2 = p2 as Point of (Euclid 2) ;
A5: (sn -FanMorphE ) .: K0 c= K0

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in (sn -FanMorphE ) .: K0 or y in K0 )
assume y in (sn -FanMorphE ) .: K0 ; :: thesis: y in K0
then consider x being set such that
A6: ( x in dom (sn -FanMorphE ) & x in K0 & y = (sn -FanMorphE ) . x ) by FUNCT_1:def 12;
reconsider q = x as Point of (TOP-REAL 2) by A6;
reconsider uq = q as Point of (Euclid 2) ;
A7: y in rng (sn -FanMorphE ) by A6, FUNCT_1:def 5;
then reconsider u = y as Point of (Euclid 2) ;
reconsider q4 = y as Point of (TOP-REAL 2) by A7;
A8: |.q4.| = |.q.| by A6, Th104;
dist O,uq <= |.p2.| + 1 by A6, METRIC_1:13;
then |.((0.REAL 2) - q).| <= |.p2.| + 1 by JGRAPH_1:45;
then |.((0.REAL 2) + (- q)).| <= |.p2.| + 1 by EUCLID:45;
then |.(- q).| <= |.p2.| + 1 by EUCLID:31;
then |.q.| <= |.p2.| + 1 by TOPRNS_1:27;
then |.(- q4).| <= |.p2.| + 1 by A8, TOPRNS_1:27;
then |.((0.REAL 2) + (- q4)).| <= |.p2.| + 1 by EUCLID:31;
then |.((0.REAL 2) - q4).| <= |.p2.| + 1 by EUCLID:45;
then dist O,u <= |.p2.| + 1 by JGRAPH_1:45;
hence y in K0 by METRIC_1:13; :: thesis: verum

end;

K0 c= (sn -FanMorphE ) .: K0

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in K0 or y in (sn -FanMorphE ) .: K0 )
assume A9: y in K0 ; :: thesis: y in (sn -FanMorphE ) .: K0
reconsider q4 = y as Point of (TOP-REAL 2) by A9;
the carrier of (TOP-REAL 2) c= rng (sn -FanMorphE ) by A1, Th110;
then q4 in rng (sn -FanMorphE ) by TARSKI:def 3;
then consider x being set such that
A10: ( x in dom (sn -FanMorphE ) & y = (sn -FanMorphE ) . x ) by FUNCT_1:def 5;
reconsider q = x as Point of (TOP-REAL 2) by A10;
|.q4.| = |.q.| by A10, Th104;
then q in K0 by A9, Lm11;
hence y in (sn -FanMorphE ) .: K0 by A10, FUNCT_1:def 12; :: thesis: verum

end;

then A11: K0 = (sn -FanMorphE ) .: K0 by A5, XBOOLE_0:def 10;
|.(- p2).| < |.p2.| + 1 by A2, TOPRNS_1:27;
then |.((0.REAL 2) + (- p2)).| < |.p2.| + 1 by EUCLID:31;
then |.((0.REAL 2) - p2).| < |.p2.| + 1 by EUCLID:45;
then dist O,u2 < |.p2.| + 1 by JGRAPH_1:45;
then A12: p2 in V0 by METRIC_1:12;
A13: V0 is open by TOPMETR:21;
set q3 = (sn -FanMorphE ) . p2;
reconsider u3 = (sn -FanMorphE ) . p2 as Point of (Euclid 2) ;
|.((sn -FanMorphE ) . p2).| = |.p2.| by Th104;
then |.(- ((sn -FanMorphE ) . p2)).| < |.p2.| + 1 by A2, TOPRNS_1:27;
then |.((0.REAL 2) + (- ((sn -FanMorphE ) . p2))).| < |.p2.| + 1 by EUCLID:31;
then |.((0.REAL 2) - ((sn -FanMorphE ) . p2)).| < |.p2.| + 1 by EUCLID:45;
then dist O,u3 < |.p2.| + 1 by JGRAPH_1:45;
then (sn -FanMorphE ) . p2 in V0 by METRIC_1:12;
hence ex K being non empty compact Subset of (TOP-REAL 2) st
( K = (sn -FanMorphE ) .: K & ex V2 being Subset of (TOP-REAL 2) st
( p2 in V2 & V2 is open & V2 c= K & (sn -FanMorphE ) . p2 in V2 ) ) by A11, A12, A13, METRIC_1:15; :: thesis: verum