let X be set ; :: thesis: for f being PartFunc of REAL , REAL st f | X is continuous & f " {0 } = {} holds
(f ^ ) | X is continuous
let f be PartFunc of REAL , REAL ; :: thesis: ( f | X is continuous & f " {0 } = {} implies (f ^ ) | X is continuous )
assume that
A1: f | X is continuous and
A2: f " {0 } = {} ; :: thesis: (f ^ ) | X is continuous
A3: dom (f ^ ) = (dom f) \ {} by A2, RFUNCT_1:def 8
.= dom f ;
let r be real number ; :: according to FCONT_1:def 2 :: thesis: ( r in dom ((f ^ ) | X) implies (f ^ ) | X is_continuous_in r )
assume A5: r in dom ((f ^ ) | X) ; :: thesis: (f ^ ) | X is_continuous_in r
then ( r in X & r in dom (f ^ ) ) by RELAT_1:86;
then B5: r in dom (f | X) by A3, RELAT_1:86;
then A6: f | X is_continuous_in r by A1, Def2;

now

let s1 be Real_Sequence; :: thesis: ( rng s1 c= dom ((f ^ ) | X) & s1 is convergent & lim s1 = r implies ( ((f ^ ) | X) /* s1 is convergent & lim (((f ^ ) | X) /* s1) = ((f ^ ) | X) . r ) )
assume A8: ( rng s1 c= dom ((f ^ ) | X) & s1 is convergent & lim s1 = r ) ; :: thesis: ( ((f ^ ) | X) /* s1 is convergent & lim (((f ^ ) | X) /* s1) = ((f ^ ) | X) . r )
then rng s1 c= (dom (f ^ )) /\ X by RELAT_1:90;
then A9: rng s1 c= dom (f | X) by A3, RELAT_1:90;
then A10: ( (f | X) /* s1 is convergent & (f | X) . r = lim ((f | X) /* s1) ) by A6, A8, Def1;
A12: (f | X) . r = f . r by B5, FUNCT_1:68;
B11: r in dom f by B5, RELAT_1:86;

A13: now

let n be Element of NAT ; :: thesis: ((f | X) /* s1) . n <> 0
A14: rng s1 c= (dom f) /\ X by A3, A8, RELAT_1:90;
(dom f) /\ X c= dom f by XBOOLE_1:17;
then A15: rng s1 c= dom f by A14, XBOOLE_1:1;
A16: s1 . n in rng s1 by VALUED_0:28;

A17: now

assume f . (s1 . n) = 0 ; :: thesis: contradiction
then f . (s1 . n) in {0 } by TARSKI:def 1;
hence contradiction by A2, A15, A16, FUNCT_1:def 13; :: thesis: verum

end;

((f | X) /* s1) . n = (f | X) . (s1 . n) by A9, FUNCT_2:185
.= f . (s1 . n) by A9, A16, FUNCT_1:68 ;
hence ((f | X) /* s1) . n <> 0 by A17; :: thesis: verum

end;

now

assume f . r = 0 ; :: thesis: contradiction
then f . r in {0 } by TARSKI:def 1;
hence contradiction by A2, B11, FUNCT_1:def 13; :: thesis: verum

end;

then A18: ( lim ((f | X) /* s1) <> 0 & (f | X) /* s1 is non-zero ) by A6, A8, A9, A12, A13, Def1, SEQ_1:7;

now

let n be Element of NAT ; :: thesis: (((f ^ ) | X) /* s1) . n = (((f | X) /* s1) " ) . n
A19: s1 . n in rng s1 by VALUED_0:28;
then s1 . n in dom ((f ^ ) | X) by A8;
then s1 . n in (dom (f ^ )) /\ X by RELAT_1:90;
then A20: s1 . n in dom (f ^ ) by XBOOLE_0:def 4;
thus (((f ^ ) | X) /* s1) . n = ((f ^ ) | X) . (s1 . n) by A8, FUNCT_2:185
.= (f ^ ) . (s1 . n) by A8, A19, FUNCT_1:68
.= (f . (s1 . n)) " by A20, RFUNCT_1:def 8
.= ((f | X) . (s1 . n)) " by A9, A19, FUNCT_1:68
.= (((f | X) /* s1) . n) " by A9, FUNCT_2:185
.= (((f | X) /* s1) " ) . n by VALUED_1:10 ; :: thesis: verum

end;

then A21: ((f ^ ) | X) /* s1 = ((f | X) /* s1) " by FUNCT_2:113;
hence ((f ^ ) | X) /* s1 is convergent by A10, A18, SEQ_2:35; :: thesis: lim (((f ^ ) | X) /* s1) = ((f ^ ) | X) . r
thus lim (((f ^ ) | X) /* s1) = ((f | X) . r) " by A10, A18, A21, SEQ_2:36
.= (f . r) " by B5, FUNCT_1:68
.= (f ^ ) . r by A3, B11, RFUNCT_1:def 8
.= ((f ^ ) | X) . r by A5, FUNCT_1:68 ; :: thesis: verum

end;

hence (f ^ ) | X is_continuous_in r by Def1; :: thesis: verum