let V be RealLinearSpace; :: thesis: for W1, W2, W3 being Subspace of V st W1 is Subspace of W2 holds
the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3))

let W1, W2, W3 be Subspace of V; :: thesis: ( W1 is Subspace of W2 implies the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3)) )
reconsider V2 = the carrier of W2 as Subset of V by RLSUB_1:def 2;
A1: V2 is linearly-closed by RLSUB_1:34;
assume W1 is Subspace of W2 ; :: thesis: the carrier of (W2 + (W1 /\ W3)) = the carrier of ((W1 + W2) /\ (W2 + W3))
then A2: the carrier of W1 c= the carrier of W2 by RLSUB_1:def 2;
thus the carrier of (W2 + (W1 /\ W3)) c= the carrier of ((W1 + W2) /\ (W2 + W3)) by Lm10; :: according to XBOOLE_0:def 10 :: thesis: the carrier of ((W1 + W2) /\ (W2 + W3)) c= the carrier of (W2 + (W1 /\ W3))
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in the carrier of ((W1 + W2) /\ (W2 + W3)) or x in the carrier of (W2 + (W1 /\ W3)) )
assume x in the carrier of ((W1 + W2) /\ (W2 + W3)) ; :: thesis: x in the carrier of (W2 + (W1 /\ W3))
then x in the carrier of (W1 + W2) /\ the carrier of (W2 + W3) by Def2;
then x in the carrier of (W1 + W2) by XBOOLE_0:def 4;
then x in { (u1 + u2) where u2, u1 is VECTOR of V : ( u1 in W1 & u2 in W2 ) } by Def1;
then consider u2, u1 being VECTOR of V such that
A3: x = u1 + u2 and
A4: ( u1 in W1 & u2 in W2 ) ;
( u1 in the carrier of W1 & u2 in the carrier of W2 ) by ;
then u1 + u2 in V2 by A2, A1;
then A5: u1 + u2 in W2 by STRUCT_0:def 5;
( 0. V in W1 /\ W3 & (u1 + u2) + (0. V) = u1 + u2 ) by RLSUB_1:17;
then x in { (u + v) where v, u is VECTOR of V : ( u in W2 & v in W1 /\ W3 ) } by A3, A5;
hence x in the carrier of (W2 + (W1 /\ W3)) by Def1; :: thesis: verum