let AP be AffinPlane; :: thesis: ( AP is satisfying_TDES_2 implies AP is satisfying_TDES_3 )
assume A1: AP is satisfying_TDES_2 ; :: thesis: AP is satisfying_TDES_3
thus AP is satisfying_TDES_3 :: thesis: verum

proof

let K be Subset of AP; :: according to AFF_2:def 10 :: thesis: for o, a, b, c, a', b', c' being Element of AP st K is being_line & o in K & c in K & not a in K & o <> c & a <> b & LIN o,a,a' & LIN o,b,b' & a,b // a',b' & a,c // a',c' & b,c // b',c' & a,b // K holds
c' in K
let o, a, b, c, a', b', c' be Element of AP; :: thesis: ( K is being_line & o in K & c in K & not a in K & o <> c & a <> b & LIN o,a,a' & LIN o,b,b' & a,b // a',b' & a,c // a',c' & b,c // b',c' & a,b // K implies c' in K )
assume A2: ( K is being_line & o in K & c in K & not a in K & o <> c & a <> b & LIN o,a,a' & LIN o,b,b' & a,b // a',b' & a,c // a',c' & b,c // b',c' & a,b // K ) ; :: thesis: c' in K
assume A3: not c' in K ; :: thesis: contradiction
A4: not b in K by A2, AFF_1:49;
A5: ( o <> a & o <> b & a <> c & b <> c ) by A2, AFF_1:49;
A6: not LIN a,b,c

proof

assume LIN a,b,c ; :: thesis: contradiction
then a,b // a,c by AFF_1:def 1;
then a,c // K by A2, AFF_1:46;
then c,a // K by AFF_1:48;
hence contradiction by A2, AFF_1:37; :: thesis: verum

end;

set A = Line o,a;
set P = Line o,b;
set N = Line b,c;
A7: ( Line o,a is being_line & Line o,b is being_line & Line b,c is being_line & o in Line o,a & a in Line o,a & o in Line o,b & b in Line o,b & b in Line b,c & c in Line b,c ) by A5, AFF_1:38;
then A8: ( a' in Line o,a & b' in Line o,b ) by A2, A5, AFF_1:39;
A9: Line o,a <> Line o,b

proof

assume Line o,a = Line o,b ; :: thesis: contradiction
then a,b // Line o,a by A7, AFF_1:54, AFF_1:55;
hence contradiction by A2, A7, AFF_1:59, AFF_1:67; :: thesis: verum

end;

A10: a' <> b'

proof

assume A11: a' = b' ; :: thesis: contradiction
then ( a,c // b,c or a' = c' ) by A2, AFF_1:14;
then ( c,a // c,b or a' = c' ) by AFF_1:13;
then ( LIN c,a,b or a' = c' ) by AFF_1:def 1;
hence contradiction by A2, A3, A6, A7, A8, A9, A11, AFF_1:15, AFF_1:30; :: thesis: verum

end;

A12: a' <> c'

proof

assume a' = c' ; :: thesis: contradiction
then b,c // a',b' by A2, AFF_1:13;
then a,b // b,c by A2, A10, AFF_1:14;
then b,a // b,c by AFF_1:13;
then LIN b,a,c by AFF_1:def 1;
hence contradiction by A6, AFF_1:15; :: thesis: verum

end;

not a',c' // K

proof

assume a',c' // K ; :: thesis: contradiction
then ( a',c' // K & a',c' // a,c ) by A2, AFF_1:13;
then a,c // K by A12, AFF_1:46;
then c,a // K by AFF_1:48;
hence contradiction by A2, AFF_1:37; :: thesis: verum

end;

then consider x being Element of AP such that
A13: ( x in K & LIN a',c',x ) by A2, AFF_1:73;
consider T being Subset of AP such that
A14: ( x in T & Line b,c // T ) by A7, AFF_1:63;
A15: ( T is being_line & T // Line b,c ) by A14, AFF_1:50;
not T // Line o,b

proof

assume T // Line o,b ; :: thesis: contradiction
then Line b,c // Line o,b by A14, AFF_1:58;
then c in Line o,b by A7, AFF_1:59;
hence contradiction by A2, A4, A7, AFF_1:30; :: thesis: verum

end;

then consider y being Element of AP such that
A16: ( y in T & y in Line o,b ) by A7, A15, AFF_1:72;
A17: LIN o,b,y by A7, A16, AFF_1:33;
A18: b,c // y,x by A7, A14, A16, AFF_1:53;
a,c // a',x

proof

a',c' // a',x by A13, AFF_1:def 1;
hence a,c // a',x by A2, A12, AFF_1:14; :: thesis: verum

end;

then a,b // a',y by A1, A2, A13, A17, A18, Def9;
then a',b' // a',y by A2, AFF_1:14;
then LIN a',b',y by AFF_1:def 1;
then ( LIN b',y,a' & LIN b',y,b & LIN b',y,b' ) by A7, A8, A16, AFF_1:15, AFF_1:33;
then A19: ( b' = y or LIN b,b',a' ) by AFF_1:17;

A20: now

assume y = b' ; :: thesis: contradiction
then b',c' // b',x by A2, A5, A18, AFF_1:14;
then LIN b',c',x by AFF_1:def 1;
then ( LIN c',x,b' & LIN c',x,a' & LIN c',x,c' ) by A13, AFF_1:15, AFF_1:16;
then LIN a',b',c' by A3, A13, AFF_1:17;
then a',b' // a',c' by AFF_1:def 1;
then a',b' // a,c by A2, A12, AFF_1:14;
then a,b // a,c by A2, A10, AFF_1:14;
hence contradiction by A6, AFF_1:def 1; :: thesis: verum

end;

now

assume A21: b = b' ; :: thesis: contradiction
then b,a // b,a' by A2, AFF_1:13;
then LIN b,a,a' by AFF_1:def 1;
then LIN a,a',b by AFF_1:15;
then ( a = a' or b in Line o,a ) by A7, A8, AFF_1:39;
then ( LIN a,c,c' & LIN b,c,c' ) by A2, A5, A7, A9, A21, AFF_1:30, AFF_1:def 1;
then ( LIN c,c',a & LIN c,c',b & LIN c,c',c ) by AFF_1:15, AFF_1:16;
hence contradiction by A2, A3, A6, AFF_1:17; :: thesis: verum

end;

then ( a' in Line o,b & a',b' // b,a ) by A2, A7, A8, A19, A20, AFF_1:13, AFF_1:39;
then a in Line o,b by A7, A8, A10, AFF_1:62;
hence contradiction by A2, A7, A9, AFF_1:30; :: thesis: verum

end;